Get Gentoo!
gentoo.org sites
gentoo.org Wiki Bugs Forums Packages
Planet Archives Sources
Infra Status
summaryrefslogtreecommitdiff
path: root/www-client/seamonkey
diff options
context:
space:
mode:
Diffstat (limited to 'www-client/seamonkey')
-rw-r--r--www-client/seamonkey/Manifest3
-rw-r--r--www-client/seamonkey/seamonkey-2.53.11.1.ebuild543
2 files changed, 546 insertions, 0 deletions
diff --git a/www-client/seamonkey/Manifest b/www-client/seamonkey/Manifest
index 1802bd9fe763..fef07ea1e815 100644
--- a/www-client/seamonkey/Manifest
+++ b/www-client/seamonkey/Manifest
@@ -3,6 +3,9 @@ DIST seamonkey-2.53.10.2.source-l10n.tar.xz 13616204 BLAKE2B 75e3efd51fa4628b385
DIST seamonkey-2.53.10.2.source.tar.xz 284350364 BLAKE2B 15ff60b5728b84c00831d4dccde7600648889d56ecbe034708390cd83d096f760157d84f5df266ede2d4388302b0df83684397c276e1a0f6d1dfe3e799265ca1 SHA512 59233c2bfc0cf3c9e290e1165fea4cd285cabb339f66dbad7bdbe0b7fd9b2acbc37c385b775d2a3d045d1a6648012488cc018eb3f879139c2a582e7d37e01d7a
DIST seamonkey-2.53.11-patches-02.tar.gz 90646 BLAKE2B 047beb0a9c73c9d85d628139d4169ce91451df71e24aa4f920d5d509c53458e19b71b9cb58254707512445639a1aaf606e96b1c0d4e9eda67240217d36501b9e SHA512 5584fd0b565c56bf2223389bdbf11ff9df424e9eeac44105f1d493d958068e0fae2235bf34ea174600f85efecc1dd06b746f7b86f99d56f375b4127a3a933684
DIST seamonkey-2.53.11-r1-patches.tar.gz 91301 BLAKE2B 8542270445aabc585ae6a4b61048f267241efbcee1c88c345b04e13c4850efe03d4fccc5a2dff66422630de70d68de88693a2836de27028f20d9eba21c029373 SHA512 3477901be183f9d10ea2b449f2cb3d71f8ee1dd9279a05269eaa2a9387475520e781284295d1987bf6b783d8342c55e40a8387729ee1c291b5be89f7c1e3ee6e
+DIST seamonkey-2.53.11.1-patches.tar.gz 92215 BLAKE2B e3fdbb4ab40c2ad37c9197ebe759a3f75cf8f95ca7448cf650262d4f7e9cad5adb1137e8360ddc23b9bc3516f3c26cb1cf5725206bfe5e2c869db7644bdaf779 SHA512 3c46c7c01ed4f7ef43f5628a0260c3bca730ed885cd1a798848ebd7f04cb0f2e576b80e4b4015a5c59140c78babb4d8325379bc67ee8e5a9280473baebe82650
+DIST seamonkey-2.53.11.1.source-l10n.tar.xz 13626448 BLAKE2B 4dc2de15273b8b5a5e2572c7275d4172151d551348bb8481006d6917faf2814b582796ec6a74cc147299a9466d5de2c3cf3305ed61c70543e7e20047de0612ed SHA512 a20f692366a000418161521a18d696880b62f2f9a8aab95d470626fcfe52798cf5da41df4ba61d2598fdf6ec0d54218988351b3c778fd189957c791442eb6d44
+DIST seamonkey-2.53.11.1.source.tar.xz 287864844 BLAKE2B 9ca1824ea1ee142237d88a94e7c1705cc1e7e043379b961f22ebb491f3cb9a46fed0685e593c2359ced1803604cd7e2adbfe19c9bc2bd8d676c3c9d39f7a4ce0 SHA512 e5450b9ca24693bf3e74e4ca3a8bba45c4a0b2ef0cc7c8d77f1f155dcf571478da1abb22bb572b37be27051a4d592f1f95de5940b6f24fd3b994eb93cb154f2f
DIST seamonkey-2.53.11.source-l10n.tar.xz 13626448 BLAKE2B 4dc2de15273b8b5a5e2572c7275d4172151d551348bb8481006d6917faf2814b582796ec6a74cc147299a9466d5de2c3cf3305ed61c70543e7e20047de0612ed SHA512 a20f692366a000418161521a18d696880b62f2f9a8aab95d470626fcfe52798cf5da41df4ba61d2598fdf6ec0d54218988351b3c778fd189957c791442eb6d44
DIST seamonkey-2.53.11.source.tar.xz 287567152 BLAKE2B 96f89360948169a6ac650cec331f29026ac5dea40e953422f54ff2410dab0c49f883ca650f12514db2bc458bc2d58e6e3f3b6c9e75717ed2f8818cd35529215e SHA512 5a9b1f0f638dd08654b8e0654f5a87cc269e29cfe1efe7b9707fe306398354c95018317c826f7523e33bec50cf72e1ba33a0a1eb216568f62f02bd95eb1eaf16
DIST seamonkey-2.53.3-system_libvpx-1.8.patch.gz 3197 BLAKE2B 7a84d2184f4812eabfe3626eb6b2364f2f8c0ba24d4e53440e9d38658b89a3f1c23bdcbd623fd9aca3bfd04743e582587e9c42ba3d983cc9ec4059ea9503830a SHA512 ffc6f179f07cb9dcce2924c64bfed84a5cc724d857b32e5e349967e72022536c5192c3966e1089bab8efd91671584d6474334730ebefe1c4398f564a5f1753be
diff --git a/www-client/seamonkey/seamonkey-2.53.11.1.ebuild b/www-client/seamonkey/seamonkey-2.53.11.1.ebuild
new file mode 100644
index 000000000000..1b63a5976dc5
--- /dev/null
+++ b/www-client/seamonkey/seamonkey-2.53.11.1.ebuild
@@ -0,0 +1,543 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+WANT_AUTOCONF="2.1"
+
+PYTHON_COMPAT=( python3_{8..10} )
+PYTHON_REQ_USE='ncurses,sqlite,ssl,threads(+)'
+
+# This list can be updated with scripts/get_langs.sh from the mozilla overlay
+# note - could not roll langpacks for: ca fi
+#MOZ_LANGS=(ca cs de en-GB es-AR es-ES fi fr gl hu it ja lt nb-NO nl pl pt-PT
+# ru sk sv-SE tr uk zh-CN zh-TW)
+MOZ_LANGS=(cs de en-GB es-AR es-ES fr hu it ja lt nl pl pt-PT
+ ru sk sv-SE zh-CN zh-TW)
+
+MOZ_PV="${PV/_pre*}"
+MOZ_PV="${MOZ_PV/_alpha/a}"
+MOZ_PV="${MOZ_PV/_beta/b}"
+MOZ_PV="${MOZ_PV/_rc/rc}"
+MOZ_P="${P}"
+MY_MOZ_P="${PN}-${MOZ_PV}"
+PATCH="${PN}-${PV}-patches"
+
+if [[ ${PV} == *_pre* ]] ; then
+ MOZ_HTTP_URI="https://archive.mozilla.org/pub/${PN}/candidates/${MOZ_PV}-candidates/build${PV##*_pre}"
+else
+ MOZ_HTTP_URI="https://archive.mozilla.org/pub/${PN}/releases/${MOZ_PV}"
+fi
+
+SRC_URI="${MOZ_HTTP_URI}/source/${MY_MOZ_P}.source.tar.xz -> ${P}.source.tar.xz
+ ${MOZ_HTTP_URI}/source/${MY_MOZ_P}.source-l10n.tar.xz -> ${P}.source-l10n.tar.xz
+ https://github.com/BioMike/gentoo-${PN}-patches/archive/refs/tags/${PV}.tar.gz -> ${PATCH}.tar.gz"
+
+S="${WORKDIR}/${MY_MOZ_P}"
+
+MOZ_GENERATE_LANGPACKS=1
+MOZ_L10N_SOURCEDIR="${S}/${P}-l10n"
+inherit autotools check-reqs desktop edos2unix flag-o-matic mozcoreconf-v6 mozlinguas-v2 pax-utils toolchain-funcs xdg-utils
+
+DESCRIPTION="Seamonkey Web Browser"
+HOMEPAGE="https://www.seamonkey-project.org/"
+
+LICENSE="MPL-2.0 GPL-2 LGPL-2.1"
+SLOT="0"
+SYSTEM_IUSE=( +system-{av1,harfbuzz,icu,jpeg,libevent,libvpx,png,sqlite} )
+IUSE="+chatzilla cpu_flags_arm_neon +crypt dbus debug +gmp-autoupdate +ipc jack
+lto pulseaudio selinux startup-notification test wifi"
+IUSE+=" ${SYSTEM_IUSE[@]}"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+ app-arch/unzip
+ app-arch/zip
+ >=dev-lang/nasm-2.13
+ dev-lang/perl
+ >=sys-devel/binutils-2.16.1
+ virtual/pkgconfig
+ >=virtual/rust-1.58.1
+ amd64? ( >=dev-lang/yasm-1.1 )
+ lto? ( sys-devel/binutils[gold] )
+ x86? ( >=dev-lang/yasm-1.1 )
+"
+COMMON_DEPEND="
+ app-arch/bzip2
+ >=app-text/hunspell-1.5.4:=
+ dev-libs/atk
+ >=dev-libs/glib-2.26:2
+ >=dev-libs/libffi-3.0.10:=
+ >=dev-libs/nspr-4.23
+ >=dev-libs/nss-3.47.1
+ media-libs/fontconfig
+ >=media-libs/freetype-2.4.10
+ >=media-libs/mesa-10.2:=
+ >=sys-libs/zlib-1.2.3
+ >=x11-libs/cairo-1.10[X]
+ x11-libs/gdk-pixbuf
+ >=x11-libs/gtk+-3.4.0:3
+ x11-libs/libX11
+ x11-libs/libXcomposite
+ x11-libs/libXdamage
+ x11-libs/libXext
+ x11-libs/libXfixes
+ x11-libs/libXrender
+ x11-libs/libXt
+ x11-libs/libxcb:=
+ >=x11-libs/pango-1.22.0
+ >=x11-libs/pixman-0.19.2
+ media-video/ffmpeg
+ virtual/freedesktop-icon-theme
+ dbus? (
+ >=dev-libs/dbus-glib-0.72
+ >=sys-apps/dbus-0.60
+ )
+ jack? ( virtual/jack )
+ crypt? ( <x11-plugins/enigmail-2.1.0 )
+ kernel_linux? ( !pulseaudio? ( media-libs/alsa-lib ) )
+ pulseaudio? ( || (
+ media-sound/pulseaudio
+ >=media-sound/apulse-0.1.9
+ ) )
+ startup-notification? ( >=x11-libs/startup-notification-0.8 )
+ system-av1? (
+ >=media-libs/dav1d-0.3.0:=
+ >=media-libs/libaom-1.0.0:=
+ )
+ system-harfbuzz? (
+ >=media-gfx/graphite2-1.3.9-r1
+ >=media-libs/harfbuzz-1.3.3:0=
+ )
+ system-icu? ( >=dev-libs/icu-59.1:= )
+ system-jpeg? ( >=media-libs/libjpeg-turbo-1.2.1 )
+ system-libevent? ( >=dev-libs/libevent-2.0:0= )
+ system-libvpx? ( >=media-libs/libvpx-1.8.0:0=[postproc] )
+ system-png? ( >=media-libs/libpng-1.6.31:0=[apng] )
+ system-sqlite? ( >=dev-db/sqlite-3.36.0:3[secure-delete,debug=] )
+ wifi? (
+ kernel_linux? (
+ >=dev-libs/dbus-glib-0.72
+ net-misc/networkmanager
+ >=sys-apps/dbus-0.60
+ )
+ )
+"
+RDEPEND="${COMMON_DEPEND}
+ selinux? ( sec-policy/selinux-mozilla )
+"
+DEPEND="${COMMON_DEPEND}
+ amd64? ( virtual/opengl )
+ x86? ( virtual/opengl )
+"
+
+# allow GMP_PLUGIN_LIST to be set in an eclass or
+# overridden in the enviromnent (advanced hackers only)
+[[ -z ${GMP_PLUGIN_LIST} ]] && GMP_PLUGIN_LIST=( gmp-gmpopenh264 gmp-widevinecdm )
+
+BUILD_OBJ_DIR="${S}/seamonk"
+
+pkg_setup() {
+ if [[ ${PV} == *_beta* ]] || [[ ${PV} == *_pre* ]] ; then
+ ewarn
+ ewarn "You're using an unofficial release of ${PN}. Don't file any bug in"
+ ewarn "Gentoo's Bugtracker against this package in case it breaks for you."
+ ewarn "Those belong to upstream: https://bugzilla.mozilla.org"
+ fi
+
+ if use crypt ; then
+ ewarn
+ ewarn "Enigmail has dropped support for Seamonkey in early 2019. If you are still"
+ ewarn "using it, consider yourself lucky, but also consider to start migrating away"
+ ewarn "from it. The crypt USE flag and its x11-plugins/enigmail dependency will be"
+ ewarn "removed in the near future."
+ ewarn
+ fi
+
+ moz_pkgsetup
+}
+
+pkg_pretend() {
+ # Ensure we have enough disk space to compile
+ if use debug || use lto || use test ; then
+ CHECKREQS_DISK_BUILD="16G"
+ else
+ CHECKREQS_DISK_BUILD="12G"
+ fi
+ check-reqs_pkg_setup
+}
+
+spkg_setup() {
+ # Ensure we have enough disk space to compile
+ if use debug || use lto || use test ; then
+ CHECKREQS_DISK_BUILD="16G"
+ else
+ CHECKREQS_DISK_BUILD="12G"
+ fi
+ check-reqs_pkg_setup
+}
+
+src_unpack() {
+ local l10n_sources="${P}.source-l10n.tar.xz"
+ unpack ${A/ ${l10n_sources}}
+
+ mkdir "${S}/${P}-l10n" || die
+ cd "${S}/${P}-l10n" || die
+ unpack ${l10n_sources}
+}
+
+src_prepare() {
+ # Apply our patches
+ eapply "${WORKDIR}"/gentoo-${PN}-patches-${PV}/${PN}
+
+ # Shell scripts sometimes contain DOS line endings; bug 391889
+ grep -rlZ --include="*.sh" $'\r$' . |
+ while read -r -d $'\0' file ; do
+ einfo edos2unix "${file}"
+ edos2unix "${file}"
+ done
+
+ use system-libvpx && eapply -p2 "${WORKDIR}"/gentoo-${PN}-patches-${PV}/USE_flag/1009_seamonkey-2.53.3-system_libvpx-1.8.patch
+
+ # Allow user to apply any additional patches without modifing ebuild
+ eapply_user
+
+ # Enable gnomebreakpad
+ if use debug ; then
+ sed -i -e "s:GNOME_DISABLE_CRASH_DIALOG=1:GNOME_DISABLE_CRASH_DIALOG=0:g" \
+ build/unix/run-mozilla.sh || die
+ fi
+
+ # Ensure that are plugins dir is enabled as default
+ sed -i -e "s:/usr/$(get_libdir)/mozilla/plugins:/usr/$(get_libdir)/${PN}/plugins:" \
+ xpcom/io/nsAppFileLocationProvider.cpp || die
+
+ # Don't exit with error when some libs are missing which we have in
+ # system.
+ sed '/^MOZ_PKG_FATAL_WARNINGS/s@= 1@= 0@' \
+ -i comm/suite/installer/Makefile.in || die
+ # Don't error out when there's no files to be removed:
+ sed 's@\(xargs rm\)$@\1 -f@' \
+ -i toolkit/mozapps/installer/packager.mk || die
+
+ # Don't build libs-% locale files for chatzilla if we are not building chatzilla
+ # (this is hard-coded in the build system at present rather than being based on configuration)
+ if ! use chatzilla ; then
+ sed '/extensions\/irc\/locales libs-/s@^@#@' \
+ -i comm/suite/locales/Makefile.in || die
+ fi
+
+ eautoreconf old-configure.in
+ cd js/src || die
+ eautoconf old-configure.in
+}
+
+src_configure() {
+ # Google API keys (see http://www.chromium.org/developers/how-tos/api-keys)
+ # Note: These are for Gentoo Linux use ONLY. For your own distribution, please
+ # get your own set of keys.
+ _google_api_key=AIzaSyDEAOvatFo0eTgsV_ZlEzx0ObmepsMzfAc
+
+ ######################################
+ #
+ # mozconfig, CFLAGS and CXXFLAGS setup
+ #
+ ######################################
+
+ mozconfig_init
+
+ ##################################
+ # Former mozconfig_config() part #
+ ##################################
+
+ # Migrated from mozcoreconf-2
+ mozconfig_annotate 'system_libs' --with-system-bz2
+ mozconfig_annotate 'system_libs' --with-system-zlib
+
+ # Disable for testing purposes only
+ mozconfig_annotate 'Upstream bug 1341234' --disable-stylo
+
+ # Must pass release in order to properly select linker via gold useflag
+ mozconfig_annotate 'Enable by Gentoo' --enable-release
+
+ # Must pass --enable-gold if using ld.gold
+ if tc-ld-is-gold ; then
+ mozconfig_annotate 'tc-ld-is-gold=true' --enable-gold
+ else
+ mozconfig_annotate 'tc-ld-is-gold=false' --disable-gold
+ fi
+
+ # Enable position independent executables
+ mozconfig_annotate 'enabled by Gentoo' --enable-pie
+
+ mozconfig_use_enable debug
+ mozconfig_use_enable debug tests
+ if use debug ; then
+ mozconfig_annotate 'enabled by Gentoo' --enable-debug-symbols
+ else
+ mozconfig_annotate 'disabled by Gentoo' --disable-debug-symbols
+ fi
+
+ mozconfig_use_enable startup-notification
+
+ # wifi pulls in dbus so manage both here
+ mozconfig_use_enable wifi necko-wifi
+ if use kernel_linux && use wifi && ! use dbus ; then
+ echo "Enabling dbus support due to wifi request"
+ mozconfig_annotate 'dbus required by necko-wifi on linux' --enable-dbus
+ else
+ mozconfig_use_enable dbus
+ mozconfig_annotate 'disabled' --disable-necko-wifi
+ fi
+
+ # These are enabled by default in all mozilla applications
+ mozconfig_annotate '' --with-system-nspr --with-nspr-prefix="${ESYSROOT}"/usr
+ mozconfig_annotate '' --with-system-nss --with-nss-prefix="${ESYSROOT}"/usr
+ mozconfig_annotate '' --x-includes="${ESYSROOT}"/usr/include --x-libraries="${ESYSROOT}"/usr/$(get_libdir)
+ if use system-libevent ; then
+ mozconfig_annotate '' --with-system-libevent="${ESYSROOT}"/usr
+ fi
+ mozconfig_annotate '' --prefix="${EPREFIX}"/usr
+ mozconfig_annotate '' --libdir="${EPREFIX}"/usr/$(get_libdir)
+ mozconfig_annotate 'Gentoo default' --enable-system-hunspell
+ mozconfig_annotate '' --disable-crashreporter
+ mozconfig_annotate '' --enable-system-ffi
+ mozconfig_annotate '' --disable-gconf
+ mozconfig_annotate '' --with-intl-api
+
+ # default toolkit is cairo-gtk3, optional use flags can change this
+ mozconfig_annotate '' --enable-default-toolkit=cairo-gtk3
+
+ # Instead of the standard --build= and --host=, mozilla uses --host instead
+ # of --build, and --target intstead of --host.
+ # Note, mozilla also has --build but it does not do what you think it does.
+ # Set both --target and --host as mozilla uses python to guess values otherwise
+ mozconfig_annotate '' --target="${CHOST}"
+ mozconfig_annotate '' --host="${CBUILD:-${CHOST}}"
+
+ mozconfig_use_enable pulseaudio
+ # force the deprecated alsa sound code if pulseaudio is disabled
+ if use kernel_linux && ! use pulseaudio ; then
+ mozconfig_annotate '-pulseaudio' --enable-alsa
+ fi
+
+ # For testing purpose only
+ mozconfig_annotate 'Sandbox' --enable-content-sandbox
+
+ mozconfig_use_enable system-sqlite
+ mozconfig_use_with system-jpeg
+ mozconfig_use_with system-icu
+ mozconfig_use_with system-libvpx
+ mozconfig_use_with system-png
+ mozconfig_use_with system-harfbuzz
+ mozconfig_use_with system-harfbuzz system-graphite2
+ mozconfig_use_with system-av1
+
+ # Modifications to better support ARM, bug 553364
+ if use cpu_flags_arm_neon ; then
+ mozconfig_annotate '' --with-fpu=neon
+ mozconfig_annotate '' --with-thumb=yes
+ mozconfig_annotate '' --with-thumb-interwork=no
+ fi
+ if [[ ${CHOST} == armv* ]] ; then
+ mozconfig_annotate '' --with-float-abi=hard
+ if ! use system-libvpx ; then
+ sed -i -e "s|softfp|hard|" media/libvpx/moz.build || die
+ fi
+ fi
+
+ if use lto ; then
+ # Linking only works when using ld.gold when LTO is enabled
+ mozconfig_annotate "forcing ld=gold due to USE=lto" --enable-linker=gold
+ # ThinLTO is currently broken, see bmo#1644409
+ mozconfig_annotate '+lto' --enable-lto=full
+ else
+ if tc-ld-is-gold ; then
+ mozconfig_annotate "linker is set to gold" --enable-linker=gold
+ else
+ mozconfig_annotate "linker is set to bfd" --enable-linker=bfd
+ fi
+ fi
+ # LTO flag was handled via configure
+ filter-flags '-flto*'
+
+ ##################################
+ # Former mozconfig_config() end #
+ ##################################
+
+ # enable JACK, bug 600002
+ mozconfig_use_enable jack
+
+ # It doesn't compile on alpha without this LDFLAGS
+ use alpha && append-ldflags "-Wl,--no-relax"
+
+ # Linking fails without this due to memory exhaustion
+ use x86 && append-ldflags "-Wl,--no-keep-memory"
+
+ # Setup api key for location services
+ printf '%s' "${_google_api_key}" > "${S}"/google-api-key
+ mozconfig_annotate '' --with-google-location-service-api-keyfile="${S}/google-api-key"
+ mozconfig_annotate '' --with-google-safebrowsing-api-keyfile="${S}/google-api-key"
+
+ mozconfig_use_enable chatzilla irc
+ mozconfig_annotate '' --enable-dominspector
+
+ # use startup-cache for faster startup time
+ mozconfig_annotate '' --enable-startupcache
+
+ # Broken on some arches
+ mozconfig_annotate '' --disable-elf-hack
+
+ # Use an objdir to keep things organized.
+ echo "mk_add_options MOZ_OBJDIR=${BUILD_OBJ_DIR}" >> "${S}"/.mozconfig || die
+ echo "mk_add_options XARGS=/usr/bin/xargs" >> "${S}"/.mozconfig || die
+
+ mozlinguas_mozconfig
+
+ # Finalize and report settings
+ mozconfig_final
+
+ # Work around breakage in makeopts with --no-print-directory
+ MAKEOPTS="${MAKEOPTS/--no-print-directory/}"
+
+ if [[ $(gcc-major-version) -lt 4 ]] ; then
+ append-cxxflags -fno-stack-protector
+ elif [[ $(gcc-major-version) -gt 4 || $(gcc-minor-version) -gt 3 ]] ; then
+ if use amd64 || use x86 ; then
+ append-flags -mno-avx
+ fi
+ fi
+
+ # Pass $MAKEOPTS to build system
+ export MOZ_MAKE_FLAGS="${MAKEOPTS}"
+ # Use system's Python environment
+ export MACH_USE_SYSTEM_PYTHON=1
+ # Disable notification when build system has finished
+ export MOZ_NOSPAM=1
+
+ # workaround for funky/broken upstream configure...
+ export SHELL="${SHELL:-${EPREFIX}/bin/bash}"
+ #emake V=1 -f client.mk configure
+ ./mach configure || die
+}
+
+src_compile() {
+ #MOZ_MAKE_FLAGS="${MAKEOPTS}" SHELL="${SHELL}" \
+ #emake V=1 -f client.mk
+ ./mach build --verbose || die
+
+ mozlinguas_src_compile
+}
+
+src_install() {
+ MOZILLA_FIVE_HOME="/usr/$(get_libdir)/${PN}"
+ DICTPATH="\"${EPREFIX}/usr/share/myspell\""
+
+ local emid
+ pushd "${BUILD_OBJ_DIR}" &>/dev/null || die
+
+ # Pax mark xpcshell for hardened support, only used for startupcache creation.
+ pax-mark m dist/bin/xpcshell
+
+ # Copy our preference before omnijar is created.
+ sed "s|SEAMONKEY_PVR|${PVR}|" "${FILESDIR}"/all-gentoo-1.js > \
+ dist/bin/defaults/pref/all-gentoo.js \
+ || die
+
+ # Set default path to search for dictionaries.
+ echo "pref(\"spellchecker.dictionary_path\", ${DICTPATH});" \
+ >> dist/bin/defaults/pref/all-gentoo.js \
+ || die
+
+ echo 'pref("extensions.autoDisableScopes", 3);' >> \
+ dist/bin/defaults/pref/all-gentoo.js \
+ || die
+
+ local plugin
+ if ! use gmp-autoupdate ; then
+ for plugin in "${GMP_PLUGIN_LIST[@]}" ; do
+ echo "pref(\"media.${plugin}.autoupdate\", false);" >> \
+ dist/bin/defaults/pref/all-gentoo.js || die
+ done
+ fi
+
+ popd &>/dev/null || die
+
+ #MOZ_MAKE_FLAGS="${MAKEOPTS}" SHELL="${SHELL:-${EPREFIX}/bin/bash}" \
+ #emake DESTDIR="${D}" install
+ DESTDIR="${D}" ./mach install || die
+ MOZ_P="${MY_MOZ_P}" mozlinguas_src_install
+
+ cp "${FILESDIR}"/${PN}.desktop "${T}" || die
+
+ sed 's|^\(MimeType=.*\)$|\1text/x-vcard;text/directory;application/mbox;message/rfc822;x-scheme-handler/mailto;|' \
+ -i "${T}"/${PN}.desktop || die
+ sed 's|^\(Categories=.*\)$|\1Email;|' -i "${T}"/${PN}.desktop \
+ || die
+
+ # Install icon and .desktop for menu entry
+ newicon "${S}"/comm/suite/branding/${PN}/default64.png ${PN}.png
+ domenu "${T}"/${PN}.desktop
+
+ # Required in order to use plugins and even run seamonkey on hardened.
+ pax-mark m "${ED}"/${MOZILLA_FIVE_HOME}/{seamonkey,seamonkey-bin,plugin-container}
+
+ if use chatzilla ; then
+ local emid='{59c81df5-4b7a-477b-912d-4e0fdf64e5f2}'
+
+ # remove the en_US-only xpi file so a version with all requested locales can be installed
+ if [[ -e "${ED}"/${MOZILLA_FIVE_HOME}/extensions/${emid}.xpi ]] ; then
+ rm -f "${ED}"/${MOZILLA_FIVE_HOME}/extensions/${emid}.xpi || die
+ fi
+
+ # merge the extra locales into the main extension
+ mozlinguas_xpistage_langpacks dist/xpi-stage/chatzilla
+
+ # install the merged extension
+ mkdir -p "${T}/${emid}" || die
+ cp -RLp -t "${T}/${emid}" dist/xpi-stage/chatzilla/* || die
+ insinto ${MOZILLA_FIVE_HOME}/extensions
+ doins -r "${T}/${emid}"
+ fi
+
+ # Provide a place for plugins
+ keepdir "${MOZILLA_FIVE_HOME}/plugins"
+
+ # revdep-rebuild entry
+ insinto /etc/revdep-rebuild
+ echo "SEARCH_DIRS_MASK=${MOZILLA_FIVE_HOME}*" >> ${T}/11${PN} || die
+ doins "${T}"/11${PN}
+}
+
+pkg_preinst() {
+ SEAMONKEY_PLUGINS_DIR="${EROOT}/usr/$(get_libdir)/${PN}/plugins"
+
+ if [[ -L "${SEAMONKEY_PLUGINS_DIR}" ]] ; then
+ rm "${SEAMONKEY_PLUGINS_DIR}" || die
+ fi
+}
+
+pkg_postinst() {
+ # Update mimedb for the new .desktop file
+ xdg_desktop_database_update
+
+ if ! use gmp-autoupdate ; then
+ elog "USE='-gmp-autoupdate' has disabled the following plugins from updating or"
+ elog "installing into new profiles:"
+ local plugin
+ for plugin in "${GMP_PLUGIN_LIST[@]}"; do
+ elog "\t ${plugin}" ;
+ done
+ fi
+
+ if use chatzilla ; then
+ elog "chatzilla is now an extension which can be en-/disabled and configured via"
+ elog "the Add-on manager."
+ fi
+}
+
+pkg_postrm() {
+ xdg_desktop_database_update
+}