From 35680dd7a0565547f9c8926d87fa4ad17f02bd9b Mon Sep 17 00:00:00 2001
From: Andreas Sturmlechner <asturm@gentoo.org>
Date: Tue, 8 May 2018 20:01:22 +0200
Subject: dev-qt: Add Qt 5.11.0_rc

Package-Manager: Portage-2.3.36, Repoman-2.3.9
---
 dev-qt/qtwidgets/qtwidgets-5.11.0_rc.ebuild | 57 +++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 dev-qt/qtwidgets/qtwidgets-5.11.0_rc.ebuild

(limited to 'dev-qt/qtwidgets/qtwidgets-5.11.0_rc.ebuild')

diff --git a/dev-qt/qtwidgets/qtwidgets-5.11.0_rc.ebuild b/dev-qt/qtwidgets/qtwidgets-5.11.0_rc.ebuild
new file mode 100644
index 000000000000..caf1f79a84de
--- /dev/null
+++ b/dev-qt/qtwidgets/qtwidgets-5.11.0_rc.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qtbase"
+inherit qt5-build
+
+DESCRIPTION="Set of components for creating classic desktop-style UIs for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+fi
+
+# keep IUSE defaults in sync with qtgui
+IUSE="gles2 gtk +png +xcb"
+
+DEPEND="
+	~dev-qt/qtcore-${PV}
+	~dev-qt/qtgui-${PV}[gles2=,png=,xcb?]
+	gtk? (
+		~dev-qt/qtgui-${PV}[dbus]
+		x11-libs/gtk+:3
+		x11-libs/libX11
+		x11-libs/pango
+	)
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+	src/tools/uic
+	src/widgets
+	src/plugins/platformthemes
+)
+
+QT5_GENTOO_CONFIG=(
+	gtk:gtk3:
+	::widgets
+	!:no-widgets:
+)
+
+QT5_GENTOO_PRIVATE_CONFIG=(
+	:widgets
+)
+
+src_configure() {
+	local myconf=(
+		-opengl $(usex gles2 es2 desktop)
+		$(qt_use gtk)
+		-gui
+		$(qt_use png libpng system)
+		-widgets
+		$(qt_use xcb xcb system)
+		$(qt_use xcb xkbcommon system)
+		$(usex xcb '-xcb-xlib -xinput2 -xkb' '')
+	)
+	qt5-build_src_configure
+}
-- 
cgit v1.2.3-65-gdbad