1 files changed, 0 insertions, 77 deletions
diff --git a/sys-apps/kbd/kbd-2.0.4-r1.ebuild b/sys-apps/kbd/kbd-2.0.4-r1.ebuild
deleted file mode 100644
index aeabdfc9bae0..000000000000
--- a/sys-apps/kbd/kbd-2.0.4-r1.ebuild
+++ /dev/null
@@ -1,77 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit autotools pam
-
-if [[ ${PV} == "9999" ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://git.kernel.org/pub/scm/linux/kernel/git/legion/kbd.git"
-	EGIT_BRANCH="master"
-else
-	SRC_URI="https://www.kernel.org/pub/linux/utils/kbd/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-fi
-
-DESCRIPTION="Keyboard and console utilities"
-HOMEPAGE="http://kbd-project.org/"
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="nls pam test"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	app-arch/gzip
-	pam? (
-		!app-misc/vlock
-		sys-libs/pam
-	)
-"
-DEPEND="${RDEPEND}"
-BDEPEND="
-	virtual/pkgconfig
-	test? ( dev-libs/check )
-"
-
-PATCHES=(
-	"${FILESDIR}/${P}-vlock_configure_switch.patch"
-)
-
-src_unpack() {
-	if [[ ${PV} == "9999" ]] ; then
-		git-r3_src_unpack
-	else
-		default
-	fi
-
-	# Rename conflicting keymaps to have unique names, bug #293228
-	cd "${S}"/data/keymaps/i386 || die
-	mv dvorak/no.map dvorak/no-dvorak.map || die
-	mv fgGIod/trf.map fgGIod/trf-fgGIod.map || die
-	mv olpc/es.map olpc/es-olpc.map || die
-	mv olpc/pt.map olpc/pt-olpc.map || die
-	mv qwerty/cz.map qwerty/cz-qwerty.map || die
-}
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_configure() {
-	local myeconfargs=(
-		$(use_enable nls)
-		$(use_enable pam vlock)
-		$(use_enable test tests)
-	)
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	default
-	docinto html
-	dodoc docs/doc/*.html
-	use pam && pamd_mimic_system vlock auth account
-}