3 files changed, 110 insertions, 1 deletions
diff --git a/app-admin/drush/ChangeLog b/app-admin/drush/ChangeLog
index 3e308fafad5f..dd394c9ac481 100644
--- a/app-admin/drush/ChangeLog
+++ b/app-admin/drush/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-admin/drush
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/drush/ChangeLog,v 1.2 2012/03/09 05:03:41 ramereth Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/drush/ChangeLog,v 1.3 2012/05/13 08:01:48 ramereth Exp $
+
+*drush-5.1 (13 May 2012)
+*drush-4.5-r1 (13 May 2012)
+
+  13 May 2012; Lance Albertson <ramereth@gentoo.org> +drush-4.5-r1.ebuild,
+  +drush-5.1.ebuild:
+  Version bump, fix #371919 & #405539
 
 *drush-4.5 (09 Mar 2012)
 
diff --git a/app-admin/drush/drush-4.5-r1.ebuild b/app-admin/drush/drush-4.5-r1.ebuild
new file mode 100644
index 000000000000..40fd579b6d67
--- /dev/null
+++ b/app-admin/drush/drush-4.5-r1.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/drush/drush-4.5-r1.ebuild,v 1.1 2012/05/13 08:01:48 ramereth Exp $
+
+EAPI="4"
+
+DESCRIPTION="Drush is a command line shell and scripting interface for Drupal"
+HOMEPAGE="http://drupal.org/project/drush"
+SRC_URI="http://ftp.drupal.org/files/projects/${PN}-7.x-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples"
+
+DEPEND="dev-lang/php[cli,simplexml]
+	dev-php/pear
+	dev-php/PEAR-Console_Table"
+RDEPEND="${DEPEND}"
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	sed -i -e \
+		"s!/share/doc/drush!/share/doc/${PF}!" \
+		-e "s!README\.txt!\0.bz2!g" \
+		includes/environment.inc || die
+	sed -i -e "s!\.php'!.php.bz2'!" commands/core/docs.drush.inc || die
+}
+
+src_install() {
+	local docs="README.txt docs"
+	use examples && docs="${docs} examples"
+	insinto /usr/share/drush
+	doins -r .
+	exeinto /usr/share/drush
+	doexe drush
+	dosym /usr/share/drush/drush /usr/bin/drush
+	dodoc -r ${docs}
+	# cleanup
+	for i in ${docs} LICENSE.txt drush.bat examples includes/.gitignore ; do
+		rm -rf "${D}/usr/share/drush/${i}"
+	done
+	keepdir /etc/drush
+}
diff --git a/app-admin/drush/drush-5.1.ebuild b/app-admin/drush/drush-5.1.ebuild
new file mode 100644
index 000000000000..fb551bbfba85
--- /dev/null
+++ b/app-admin/drush/drush-5.1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/drush/drush-5.1.ebuild,v 1.1 2012/05/13 08:01:51 ramereth Exp $
+
+EAPI="4"
+
+inherit bash-completion-r1
+
+DESCRIPTION="Drush is a command line shell and scripting interface for Drupal"
+HOMEPAGE="http://drupal.org/project/drush"
+SRC_URI="http://ftp.drupal.org/files/projects/${PN}-7.x-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+examples"
+
+DEPEND="dev-lang/php[cli,simplexml]
+	dev-php/pear
+	dev-php/PEAR-Console_Table
+	dev-php/PEAR-Console_Getopt"
+RDEPEND="${DEPEND}"
+S="${WORKDIR}/${PN}"
+
+src_prepare() {
+	sed -i -e \
+		"s!/share/doc/drush!/share/doc/${PF}!" \
+		-e "s!README\.txt!\0.bz2!g" \
+		includes/bootstrap.inc || die
+	sed -i \
+		-e "s!\.php'!.php.bz2'!" \
+		-e "s!\.ini'!.ini.bz2'!" \
+		-e "s!\.txt'!.txt.bz2'!" \
+		-e "s!\.bashrc'!.bashrc.bz2'!" \
+		commands/core/docs.drush.inc || die
+	sed \
+		-e "1,2d" \
+		-e "5,11d" \
+		drush.complete.sh > drush.bashcomp
+}
+
+src_install() {
+	local docs="README.txt docs"
+	use examples && docs="${docs} examples"
+	insinto /usr/share/drush
+	doins -r .
+	exeinto /usr/share/drush
+	doexe drush
+	dosym /usr/share/drush/drush /usr/bin/drush
+	dodoc -r ${docs}
+	# cleanup
+	for i in ${docs} LICENSE.txt drush.bat examples includes/.gitignore \
+		.gitignore .travis.yml drush.complete.sh ; do
+		rm -rf "${D}/usr/share/drush/${i}"
+	done
+	keepdir /etc/drush
+	newbashcomp drush.bashcomp drush
+}