mail-client/evolution: Drop old versions

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 0 insertions, 153 deletions

diff --git a/mail-client/evolution/Manifest b/mail-client/evolution/Manifest
index 52753b5b3f76..f6a16c38f18f 100644
--- a/mail-client/evolution/Manifest
+++ b/mail-client/evolution/Manifest
@@ -1,3 +1,2 @@
-DIST evolution-3.40.1.tar.xz 12223944 BLAKE2B 00e37d45c5139e77ab9461948185467c9d2fadd3b315bdc65b6a55fe78e605a1eb65479ced304fc0d5a2bd2acf813164fc567254ad8e692701823420195c810a SHA512 acebe937e7bce5e998b86ceb8e53b07ffc9f558543b72cc5d68a54ca2714684bdf3f22726f243754c6ecea7205ccb1b9411095e9c62ca7f9890d2edb0a0b0d00
 DIST evolution-3.40.2.tar.xz 12215356 BLAKE2B df1bc738ea058c2e624e7d56b69bb13e059ceb25fc4fa26d00823677fee61ccb9adc16ee70f5f702163b59f3fcf760a116eb2eabe2350edcad693614d6c0b68e SHA512 081692e157bcc300ef26179f5e12a22bdc993043ca7c56b63622c4608b3c36c3c2e642d5353124c8661cc1ce2841d147345de86b4171ee7341493ffe0e24fc08
 DIST evolution-3.40.3.tar.xz 12216768 BLAKE2B 7b146ee09abff566a5a0cbbda9dda6ce5cd26c076462fd511cbc02fa35352d1ab776c67c5c99990278963a6f96c2ea8410588925cce1c05300e34ad5252de618 SHA512 08fcfdafd78ee323a57355dec1c8755525eefb599b70e6fb60ed0e9963a538a4b3f172b78f03aecbd245741fad08363b01ada46c2e349a9ccdc080d28c286452
diff --git a/mail-client/evolution/evolution-3.40.1.ebuild b/mail-client/evolution/evolution-3.40.1.ebuild
deleted file mode 100644
index a37eb5ddf470..000000000000
--- a/mail-client/evolution/evolution-3.40.1.ebuild
+++ /dev/null
@@ -1,152 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit cmake gnome2 flag-o-matic readme.gentoo-r1
-
-DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
-HOMEPAGE="https://wiki.gnome.org/Apps/Evolution"
-
-# Note: explicitly "|| ( LGPL-2 LGPL-3 )", not "LGPL-2+".
-LICENSE="|| ( LGPL-2 LGPL-3 ) CC-BY-SA-3.0 FDL-1.3+ OPENLDAP"
-SLOT="2.0"
-
-IUSE="archive +bogofilter geolocation gtk-doc highlight ldap spamassassin spell ssl +weather ytnef"
-
-KEYWORDS="amd64 ~arm ~arm64 ~ppc64 x86"
-
-# glade-3 support is for maintainers only per configure.ac
-# pst is not mature enough and changes API/ABI frequently
-# dconf explicitely needed for backup plugin
-# gnome-desktop support is optional with --enable-gnome-desktop
-# automagic libunity dep
-# >=gspell-1.8 to ensure it uses enchant:2 like webkit-gtk
-DEPEND="
-	>=app-crypt/gcr-3.4:=[gtk]
-	>=app-text/enchant-2.2.0:2
-	>=dev-libs/glib-2.56:2[dbus]
-	>=dev-libs/libxml2-2.7.3:2
-	>=gnome-base/gnome-desktop-2.91.3:3=
-	>=gnome-base/gsettings-desktop-schemas-2.91.92
-	>=gnome-extra/evolution-data-server-${PV}:=[gtk,weather?]
-	>=media-libs/libcanberra-0.25[gtk3]
-	>=net-libs/libsoup-2.42:2.4
-	>=net-libs/webkit-gtk-2.28.0:4[spell?]
-	>=x11-libs/cairo-1.9.15:=[glib]
-	>=x11-libs/gdk-pixbuf-2.24:2
-	>=x11-libs/gtk+-3.22:3
-	>=x11-libs/libnotify-0.7:=
-	>=x11-misc/shared-mime-info-0.22
-
-	>=app-text/iso-codes-0.49
-	dev-libs/atk
-	gnome-base/dconf
-	x11-libs/libSM
-	x11-libs/libICE
-
-	archive? ( >=app-arch/gnome-autoar-0.1.1[gtk] )
-	bogofilter? ( mail-filter/bogofilter )
-	geolocation? (
-		>=media-libs/libchamplain-0.12:0.12[gtk]
-		>=media-libs/clutter-1.0.0:1.0
-		>=media-libs/clutter-gtk-0.90:1.0
-		>=sci-geosciences/geocode-glib-3.10.0
-		x11-libs/mx:1.0 )
-	ldap? ( >=net-nds/openldap-2:= )
-	spamassassin? ( mail-filter/spamassassin )
-	spell? ( >=app-text/gspell-1.8:= )
-	ssl? (
-		>=dev-libs/nspr-4.6.1:=
-		>=dev-libs/nss-3.11:= )
-	weather? ( >=dev-libs/libgweather-3.10:2= )
-	ytnef? ( net-mail/ytnef )
-"
-RDEPEND="${DEPEND}
-	highlight? ( app-text/highlight )
-"
-BDEPEND="
-	app-text/docbook-xml-dtd:4.1.2
-	dev-util/gdbus-codegen
-	dev-util/glib-utils
-	dev-util/itstool
-	gtk-doc? ( dev-util/gtk-doc
-		app-text/docbook-xml-dtd:4.3 )
-	>=dev-util/intltool-0.40.0
-	>=sys-devel/gettext-0.18.3
-	virtual/pkgconfig
-"
-
-DISABLE_AUTOFORMATTING="yes"
-DOC_CONTENTS="To change the default browser if you are not using GNOME, edit
-~/.local/share/applications/mimeapps.list so it includes the
-following content:
-
-[Default Applications]
-x-scheme-handler/http=firefox.desktop
-x-scheme-handler/https=firefox.desktop
-
-(replace firefox.desktop with the name of the appropriate .desktop
-file from /usr/share/applications if you use a different browser)."
-
-# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
-# call; if needed, set them after cmake_src_prepare call, if that works
-
-src_prepare() {
-	cmake_src_prepare
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# Use NSS/NSPR only if 'ssl' is enabled.
-	local mycmakeargs=(
-		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
-		-DENABLE_SCHEMAS_COMPILE=OFF
-		-DENABLE_GTK_DOC=$(usex gtk-doc)
-		-DWITH_OPENLDAP=$(usex ldap)
-		-DENABLE_SMIME=$(usex ssl)
-		-DENABLE_GNOME_DESKTOP=ON
-		-DWITH_ENCHANT_VERSION=2
-		-DENABLE_CANBERRA=ON
-		-DENABLE_AUTOAR=$(usex archive)
-		-DWITH_HELP=ON
-		-DENABLE_YTNEF=OFF
-		-DWITH_BOGOFILTER=$(usex bogofilter)
-		-DWITH_SPAMASSASSIN=$(usex spamassassin)
-		-DENABLE_GSPELL=$(usex spell)
-		-DENABLE_TEXT_HIGHLIGHT=$(usex highlight)
-		-DENABLE_WEATHER=$(usex weather)
-		-DENABLE_CONTACT_MAPS=$(usex geolocation)
-		-DENABLE_YTNEF=$(usex ytnef)
-		-DENABLE_PST_IMPORT=OFF
-		-DWITH_GLADE_CATALOG=OFF
-	)
-
-	cmake_src_configure
-}
-
-src_compile() {
-	cmake_src_compile
-}
-
-src_test() {
-	cmake_src_test
-}
-
-src_install() {
-	cmake_src_install
-
-	# Problems with prelink:
-	# https://bugzilla.gnome.org/show_bug.cgi?id=731680
-	# https://bugzilla.gnome.org/show_bug.cgi?id=732148
-	# https://bugzilla.redhat.com/show_bug.cgi?id=1114538
-	echo PRELINK_PATH_MASK=/usr/bin/evolution > ${T}/99${PN}
-	doenvd "${T}"/99${PN}
-
-	readme.gentoo_create_doc
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	readme.gentoo_print_elog
-}