From f2de62c717a305c561f13d591d72705fe2c951df Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Mon, 25 Nov 2013 14:26:05 +0000
Subject: Enable multilib support, bug #488286. Acked by Chainsaw.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)
---
 sys-libs/libcap/libcap-2.22-r2.ebuild | 69 +++++++++++++++++++++++++++++++++++
 1 file changed, 69 insertions(+)
 create mode 100644 sys-libs/libcap/libcap-2.22-r2.ebuild

(limited to 'sys-libs/libcap/libcap-2.22-r2.ebuild')

diff --git a/sys-libs/libcap/libcap-2.22-r2.ebuild b/sys-libs/libcap/libcap-2.22-r2.ebuild
new file mode 100644
index 000000000000..815331a3450d
--- /dev/null
+++ b/sys-libs/libcap/libcap-2.22-r2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/libcap/libcap-2.22-r2.ebuild,v 1.1 2013/11/25 14:26:05 mgorny Exp $
+
+EAPI="4"
+
+inherit eutils multilib multilib-minimal toolchain-funcs pam
+
+DESCRIPTION="POSIX 1003.1e capabilities"
+HOMEPAGE="http://www.friedhoff.org/posixfilecaps.html"
+SRC_URI="mirror://kernel/linux/libs/security/linux-privs/libcap${PV:0:1}/${P}.tar.bz2"
+
+# it's available under either of the licenses
+LICENSE="|| ( GPL-2 BSD )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux"
+IUSE="pam"
+
+RDEPEND="sys-apps/attr[${MULTILIB_USEDEP}]
+	pam? ( virtual/pam )"
+DEPEND="${RDEPEND}
+	sys-kernel/linux-headers"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.22-build-system-fixes.patch
+	epatch "${FILESDIR}"/${PN}-2.22-no-perl.patch
+	epatch "${FILESDIR}"/${PN}-2.20-ignore-RAISE_SETFCAP-install-failures.patch
+	epatch "${FILESDIR}"/${PN}-2.21-include.patch
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	if multilib_build_binaries && use pam; then
+		pam=yes
+	else
+		pam=no
+	fi
+
+	sed -i \
+		-e "/^PAM_CAP/s:=.*:=${pam}:" \
+		-e '/^DYNAMIC/s:=.*:=yes:' \
+		-e "/^lib=/s:=.*:=/usr/$(get_libdir):" \
+		Make.Rules
+}
+
+multilib_src_compile() {
+	tc-export_build_env BUILD_CC
+	tc-export AR RANLIB
+
+	default
+}
+
+multilib_src_install() {
+	# no configure, needs explicit install line #444724#c3
+	emake install DESTDIR="${ED}"
+
+	multilib_build_binaries && gen_usr_ldscript -a cap
+
+	rm -rf "${ED}"/usr/$(get_libdir)/security
+	if multilib_build_binaries && use pam; then
+		dopammod pam_cap/pam_cap.so
+		dopamsecurity '' pam_cap/capability.conf
+	fi
+}
+
+multilib_src_install_all() {
+	dodoc CHANGELOG README doc/capability.notes
+}
-- 
cgit v1.2.3-65-gdbad