# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-accessibility/sphinx3/sphinx3-0.8.ebuild,v 1.1 2011/11/17 17:45:56 neurogeek Exp $

EAPI=3
PYTHON_DEPEND="python? 2:2.6"
SUPPORT_PYTHON_ABIS="1"

inherit autotools-utils prefix python

DESCRIPTION="CMU Speech Recognition engine"
HOMEPAGE="http://cmusphinx.sourceforge.net/"
SRC_URI="mirror://sourceforge/cmusphinx/${P}.tar.gz"

LICENSE="BSD as-is"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc python static-libs"

DEPEND=">=app-accessibility/sphinxbase-0.7[static-libs?,python?]"
RDEPEND="${DEPEND}"

RESTRICT_PYTHON_ABIS="3*"

src_prepare() {
	epatch "${FILESDIR}/${P}_heap_fix.patch"
	eprefixify 'python/setup.py'
}

src_configure() {
	econf \
		$( use_enable static-libs static )
}

src_compile() {
	default

	if use python; then
		python_copy_sources python

		building() {
			"$(PYTHON)" setup.py build
		}

		python_execute_function -s --source-dir python building
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die

	dodoc AUTHORS ChangeLog NEWS README

	if use doc; then
		cd doc
		dohtml -r -x CVS s3* s3 *.html
	fi

	if use python; then

		installing() {
			"$(PYTHON)" setup.py install \
				--install-lib="${D}/$(python_get_sitedir)"
		}

		python_execute_function -s --source-dir python installing
	fi

	remove_libtool_files
}