1 files changed, 99 insertions, 0 deletions
diff --git a/media-sound/mpd/mpd-0.11.5-r1.ebuild b/media-sound/mpd/mpd-0.11.5-r1.ebuild
new file mode 100644
index 000000000000..c23b9304ae21
--- /dev/null
+++ b/media-sound/mpd/mpd-0.11.5-r1.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/mpd/mpd-0.11.5-r1.ebuild,v 1.1 2005/10/16 21:11:44 ticho Exp $
+
+inherit eutils
+
+DESCRIPTION="Music Player Daemon (mpd)"
+HOMEPAGE="http://www.musicpd.org"
+SRC_URI="http://mercury.chem.pitt.edu/~shank/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~sparc ~x86"
+IUSE="aac alsa audiofile flac ipv6 mad mikmod unicode vorbis"
+
+DEPEND=">=media-libs/libao-0.8.4
+	!media-sound/mpd-svn
+	sys-libs/zlib
+	aac? ( >=media-libs/faad2-2.0_rc2 )
+	alsa? ( media-libs/alsa-lib )
+	audiofile? ( media-libs/audiofile )
+	flac? ( >=media-libs/flac-1.1.0 )
+	mad? ( media-libs/libmad
+	       media-libs/libid3tag )
+	mikmod? ( media-libs/libmikmod )
+	vorbis? ( media-libs/libvorbis )"
+
+pkg_setup() {
+	enewuser mpd '' '' '' audio || die "problem adding user mpd"
+}
+
+src_compile() {
+	econf \
+		$(use_enable aac) \
+		$(use_enable audiofile) \
+		$(use_enable audiofile audiofiletest) \
+		$(use_enable flac libFLACtest) \
+		$(use_enable flac) \
+		$(use_enable ipv6) \
+		$(use_enable !mad mpd-mad) \
+		$(use_enable !mad id3tag) \
+		$(use_enable mikmod libmikmodtest) \
+		$(use_enable mikmod mod) \
+		$(use_enable vorbis ogg) \
+		$(use_enable vorbis oggtest) \
+		$(use_enable vorbis vorbistest) \
+		|| die "could not configure"
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	make install DESTDIR=${D} || die "make install failed"
+
+	rm -rf ${D}/usr/share/doc/mpd/
+	dodoc ChangeLog INSTALL README TODO UPGRADING
+	dodoc doc/COMMANDS doc/mpdconf.example
+
+	insinto /etc
+	newins doc/mpdconf.example mpd.conf
+
+	exeinto /etc/init.d
+	newexe ${FILESDIR}/mpd.rc6 mpd
+
+	if use unicode; then
+		dosed 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' /etc/mpd.conf
+	fi
+	dosed 's:^#user.*$:user "mpd":' /etc/mpd.conf
+	dosed 's:^#bind.*$:bind_to_address "localhost":' /etc/mpd.conf
+	dosed 's:^port.*$:port "6600":' /etc/mpd.conf
+	dosed 's:^music_directory.*$:music_directory "/usr/share/mpd/music":' /etc/mpd.conf
+	dosed 's:^playlist_directory.*$:playlist_directory "/usr/share/mpd/playlists":' /etc/mpd.conf
+	dosed 's:^log_file.*$:log_file "/var/log/mpd.log":' /etc/mpd.conf
+	dosed 's:^error_file.*$:error_file "/var/log/mpd.error.log":' /etc/mpd.conf
+	diropts -m0755 -o mpd -g audio
+	dodir /usr/share/mpd/music
+	keepdir /usr/share/mpd/music
+	dodir /usr/share/mpd/playlists
+	keepdir /usr/share/mpd/playlists
+	dodir /usr/share/mpd/
+	insinto /var/log
+	touch ${T}/blah
+	insopts -m0640 -o mpd -g audio
+	newins ${T}/blah mpd.log
+	newins ${T}/blah mpd.error.log
+
+	use alsa && \
+		dosed 's:need :need alsasound :' /etc/init.d/mpd
+}
+
+pkg_postinst() {
+	einfo "libao prior to 0.8.4 has issues with the ALSA drivers"
+	einfo "please refer to the FAQ"
+	einfo "http://www.musicpd.org/wiki/moin.cgi/MpdFAQ if you are having"
+	einfo "problems."
+	einfo
+	einfo "The default config now binds the daemon strictly to localhost,"
+	einfo "rather then all available IPs."
+}