dev-python/nbdime: add version 3.1.1, EAPI 8, enable py3.10

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>

2 files changed, 79 insertions, 0 deletions

diff --git a/dev-python/nbdime/Manifest b/dev-python/nbdime/Manifest
index 8eb220b0879b..c61651eb797f 100644
--- a/dev-python/nbdime/Manifest
+++ b/dev-python/nbdime/Manifest
@@ -1 +1,2 @@
 DIST nbdime-3.1.0.tar.gz 7508382 BLAKE2B 10ca59684df06e922afbba30d5419a20490508af8bb9d4f371b1a06db49df7b665195c9aec21c3a303b3fa0c60e5c0c1e57badaba27ac81599b311f9a5000244 SHA512 be19fc058a918cd2aad38a8f727504a01c7830dfaba7fbf06caa0a6799770824499a70f4efe1ebf0a82847dc79d84896baf9aa86d3e7cd16dd7163023fed3855
+DIST nbdime-3.1.1.tar.gz 7723671 BLAKE2B 2a8f0e7281e1830d6ab15bcc25c1be69e37b575e4ecde1f61f5d697be8cf556c7e3bfdf11375f47808aa812bebbbaf4bfacaa121c17fefb9cc8a80ba9ca08d1c SHA512 268c2c3f8c45dd4a55a632d55a817ee4a4283c5411b73915bb514a9b546ebcdebd7481e93a1e7ba66c30bcdc70932ba7af83de454d3d0ab9d2cfa24bc19c8d9f
diff --git a/dev-python/nbdime/nbdime-3.1.1.ebuild b/dev-python/nbdime/nbdime-3.1.1.ebuild
new file mode 100644
index 000000000000..aff1fcbbdd00
--- /dev/null
+++ b/dev-python/nbdime/nbdime-3.1.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Diff and merge of Jupyter Notebooks"
+HOMEPAGE="https://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="webtools"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	dev-python/GitPython[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_server[${PYTHON_USEDEP}]
+	dev-python/jupyter_server_mathjax[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+	webtools? ( net-libs/nodejs[npm] )"
+BDEPEND="
+	test? (
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/notebook[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/tabulate[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_sphinx docs/source \
+		dev-python/recommonmark \
+		dev-python/sphinx_rtd_theme
+distutils_enable_tests --install pytest
+
+python_prepare_all() {
+	# yield tests were removed in pytest 4.0
+	sed -i -e 's/test_offline_mathjax/_&/' \
+		-e 's/test_api_merge/_&/' \
+		-e 's/test_fetch_merge/_&/' \
+		-e 's/test_api_diff/_&/' \
+		-e 's/test_fetch_diff/_&/' \
+		nbdime/tests/test_web.py || die
+	sed -i -e 's/test_git_difftool/_&/' \
+		nbdime/tests/test_server_extension.py || die
+	# reason: [NOTRUN] flaws in deep diffing of lists, not identifying almost equal sublists
+	sed -i -e 's/test_deep_merge_lists_delete_no_conflict__currently_expected_failures/_&/' \
+		nbdime/tests/test_merge.py || die
+	sed -i -e 's/test_diff_to_json_patch/_&/' \
+		nbdime/tests/test_diff_json_conversion.py || die
+	sed -i -e 's/test_build_diffs_unsorted/_&/' \
+		nbdime/tests/test_decision_tools.py || die
+	sed -i -e 's/test_merge_multiline_cell_source_conflict/_&/' \
+		-e 's/test_merge_interleave_cell_add_remove/_&/' \
+		-e 's/test_merge_conflicts_get_diff_indices_shifted/_&/' \
+		-e 's/test_merge_inserts_within_deleted_range/_&/' \
+		nbdime/tests/test_merge_notebooks.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	use webtools || DISTUTILS_ARGS=( --skip-npm )
+}
+
+src_test() {
+	# user.email and user.name are not configured in the sandbox
+	git config --global user.email "larry@gentoo.org" || die
+	git config --global user.name "Larry the Cow" || die
+	python_foreach_impl python_test
+}