Version bump, now runs sane plugin in a separate process. Remove migration messages for ancient 0.1.11 version.

(Portage version: 2.2.0_alpha90/cvs/Linux x86_64)

2 files changed, 103 insertions, 1 deletions

diff --git a/x11-misc/colord/ChangeLog b/x11-misc/colord/ChangeLog
index 53abe035fae3..5f1f68811dfc 100644
--- a/x11-misc/colord/ChangeLog
+++ b/x11-misc/colord/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for x11-misc/colord
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/colord/ChangeLog,v 1.20 2012/03/14 03:03:41 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/colord/ChangeLog,v 1.21 2012/03/17 00:33:51 tetromino Exp $
+
+*colord-0.1.18 (17 Mar 2012)
+
+  17 Mar 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +colord-0.1.18.ebuild:
+  Version bump, now runs sane plugin in a separate process. Remove migration
+  messages for ancient 0.1.11 version.
 
 *colord-0.1.17 (14 Mar 2012)
 
diff --git a/x11-misc/colord/colord-0.1.18.ebuild b/x11-misc/colord/colord-0.1.18.ebuild
new file mode 100644
index 000000000000..6e08e75b9c90
--- /dev/null
+++ b/x11-misc/colord/colord-0.1.18.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/colord/colord-0.1.18.ebuild,v 1.1 2012/03/17 00:33:51 tetromino Exp $
+
+EAPI="4"
+
+inherit autotools eutils systemd base
+
+DESCRIPTION="System service to accurately color manage input and output devices"
+HOMEPAGE="http://www.freedesktop.org/software/colord/"
+SRC_URI="http://www.freedesktop.org/software/colord/releases/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="doc examples +gusb +introspection scanner +udev vala"
+
+COMMON_DEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.28.0:2
+	>=media-libs/lcms-2.2:2
+	>=sys-auth/polkit-0.103
+	gusb? ( >=dev-libs/libgusb-0.1.1 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.8 )
+	scanner? ( media-gfx/sane-backends )
+	udev? ( || ( sys-fs/udev[gudev] sys-fs/udev[extras] ) )
+"
+RDEPEND="${COMMON_DEPEND}
+	media-gfx/shared-color-profiles"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	>=dev-util/intltool-0.35
+	dev-util/pkgconfig
+	>=sys-devel/gettext-0.17
+	doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		>=dev-util/gtk-doc-1.9
+	)
+	vala? ( dev-lang/vala:0.14[vapigen] )
+"
+
+# FIXME: needs pre-installed dbus service files
+RESTRICT="test"
+
+DOCS=(AUTHORS ChangeLog MAINTAINERS NEWS README TODO)
+
+pkg_setup() {
+	enewgroup colord
+	enewuser colord -1 -1 /var/lib/colord colord
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-0.1.11-fix-automagic-vala.patch"
+	epatch "${FILESDIR}/${PN}-0.1.15-fix-automagic-libgusb.patch"
+
+	eautoreconf
+}
+
+src_configure() {
+	# Reverse tools require gusb
+	econf \
+		--disable-examples \
+		--disable-static \
+		--enable-polkit \
+		--disable-volume-search \
+		--with-daemon-user=colord \
+		--localstatedir="${EPREFIX}"/var \
+		$(use_enable doc gtk-doc) \
+		$(use_enable gusb) \
+		$(use_enable gusb reverse) \
+		$(use_enable introspection) \
+		$(use_enable scanner sane) \
+		$(use_enable udev gudev) \
+		$(use_enable vala) \
+		$(systemd_with_unitdir) \
+		VAPIGEN=$(type -p vapigen-0.14)
+	# parallel make fails in doc/api
+	use doc && MAKEOPTS="${MAKEOPTS} -j1"
+}
+
+src_install() {
+	base_src_install
+
+	# Ensure config and profile directories exist and /var/lib/colord/*
+	# is writable by colord user
+	keepdir /var/lib/color{,d}/icc
+	fowners colord:colord /var/lib/colord{,/icc}
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.c
+	fi
+
+	find "${D}" -name "*.la" -delete || die
+}