From 54fec07e295015109b12f59526938847b9fcbca2 Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Tue, 30 Aug 2022 17:32:38 +0100
Subject: dev-util/cvise: drop -Werror, respect CFLAGS

Closes: https://bugs.gentoo.org/867424
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-util/cvise/cvise-2.5.0-r1.ebuild               | 76 ++++++++++++++++++++++
 dev-util/cvise/cvise-2.5.0.ebuild                  | 72 --------------------
 .../cvise/files/cvise-2.5.0-no-werror-cflags.patch | 34 ++++++++++
 3 files changed, 110 insertions(+), 72 deletions(-)
 create mode 100644 dev-util/cvise/cvise-2.5.0-r1.ebuild
 delete mode 100644 dev-util/cvise/cvise-2.5.0.ebuild
 create mode 100644 dev-util/cvise/files/cvise-2.5.0-no-werror-cflags.patch

(limited to 'dev-util/cvise')

diff --git a/dev-util/cvise/cvise-2.5.0-r1.ebuild b/dev-util/cvise/cvise-2.5.0-r1.ebuild
new file mode 100644
index 000000000000..ed819e732b93
--- /dev/null
+++ b/dev-util/cvise/cvise-2.5.0-r1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit cmake llvm python-single-r1
+
+DESCRIPTION="Super-parallel Python port of the C-Reduce"
+HOMEPAGE="https://github.com/marxin/cvise/"
+SRC_URI="
+	https://github.com/marxin/cvise/archive/v${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+LLVM_MAX_SLOT=15
+DEPEND="
+	|| (
+		sys-devel/clang:15
+		sys-devel/clang:14
+		sys-devel/clang:13
+	)
+	<sys-devel/clang-$(( LLVM_MAX_SLOT + 1 )):=
+"
+RDEPEND="
+	${DEPEND}
+	${PYTHON_DEPS}
+	$(python_gen_cond_dep '
+		dev-python/chardet[${PYTHON_USEDEP}]
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+	')
+	dev-util/unifdef
+	sys-devel/flex
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	sys-devel/flex
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/pebble[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.5.0-no-werror-cflags.patch
+)
+
+llvm_check_deps() {
+	has_version "sys-devel/clang:${LLVM_SLOT}"
+}
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	llvm_pkg_setup
+}
+
+src_test() {
+	cd "${BUILD_DIR}" || die
+	epytest
+}
+
+src_install() {
+	cmake_src_install
+
+	python_fix_shebang "${ED}"/usr/bin/cvise
+}
diff --git a/dev-util/cvise/cvise-2.5.0.ebuild b/dev-util/cvise/cvise-2.5.0.ebuild
deleted file mode 100644
index 05efec46a120..000000000000
--- a/dev-util/cvise/cvise-2.5.0.ebuild
+++ /dev/null
@@ -1,72 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{8..11} )
-
-inherit cmake llvm python-single-r1
-
-DESCRIPTION="Super-parallel Python port of the C-Reduce"
-HOMEPAGE="https://github.com/marxin/cvise/"
-SRC_URI="
-	https://github.com/marxin/cvise/archive/v${PV}.tar.gz -> ${P}.tar.gz
-"
-
-LICENSE="UoI-NCSA"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="test"
-RESTRICT="!test? ( test )"
-REQUIRED_USE=${PYTHON_REQUIRED_USE}
-
-LLVM_MAX_SLOT=15
-DEPEND="
-	|| (
-		sys-devel/clang:15
-		sys-devel/clang:14
-		sys-devel/clang:13
-	)
-	<sys-devel/clang-$(( LLVM_MAX_SLOT + 1 )):=
-"
-RDEPEND="
-	${DEPEND}
-	${PYTHON_DEPS}
-	$(python_gen_cond_dep '
-		dev-python/chardet[${PYTHON_USEDEP}]
-		dev-python/pebble[${PYTHON_USEDEP}]
-		dev-python/psutil[${PYTHON_USEDEP}]
-	')
-	dev-util/unifdef
-	sys-devel/flex
-"
-BDEPEND="
-	${PYTHON_DEPS}
-	sys-devel/flex
-	test? (
-		$(python_gen_cond_dep '
-			dev-python/pebble[${PYTHON_USEDEP}]
-			dev-python/pytest[${PYTHON_USEDEP}]
-		')
-	)
-"
-
-llvm_check_deps() {
-	has_version "sys-devel/clang:${LLVM_SLOT}"
-}
-
-pkg_setup() {
-	python-single-r1_pkg_setup
-	llvm_pkg_setup
-}
-
-src_test() {
-	cd "${BUILD_DIR}" || die
-	epytest
-}
-
-src_install() {
-	cmake_src_install
-
-	python_fix_shebang "${ED}"/usr/bin/cvise
-}
diff --git a/dev-util/cvise/files/cvise-2.5.0-no-werror-cflags.patch b/dev-util/cvise/files/cvise-2.5.0-no-werror-cflags.patch
new file mode 100644
index 000000000000..b00b524cb2a4
--- /dev/null
+++ b/dev-util/cvise/files/cvise-2.5.0-no-werror-cflags.patch
@@ -0,0 +1,34 @@
+https://bugs.gentoo.org/867424
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -146,13 +146,13 @@ if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU"
+     OR CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
+   # XXX figure out how to get "-std=c++14 -fno-rtti" from LLVM.  That's how we
+   # get those options in the Automake path...
+-  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Werror -Wno-error=maybe-uninitialized")
+-  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++14 -fno-rtti -fno-strict-aliasing -Wall -Wextra -Wno-unused-parameter -Werror -Wno-error=maybe-uninitialized")
++  set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wall -Wextra -Wno-error=maybe-uninitialized")
++  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++14 -fno-rtti -fno-strict-aliasing -Wall -Wextra -Wno-unused-parameter -Wno-error=maybe-uninitialized")
+   if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
+     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
+   endif()
+-  set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -O3")
+-  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELEASE} -O3")
++  set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
++  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELEASE}")
+ endif()
+ 
+ ###############################################################################
+diff --git a/CMakeLists.txt b/CMakeLists.txt
+index 261a0fb..cbaebc3 100644
+--- a/CMakeLists.txt
++++ b/CMakeLists.txt
+@@ -151,8 +151,6 @@ if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU"
+   if(SUPPORTS_FVISIBILITY_INLINES_HIDDEN_FLAG)
+     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility-inlines-hidden")
+   endif()
+-  set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
+-  set(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELEASE}")
+ endif()
+ 
+ ###############################################################################
-- 
cgit v1.2.3-65-gdbad