sci-libs/ViSP: bump to 3.3.0

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

3 files changed, 101 insertions, 0 deletions

diff --git a/sci-libs/ViSP/Manifest b/sci-libs/ViSP/Manifest
index b2e256d493e6..9e7302cd53b9 100644
--- a/sci-libs/ViSP/Manifest
+++ b/sci-libs/ViSP/Manifest
@@ -1 +1,2 @@
 DIST visp-3.2.0.tar.gz 52737424 BLAKE2B 78b733183a62541f5d5af22a376ac52ba2377753fa53be62858611b27d961fad286923c11f624c4fe0f561d8dbc5367e2ac01e6bc11a2a19068167ef52198307 SHA512 b4ad21e5063327d91d4ebda268cf4a4dc2ceffbe39d6af0dd6bfeb94d1150884d37fc4ea4295f640135fc2ba758afd29b9090755561ef05249fe2cbc5680dcce
+DIST visp-3.3.0.tar.gz 60822186 BLAKE2B 559698af352b4eac227ab2cdb8d66be31c04d2e2ac2d30ce07cef5022501162211ff9bfc9ed4970ac8b825321b8fc34241a6ca7a29b3d78fb70fa79ac429f7ab SHA512 f96b017353240e63059ef1e514a64198b6a50b95b5a08405c16e99589fd2110071e2d558921a674e538f9cdea07fde8e653ca630e3c12c38bf91f7a83057afe2
diff --git a/sci-libs/ViSP/ViSP-3.3.0.ebuild b/sci-libs/ViSP/ViSP-3.3.0.ebuild
new file mode 100644
index 000000000000..f524038341b0
--- /dev/null
+++ b/sci-libs/ViSP/ViSP-3.3.0.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils
+
+DESCRIPTION="Visual Servoing Platform: visual tracking and visual servoing library"
+HOMEPAGE="http://www.irisa.fr/lagadic/visp/visp.html"
+SRC_URI="http://gforge.inria.fr/frs/download.php/latestfile/475/visp-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0/3.3"
+KEYWORDS="~amd64 ~arm"
+IUSE="
+	+coin demos +dmtx doc examples gsl ieee1394 jpeg motif ogre
+	opencv pcl png test tutorials usb v4l X xml +zbar zlib
+	cpu_flags_x86_sse2 cpu_flags_x86_sse3 cpu_flags_x86_ssse3
+"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	coin? ( >=media-libs/coin-4 virtual/opengl )
+	dmtx? ( media-libs/libdmtx )
+	gsl? ( sci-libs/gsl )
+	ieee1394? ( media-libs/libdc1394 )
+	jpeg? ( virtual/jpeg:0 )
+	motif? ( media-libs/SoXt )
+	ogre? ( dev-games/ogre[ois(+)] dev-libs/boost:=[threads] )
+	opencv? ( media-libs/opencv:=[contribdnn(+)] )
+	pcl? ( sci-libs/pcl:= )
+	png? ( media-libs/libpng:0= )
+	usb? ( virtual/libusb:1 )
+	v4l? ( media-libs/libv4l )
+	X? ( x11-libs/libX11 )
+	xml? ( dev-libs/libxml2 )
+	zbar? ( media-gfx/zbar )
+	zlib? ( sys-libs/zlib )
+"
+DEPEND="${RDEPEND}
+	v4l? ( virtual/os-headers )"
+RDEPEND="${RDEPEND}
+	demos? ( sci-misc/ViSP-images )"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( sci-misc/ViSP-images )
+	doc? ( app-doc/doxygen virtual/latex-base media-gfx/graphviz )"
+REQUIRED_USE="motif? ( coin )"
+
+S="${WORKDIR}/visp-${PV}"
+PATCHES=( "${FILESDIR}/${PN}-3.2.0-ocv.patch" "${FILESDIR}/${PN}-3.0.1-opencv.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		"-DBUILD_EXAMPLES=$(usex examples ON OFF)"
+		"-DBUILD_TESTS=$(usex test ON OFF)"
+		"-DBUILD_DEMOS=$(usex demos ON OFF)"
+		"-DBUILD_TUTORIALS=$(usex tutorials ON OFF)"
+		"-DUSE_COIN3D=$(usex coin ON OFF)"
+		"-DUSE_DC1394=$(usex ieee1394 ON OFF)"
+		"-DUSE_DMTX=$(usex dmtx ON OFF)"
+		"-DUSE_GSL=$(usex gsl ON OFF)"
+		"-DUSE_JPEG=$(usex jpeg ON OFF)"
+		"-DUSE_PNG=$(usex png ON OFF)"
+		"-DUSE_LIBUSB_1=$(usex usb ON OFF)"
+		"-DUSE_OGRE=$(usex ogre ON OFF)"
+		"-DUSE_OIS=$(usex ogre ON OFF)"
+		"-DUSE_OPENCV=$(usex opencv ON OFF)"
+		"-DUSE_PCL=$(usex pcl ON OFF)"
+		"-DUSE_SOQT=OFF"
+		"-DUSE_SOXT=$(usex motif ON OFF)"
+		"-DUSE_V4L2=$(usex v4l ON OFF)"
+		"-DUSE_X11=$(usex X ON OFF)"
+		"-DUSE_XML2=$(usex xml ON OFF)"
+		"-DUSE_ZBAR=$(usex zbar ON OFF)"
+		"-DUSE_ZLIB=$(usex zlib ON OFF)"
+		"-DCOIN3D_INCLUDE_DIR=${EPREFIX:-${SYSROOT}}/usr/include/Coin4"
+		"-DENABLE_SSE2=$(usex cpu_flags_x86_sse2 ON OFF)"
+		"-DENABLE_SSE3=$(usex cpu_flags_x86_sse3 ON OFF)"
+		"-DENABLE_SSSE3=$(usex cpu_flags_x86_ssse3 ON OFF)"
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	cd "${BUILD_DIR}"
+	use doc && emake visp_doc
+}
+
+src_install() {
+	cmake-utils_src_install
+	if use tutorials ; then
+		dodoc -r tutorial
+		docompress -x /usr/share/doc/${PF}/tutorial
+	fi
+	cd "${BUILD_DIR}"
+	use doc && dohtml -r doc/html/*
+}
diff --git a/sci-libs/ViSP/metadata.xml b/sci-libs/ViSP/metadata.xml
index 95a2f3243339..15ed30656d81 100644
--- a/sci-libs/ViSP/metadata.xml
+++ b/sci-libs/ViSP/metadata.xml
@@ -11,6 +11,7 @@
 		<flag name="demos">Installs demo programs.</flag>
 		<flag name="ogre">Enables <pkg>dev-games/ogre</pkg> support.</flag>
 		<flag name="opencv">Enables <pkg>media-libs/opencv</pkg> support.</flag>
+		<flag name="pcl">Enables <pkg>sci-libs/pcl</pkg> support.</flag>
 		<flag name="tutorials">Installs tutorials.</flag>
 		<flag name="zbar">Enables barcodes reading.</flag>
 	</use>