From 3ed19ed685f4289ee25663540dc6483f3458982d Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Thu, 16 Nov 2023 01:41:05 +0100
Subject: dev-qt/qtsql: Bump to QT5_KDEPATCHSET_REV=3

Christian Ehrlicher (1):
      SQL/MySQL: properly initialize variable

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 dev-qt/qtsql/Manifest                |  1 +
 dev-qt/qtsql/qtsql-5.15.11-r1.ebuild | 56 ++++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 dev-qt/qtsql/qtsql-5.15.11-r1.ebuild

(limited to 'dev-qt/qtsql')

diff --git a/dev-qt/qtsql/Manifest b/dev-qt/qtsql/Manifest
index 177ba1d88159..ec817fb78264 100644
--- a/dev-qt/qtsql/Manifest
+++ b/dev-qt/qtsql/Manifest
@@ -1,3 +1,4 @@
 DIST qtbase-5.15-gentoo-patchset-4.tar.xz 4884 BLAKE2B ef1f11ea63084b834e19a9bd4c4a146e0d47f10e6c1f540a23db64ba6b0d42f46d63f54f93587deae9ac528f6824fa0e88177fe109a53aaee7d8328d49e364cd SHA512 1ae6630cef6bead9187aaaf7c420566b2c1f946bfa22cb983c52267c098e9b1c7b82c99204cbd3eed5eb6ebde0359726e260fd449618802735af465ca39f0a1d
 DIST qtbase-5.15.11-gentoo-kde-1.tar.xz 324008 BLAKE2B 3ccd8645b5b727e4794fe4cb605d3db97159bf196b8e3e342ade364b701d6eb41e8e83ed608ec996480d7a82a43ddac098844dcecc9f122d63e9072abc21e9db SHA512 d145af982de89a34eaa15c5dc48ed927b5757e6a6d9bfa064a5cef40618465d7d6139ecaccb71944eac43926b977031034f6c22d4986f1e4a704007de9cb325d
+DIST qtbase-5.15.11-gentoo-kde-3.tar.xz 330732 BLAKE2B 2f783249ebbc2381861f1edec560877113a6f63977b856385977b114b654a21d3dd5d7daa8f2d93ab4549266ca75071dfc4f6fe3a7f8e2b3087e45001f5bb53f SHA512 df53c45bcf8f9dbcc8de91748c9b28b7d3d26b401800620ddc1cf244f6b500dd7e867394272f04348f58aa7aaed6e4e8c2edce694b6a6f465542d609f05ebd6e
 DIST qtbase-everywhere-opensource-src-5.15.11.tar.xz 50825756 BLAKE2B 663d370d46a17939b984ef4c541414b81acdb98a2b7e67bb202c46891f9675e921723a025cef88b54b6111f235d94e273b97e1b55e2ca52b91e3eebca5ff7161 SHA512 4136092eec7bdceba661eee0187b7952ed6ba819148295979c0fd0392c17b0178165fa20136bdf460509a815c96f43892403294ba6e5322c54c51459c358fb7f
diff --git a/dev-qt/qtsql/qtsql-5.15.11-r1.ebuild b/dev-qt/qtsql/qtsql-5.15.11-r1.ebuild
new file mode 100644
index 000000000000..bd98630aee7b
--- /dev/null
+++ b/dev-qt/qtsql/qtsql-5.15.11-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} != *9999* ]]; then
+	QT5_KDEPATCHSET_REV=3
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="SQL abstraction library for the Qt5 framework"
+
+SLOT=5/${QT5_PV} # bug 639140
+IUSE="freetds mysql oci8 odbc postgres +sqlite"
+REQUIRED_USE="
+	|| ( freetds mysql oci8 odbc postgres sqlite )
+"
+
+DEPEND="
+	=dev-qt/qtcore-${QT5_PV}*:5=
+	freetds? ( dev-db/freetds )
+	mysql? ( dev-db/mysql-connector-c:= )
+	oci8? ( dev-db/oracle-instantclient:=[sdk] )
+	odbc? ( dev-db/unixODBC )
+	postgres? ( dev-db/postgresql:* )
+	sqlite? ( dev-db/sqlite:3 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/sql
+	src/plugins/sqldrivers
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:sql
+)
+
+src_configure() {
+	local myconf=(
+		$(qt_use freetds  sql-tds    plugin)
+		$(qt_use mysql    sql-mysql  plugin)
+		$(qt_use oci8     sql-oci    plugin)
+		$(qt_use odbc     sql-odbc   plugin)
+		$(qt_use postgres sql-psql   plugin)
+		$(qt_use sqlite   sql-sqlite plugin)
+		$(usev sqlite -system-sqlite)
+	)
+
+	use oci8 && myconf+=("-I${ORACLE_HOME}/include" "-L${ORACLE_HOME}/$(get_libdir)")
+
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3-65-gdbad