From aee52469ba4d1836bca53c6554f50b073f0df8c1 Mon Sep 17 00:00:00 2001
From: Markos Chandras <hwoarang@gentoo.org>
Date: Wed, 28 Mar 2012 18:50:10 +0000
Subject: version bump

(Portage version: 2.2.0_alpha94/cvs/Linux x86_64)
---
 x11-misc/lightdm/ChangeLog            |  7 ++-
 x11-misc/lightdm/lightdm-1.1.9.ebuild | 96 +++++++++++++++++++++++++++++++++++
 2 files changed, 102 insertions(+), 1 deletion(-)
 create mode 100644 x11-misc/lightdm/lightdm-1.1.9.ebuild

(limited to 'x11-misc')

diff --git a/x11-misc/lightdm/ChangeLog b/x11-misc/lightdm/ChangeLog
index 79263387c03e..d1af5fa4dfcf 100644
--- a/x11-misc/lightdm/ChangeLog
+++ b/x11-misc/lightdm/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/lightdm
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.31 2012/03/16 22:29:52 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.32 2012/03/28 18:50:10 hwoarang Exp $
+
+*lightdm-1.1.9 (28 Mar 2012)
+
+  28 Mar 2012; Markos Chandras <hwoarang@gentoo.org> +lightdm-1.1.9.ebuild:
+  version bump
 
 *lightdm-1.1.8 (16 Mar 2012)
 
diff --git a/x11-misc/lightdm/lightdm-1.1.9.ebuild b/x11-misc/lightdm/lightdm-1.1.9.ebuild
new file mode 100644
index 000000000000..c26154b55919
--- /dev/null
+++ b/x11-misc/lightdm/lightdm-1.1.9.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.1.9.ebuild,v 1.1 2012/03/28 18:50:10 hwoarang Exp $
+
+EAPI=4
+inherit autotools eutils pam
+
+DESCRIPTION="A lightweight display manager"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
+SRC_URI="http://launchpad.net/${PN}/1.2/${PV}/+download/${P}.tar.gz
+	mirror://gentoo/introspection-20110205.m4.tar.bz2"
+
+LICENSE="GPL-3 LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection"
+
+RDEPEND="dev-libs/glib:2
+	virtual/pam
+	x11-libs/libxklavier
+	x11-libs/libX11
+	dev-libs/libxml2
+	introspection? ( dev-libs/gobject-introspection )
+	sys-apps/accountsservice"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	dev-util/pkgconfig
+	gnome-base/gnome-common
+	sys-devel/gettext"
+PDEPEND="x11-misc/lightdm-gtk-greeter"
+
+DOCS=( NEWS )
+
+src_prepare() {
+	sed -i -e "/minimum-uid/s:500:1000:" data/users.conf || die
+	sed -i -e "s:gtk+-3.0:gtk+-2.0:" configure.ac || die
+	epatch "${FILESDIR}"/session-wrapper-${PN}.patch
+	if has_version dev-libs/gobject-introspection; then
+		eautoreconf
+	else
+		AT_M4DIR=${WORKDIR} eautoreconf
+	fi
+}
+
+src_configure() {
+	# Maybe in the future, we can support some automatic session and user
+	# recognition. Until then, use default values
+	local default=gnome user=root greeter
+
+	# There is no qt greeter, so use gtk anyway
+	# use gtk && greeter=lightdm-gtk-greeter
+	greeter=lightdm-gtk-greeter
+
+	# Let user know how lightdm is configured
+	einfo "Gentoo configuration"
+	einfo "Default greeter: ${greeter}"
+	einfo "Default session: ${default}"
+	einfo "Greeter user: ${user}"
+
+	# do the actual configuration
+	econf --localstatedir=/var \
+		--disable-static \
+		$(use_enable introspection) \
+		--disable-liblightdm-qt \
+		--with-user-session=${user} \
+		--with-greeter-session=${greeter} \
+		--with-greeter-user=${user} \
+		--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
+}
+
+src_install() {
+	default
+
+	# Install missing files
+	insinto /etc/${PN}/
+	doins "${S}"/data/{${PN},users,keys}.conf
+	doins "${FILESDIR}"/Xsession
+	fperms +x /etc/${PN}/Xsession
+	# remove .la files
+	find "${ED}" -name "*.la" -exec rm -rf {} +
+	rm -Rf "${ED}"/etc/init || die
+
+	dopamd "${FILESDIR}"/${PN}
+	dopamd "${FILESDIR}"/${PN}-autologin
+}
+
+pkg_postinst() {
+	elog
+	elog "Even though the default /etc/${PN}/${PN}.conf will work for"
+	elog "most users, make sure you configure it to suit your needs"
+	elog "before using ${PN} for the first time."
+	elog "You can test the configuration file using the following"
+	elog "command: ${PN} --test-mode -c /etc/${PN}/${PN}.conf. This"
+	elog "requires xorg-server to be built with the 'kdrive' useflag."
+	elog
+}
-- 
cgit v1.2.3-65-gdbad