From f129b754cc1545f29bfeca95272ca78307216987 Mon Sep 17 00:00:00 2001
From: Maciej Barć <xgqt@gentoo.org>
Date: Wed, 28 Feb 2024 21:53:14 +0100
Subject: dev-scheme/guile-ssh: add missing pkgconfig dependencies
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

as also declared inside this pkg guix.scm

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
---
 dev-scheme/guile-ssh/guile-ssh-0.16.4-r1.ebuild | 62 +++++++++++++++++++++++++
 dev-scheme/guile-ssh/guile-ssh-0.16.4.ebuild    | 50 --------------------
 2 files changed, 62 insertions(+), 50 deletions(-)
 create mode 100644 dev-scheme/guile-ssh/guile-ssh-0.16.4-r1.ebuild
 delete mode 100644 dev-scheme/guile-ssh/guile-ssh-0.16.4.ebuild

(limited to 'dev-scheme/guile-ssh')

diff --git a/dev-scheme/guile-ssh/guile-ssh-0.16.4-r1.ebuild b/dev-scheme/guile-ssh/guile-ssh-0.16.4-r1.ebuild
new file mode 100644
index 000000000000..5a331431ce4e
--- /dev/null
+++ b/dev-scheme/guile-ssh/guile-ssh-0.16.4-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Library providing access to the SSH protocol for GNU Guile"
+HOMEPAGE="https://memory-heap.org/~avp/projects/guile-ssh/
+	https://github.com/artyom-poptsov/guile-ssh/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/artyom-poptsov/${PN}.git"
+else
+	SRC_URI="https://github.com/artyom-poptsov/${PN}/archive/v${PV}.tar.gz
+		-> ${P}.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	>=dev-scheme/guile-2.0.0:=
+	net-libs/libssh:0=[server,sftp]
+"
+DEPEND="
+	${RDEPEND}
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
+PATCHES=(
+	"${FILESDIR}/${PN}-0.16.2-tests.patch"
+)
+
+# guile generates ELF files without use of C or machine code
+# It's a portage's false positive. bug #677600
+QA_PREBUILT='*[.]go'
+
+src_prepare() {
+	default
+	eautoreconf
+
+	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
+	find "${S}" -name "*.scm" -exec touch {} + || die
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name "*.la" -delete || die
+
+	# Workaround llvm-strip problem of mangling guile ELF debug
+	# sections: https://bugs.gentoo.org/905898
+	dostrip -x "/usr/$(get_libdir)/guile"
+}
diff --git a/dev-scheme/guile-ssh/guile-ssh-0.16.4.ebuild b/dev-scheme/guile-ssh/guile-ssh-0.16.4.ebuild
deleted file mode 100644
index bda391d671fb..000000000000
--- a/dev-scheme/guile-ssh/guile-ssh-0.16.4.ebuild
+++ /dev/null
@@ -1,50 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit autotools
-
-DESCRIPTION="Library providing access to the SSH protocol for GNU Guile"
-HOMEPAGE="https://memory-heap.org/~avp/projects/guile-ssh/
-	https://github.com/artyom-poptsov/guile-ssh/"
-SRC_URI="https://github.com/artyom-poptsov/${PN}/archive/v${PV}.tar.gz
-	-> ${P}.tar.gz"
-
-LICENSE="GPL-3+"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	>=dev-scheme/guile-2.0.0:=
-	net-libs/libssh:0=[server,sftp]
-"
-DEPEND="${RDEPEND}"
-
-DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.16.2-tests.patch
-)
-
-# guile generates ELF files without use of C or machine code
-# It's a portage's false positive. bug #677600
-QA_PREBUILT='*[.]go'
-
-src_prepare() {
-	default
-
-	# http://debbugs.gnu.org/cgi/bugreport.cgi?bug=38112
-	find "${S}" -name "*.scm" -exec touch {} + || die
-
-	eautoreconf
-}
-
-src_install() {
-	default
-
-	find "${ED}" -name "*.la" -delete || die
-
-	# Workaround llvm-strip problem of mangling guile ELF debug
-	# sections: https://bugs.gentoo.org/905898
-	dostrip -x "/usr/$(get_libdir)/guile"
-}
-- 
cgit v1.2.3-65-gdbad