From b1f3fc559fd26489d5e9658065f8a2fffd33a636 Mon Sep 17 00:00:00 2001
From: "Robin H. Johnson" <robbat2@gentoo.org>
Date: Sat, 23 Sep 2023 15:46:08 -0700
Subject: dev-libs/xapian: bump

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
---
 dev-libs/xapian/Manifest             |  1 +
 dev-libs/xapian/xapian-1.4.23.ebuild | 67 ++++++++++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)
 create mode 100644 dev-libs/xapian/xapian-1.4.23.ebuild

(limited to 'dev-libs/xapian')

diff --git a/dev-libs/xapian/Manifest b/dev-libs/xapian/Manifest
index e2eaea148e9b..84d8efdcab8f 100644
--- a/dev-libs/xapian/Manifest
+++ b/dev-libs/xapian/Manifest
@@ -1 +1,2 @@
 DIST xapian-core-1.4.22.tar.xz 3019608 BLAKE2B f4aec86cd5f63f6f1825a4f8f427ea23be2092ffb4ca11a2fdf20bdf652e7b9f768b1155bcf7ee5e5c5313206c92e1725d1b4d562e3074539a2e8f9901c44f8e SHA512 60d66adbacbd59622d25e392060984bd1dc6c870f9031765f54cb335fb29f72f6d006d27af82a50c8da2cfbebd08dac4503a8afa8ad51bc4e6fa9cb367a59d29
+DIST xapian-core-1.4.23.tar.xz 3024644 BLAKE2B e26a9fd5e79daf553b474e3c794178df2cdcd83ce7d7a45ae112dde624d6e7add157c76fda3a333afce6103b2edaf7e3c928e78c47aa1fd19821c3c73926442f SHA512 52dffc93301f99aa150dda8ecd5fb7cc7d0f2ce30e60f393b1058055ade24281af16cf5b5c0e6b08e4754e3d18c39bb5bc068b19330a294ad460ef8a6bc56380
diff --git a/dev-libs/xapian/xapian-1.4.23.ebuild b/dev-libs/xapian/xapian-1.4.23.ebuild
new file mode 100644
index 000000000000..40a621af6000
--- /dev/null
+++ b/dev-libs/xapian/xapian-1.4.23.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="${PN}-core-${PV}"
+
+DESCRIPTION="Xapian Probabilistic Information Retrieval library"
+HOMEPAGE="https://xapian.org/"
+SRC_URI="https://oligarchy.co.uk/xapian/${PV}/${MY_P}.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0/30" # ABI version of libxapian.so
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos ~x64-solaris"
+IUSE="doc static-libs cpu_flags_x86_sse cpu_flags_x86_sse2 +inmemory +remote"
+
+DEPEND="
+	sys-apps/util-linux
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}"
+
+DOCS="AUTHORS HACKING PLATFORMS README NEWS"
+
+src_configure() {
+	local -a myconf
+
+	if use cpu_flags_x86_sse2; then
+		myconf+=( --enable-sse=sse2 )
+	else
+		if use cpu_flags_x86_sse; then
+			myconf+=( --enable-sse=sse )
+		else
+			myconf+=( --disable-sse )
+		fi
+	fi
+
+	myconf+=( $(use_enable static-libs static) )
+
+	use inmemory || myconf+=( --disable-backend-inmemory )
+	use remote || myconf+=( --disable-backend-remote )
+
+	myconf+=(
+		--enable-backend-glass
+		--enable-backend-chert
+		--program-suffix=
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_test() {
+	emake check VALGRIND=
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	if ! use doc; then
+		rm -r "${ED}/usr/share/doc/${PF}" || die
+	fi
+
+	einstalldocs
+
+	find "${ED}" -name "*.la" -type f -delete || die
+}
-- 
cgit v1.2.3-65-gdbad