dev-python/moto: Bump to 2.0.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 71 insertions, 0 deletions

diff --git a/dev-python/moto/Manifest b/dev-python/moto/Manifest
index 19fa8f3d3114..a84789ae0855 100644
--- a/dev-python/moto/Manifest
+++ b/dev-python/moto/Manifest
@@ -4,3 +4,4 @@ DIST moto-2.0.0.tar.gz 5054551 BLAKE2B be9b18909f90b22fe57d47e2eea50144b4ac8046d
 DIST moto-2.0.1.tar.gz 1530088 BLAKE2B eb35bcbc8b22044ae86eaa6eb1f71eb24174a8686ef06d475c870ef629d0a525719c4f153cb0a55fa27f3c33568a5796a07ce903800468557dfe275de3da3623 SHA512 d650140c76a2090332fd9f4c8be84379d4e578a63125d473b821d59bff9f93ee8e696268e4784df13f2ee3b8b6967fd10cbd94750f37e63967ed679b4a301682
 DIST moto-2.0.2.tar.gz 1534459 BLAKE2B b4609f332e8f8eb8d61250919eca805f82a6dfc468cf0b9cfe81f462aae9f93373efec6165c818589abe60955abe061a273148a36e4b1f8534ce9fa7e59f5cd2 SHA512 b478f9938f8e7b92c3e718a1aea5907c2070bda42995050d39f8e62cbd7cfd30fe4c9cbd7e7475f5a50c71c3370a89f53480adcf83df1fe08968125f2a1427f6
 DIST moto-2.0.5.tar.gz 1551415 BLAKE2B 452cb94443188e1715145bee574f04924d894a3d647673443a8a335bb907f8601098540b032d6c9a8ced3e1fc490c49ad70c877547d905cece05bbb742d05976 SHA512 70e64ab98873d480e776a2139a4d351665c6c2f98faf90e2871c6b9998571d1bd239757bc90bbc6ab6e1ed510598bfce77157ad522953efe40c884068885c57d
+DIST moto-2.0.6.tar.gz 1557871 BLAKE2B dd4c23758bc9c98fbd2b2a70af744daa245fc8b4b1154348486ae85d195e5e3fa2c513f61386504d05c0d646e81fbf8ec5bf41be317b9fd7581668cd23cc1db3 SHA512 9f287ff07f948dd3d2d6af1c6120d29e9625e420bb94f83c230d813e26689161f9a2e89e2b32947e82084cdcd865fef714ad14309ff41371bd37d251481f8dc9
diff --git a/dev-python/moto/moto-2.0.6.ebuild b/dev-python/moto/moto-2.0.6.ebuild
new file mode 100644
index 000000000000..7c3740bdf84d
--- /dev/null
+++ b/dev-python/moto/moto-2.0.6.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7..9} )
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Mock library for boto"
+HOMEPAGE="https://github.com/spulec/moto"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/aws-xray-sdk-python-0.93[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/backports-tempfile[${PYTHON_USEDEP}]' python3_{6,7})
+	dev-python/boto[${PYTHON_USEDEP}]
+	dev-python/cfn-python-lint[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-3.3.1[${PYTHON_USEDEP}]
+	dev-python/cookies[${PYTHON_USEDEP}]
+	dev-python/dicttoxml[${PYTHON_USEDEP}]
+	>=dev-python/docker-py-2.5.1[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.5[${PYTHON_USEDEP}]
+	>=dev-python/jinja-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/jsondiff-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/boto3-1.9.201[${PYTHON_USEDEP}]
+	>=dev-python/botocore-1.12.201[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/flask-cors[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/pretty-yaml[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/python-dateutil-2.1[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/python-jose[${PYTHON_USEDEP}]
+	dev-python/python-sshpubkeys[${PYTHON_USEDEP}]
+	>=dev-python/responses-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.5[${PYTHON_USEDEP}]
+	dev-python/xmltodict[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/zipp[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/freezegun[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/sure-1.4.11[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# unping indirect dep on ecdsa that's supposed to workaround pip
+	# bugs
+	sed -i -e '/ecdsa/s:<0.15::' setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# pytest-django causes freezegun try to mangle stuff inside django
+	# which fails when django is not really used
+	epytest -p no:django -m 'not network'
+}