sys-apps/flatpak: Bump to version 1.12.5

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Zac Medico <zmedico@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index d070145f50f4..b0fa2b72ddc9 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -1,2 +1,3 @@
 DIST flatpak-1.12.3.tar.xz 1555340 BLAKE2B 512b3f6abfb06d242aedad2c27c9870750254a9d0a3769999739f8885bbf1740b649e2a41f2c079532b049fcce8b58529572ea35e930437ed6b62194a73bcbb6 SHA512 2f39665457b4c3b99e32ebc88cf5b70202dba6118887617d3d7faa20f688f3f3fc14e343b70c0d11eb15ee743a68d07078e6cda14fd91aa10ca375797cfc95bc
 DIST flatpak-1.12.4.tar.xz 1556548 BLAKE2B 1347b4667b3b8e02309582c1819be7e052382bfca8f6bcdb8b578011e3931e18e8c358c9759b204c8c4f82ffe9f5157fda3c9c967cf1ad0bef2bfc39c4be2a8c SHA512 441c29c43dec6cb224f677e2d9b3dd09e95f4ca6e06d24ee30de1b931522502f903b0bbd3ead4886d16c25d8236a876ffb95ec907690aa7f55cd7ed31c5dd71b
+DIST flatpak-1.12.5.tar.xz 1557688 BLAKE2B d44b1f403afec1ce4896de70810b91eb2d5a81f923aecf5c52394aad7e5a07230ec73f14303dc3f2d201d9c0464ac268788608abb485295f56fdd5242d7cfce1 SHA512 3ac1832a3bca2544a685ba741fcb0762c615aa37600c5be6b4148ea3897800b6c2a39b81f389036896e1fe10d8fac903154917a2ae6e50b4a27a648c95acb46f
diff --git a/sys-apps/flatpak/flatpak-1.12.5.ebuild b/sys-apps/flatpak/flatpak-1.12.5.ebuild
new file mode 100644
index 000000000000..1d0d55b00eda
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.12.5.ebuild
@@ -0,0 +1,104 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9,10} )
+
+inherit autotools linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="doc gtk kde introspection policykit seccomp systemd X"
+RESTRICT+=" test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	|| (
+		dev-util/ostree[curl]
+		dev-util/ostree[soup]
+	)
+	>=gnome-base/dconf-0.26:=
+	>=net-libs/libsoup-2.4:=
+	sys-apps/bubblewrap
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	X? (
+		x11-apps/xauth
+		x11-libs/libXau:=
+	)
+	x11-libs/gdk-pixbuf:2=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+# pyparsing version pinned for https://bugs.gentoo.org/825230
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		>=dev-util/gtk-doc-1.20
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="
+	gtk? ( sys-apps/xdg-desktop-portal-gtk )
+	kde? ( kde-plasma/xdg-desktop-portal-kde )
+"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable X xauth)
+		$(use_enable doc documentation)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}