From 24fd1deb6d47c3230b6ce1aa748c2ddd59d972c5 Mon Sep 17 00:00:00 2001
From: "Anthony G. Basile" <blueness@gentoo.org>
Date: Wed, 13 Jul 2016 11:49:54 -0400
Subject: net-analyzer/echoping: add libressl support

Package-Manager: portage-2.2.28
---
 .../echoping/echoping-6.0.2_p434-r3.ebuild         | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)
 create mode 100644 net-analyzer/echoping/echoping-6.0.2_p434-r3.ebuild

(limited to 'net-analyzer')

diff --git a/net-analyzer/echoping/echoping-6.0.2_p434-r3.ebuild b/net-analyzer/echoping/echoping-6.0.2_p434-r3.ebuild
new file mode 100644
index 000000000000..cfb0b9275971
--- /dev/null
+++ b/net-analyzer/echoping/echoping-6.0.2_p434-r3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils
+
+DESCRIPTION="Small program to test performances of remote servers"
+HOMEPAGE="http://echoping.sourceforge.net/"
+SRC_URI="https://dev.gentoo.org/~jer/${P}.tar.gz"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="libressl gnutls http icp idn priority smtp ssl tos postgres ldap"
+RESTRICT="test"
+
+RDEPEND="idn? ( net-dns/libidn )
+	postgres? ( dev-db/postgresql:* )
+	ldap? ( net-nds/openldap )
+	ssl? (
+		gnutls? ( >=net-libs/gnutls-3.3:= )
+		!gnutls? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:0= )
+		)
+	)"
+DEPEND="${RDEPEND}
+	>=sys-devel/libtool-2"
+
+REQUIRED_USE="gnutls? ( ssl )"
+
+DOCS=( README AUTHORS ChangeLog DETAILS NEWS TODO )
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-6.0.2_p434-fix_implicit_declarations.patch
+	epatch "${FILESDIR}"/${PN}-6.0.2_p434-gnutls_certificate_type_set_priority.patch
+	epatch "${FILESDIR}"/${PN}-6.0.2_p434-gnutls_session.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable http)  \
+		$(use_enable icp) \
+		$(use_enable priority) \
+		$(use_enable smtp) \
+		$(use_enable tos) \
+		$(use_with idn libidn) \
+		$(usex gnutls $(use_with gnutls) $(use_with ssl)) \
+		--config-cache \
+		--disable-static \
+		--disable-ttcp
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}
-- 
cgit v1.2.3-65-gdbad