From da8d7a3a41bda5209e1f9f8ef5930afc7e6c8b08 Mon Sep 17 00:00:00 2001
From: Gilles Dartiguelongue <eva@gentoo.org>
Date: Tue, 9 Jun 2015 14:37:37 +0000
Subject: Version bump for Gnome 3.16.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key C6085806)
---
 gnome-extra/gucharmap/ChangeLog               |  7 ++-
 gnome-extra/gucharmap/gucharmap-3.16.2.ebuild | 62 +++++++++++++++++++++++++++
 2 files changed, 68 insertions(+), 1 deletion(-)
 create mode 100644 gnome-extra/gucharmap/gucharmap-3.16.2.ebuild

(limited to 'gnome-extra')

diff --git a/gnome-extra/gucharmap/ChangeLog b/gnome-extra/gucharmap/ChangeLog
index ca67ec979e67..8c126d0e9c1c 100644
--- a/gnome-extra/gucharmap/ChangeLog
+++ b/gnome-extra/gucharmap/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for gnome-extra/gucharmap
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/ChangeLog,v 1.230 2015/06/07 10:37:37 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/ChangeLog,v 1.231 2015/06/09 14:37:37 eva Exp $
+
+*gucharmap-3.16.2 (09 Jun 2015)
+
+  09 Jun 2015; Gilles Dartiguelongue <eva@gentoo.org> +gucharmap-3.16.2.ebuild:
+  Version bump for Gnome 3.16.
 
   07 Jun 2015; Markus Meier <maekke@gentoo.org> gucharmap-3.14.2.ebuild:
   arm stable, bug #534012
diff --git a/gnome-extra/gucharmap/gucharmap-3.16.2.ebuild b/gnome-extra/gucharmap/gucharmap-3.16.2.ebuild
new file mode 100644
index 000000000000..1fc3e6706091
--- /dev/null
+++ b/gnome-extra/gucharmap/gucharmap-3.16.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/gucharmap/gucharmap-3.16.2.ebuild,v 1.1 2015/06/09 14:37:37 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="yes"
+VALA_MIN_API_VERSION="0.16"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="Unicode character map viewer and library"
+HOMEPAGE="http://live.gnome.org/Gucharmap"
+
+LICENSE="GPL-3"
+SLOT="2.90"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="cjk +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.32:2
+	>=x11-libs/pango-1.2.1[introspection?]
+	>=x11-libs/gtk+-3.16:3[introspection?]
+
+	introspection? ( >=dev-libs/gobject-introspection-0.9.0 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-extra/gucharmap-3:0
+"
+DEPEND="${RDEPEND}
+	app-text/yelp-tools
+	dev-util/desktop-file-utils
+	>=dev-util/gtk-doc-am-1
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? (	app-text/docbook-xml-dtd:4.1.2 )
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	# prevent file collisions with slot 0
+	sed -e "s:GETTEXT_PACKAGE=gucharmap$:GETTEXT_PACKAGE=gucharmap-${SLOT}:" \
+		-i configure.ac configure || die "sed configure.ac configure failed"
+
+	# avoid autoreconf
+	sed -e 's/-Wall //g' -i configure || die "sed failed"
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# Do not add ITSTOOL=$(type -P true); yelp-tools is a true required
+	# dependency here for some LINGUAS.
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable introspection) \
+		$(use_enable cjk unihan) \
+		$(use_enable vala)
+}
-- 
cgit v1.2.3-65-gdbad