net-libs/libnma: Version bump to 1.8.32

Signed-off-by: Matt Turner <mattst88@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/net-libs/libnma/Manifest b/net-libs/libnma/Manifest
index 6cc656c73eb6..0e9bf5597823 100644
--- a/net-libs/libnma/Manifest
+++ b/net-libs/libnma/Manifest
@@ -1 +1,2 @@
 DIST libnma-1.8.30.tar.xz 1386248 BLAKE2B 7021e85595819b0cbd44b8c62087f49a5ecccc4bb230820d9a0159bf33b904df4f5c8021a79822c37d0933bdcde790a44f6d960b7f5f504e7506849aed35d54c SHA512 4d8f93d035fca4252e5c5dafc756ee6bc8f1d302aaeca77c5c0acb5d7f6cd4214224fb48e2706e69084c5a714aafa7837769be17d0642cc29eded9eb175a1107
+DIST libnma-1.8.32.tar.xz 1368492 BLAKE2B e91317259f79140803d5b99b23bafddebcb46a72b80c1fec912341aee377920ada3688864ede2aa3d492ef994de9b8f02e391fef98e0bbb61f296541338ad0cd SHA512 65244a8901322bc17d48c9cb809080790d5af0195b79becf0317da77b6c6a0fde3f8d3b752f5d7e59a5dba0970f4499077c5d9d6776912a72748290b8ac98e11
diff --git a/net-libs/libnma/libnma-1.8.32.ebuild b/net-libs/libnma/libnma-1.8.32.ebuild
new file mode 100644
index 000000000000..54ef96c36a65
--- /dev/null
+++ b/net-libs/libnma/libnma-1.8.32.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg vala
+
+DESCRIPTION="NetworkManager GUI library"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# pkcs11 default enabled as it's a small dep often already present by libnma users, and it was default enabled as IUSE=+gcr in nm-applet before
+IUSE="gtk-doc +introspection +pkcs11 vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+DEPEND="
+	app-text/iso-codes
+	net-misc/mobile-broadband-provider-info
+	>=dev-libs/glib-2.38:2
+	>=x11-libs/gtk+-3.10:3[introspection?]
+	>=net-misc/networkmanager-1.7[introspection?]
+	pkcs11? ( >=app-crypt/gcr-3.14:= )
+	introspection? ( >=dev-libs/gobject-introspection-1.56:= )
+"
+RDEPEND="${DEPEND}
+	!<gnome-extra/nm-applet-1.16.0" # gschema moved to here before nm-applet-1.16.0
+BDEPEND="
+	dev-libs/libxml2
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.3 )
+	vala? ( $(vala_depend)
+		net-misc/networkmanager[vala]
+	)
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dlibnma_gtk4=false
+		$(meson_use pkcs11 gcr)
+		-Dmore_asserts=0
+		-Diso_codes=true
+		-Dmobile_broadband_provider_info=true
+		-Dld_gc=false
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		$(meson_use vala vapi)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}