From 9ca6c5a9c3cdf807a0aaa54ed736df5db2d01dab Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Sat, 9 Nov 2019 14:09:24 +0100
Subject: net-dns/ndu: Bump to EAPI 7
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/697252
Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 net-dns/ndu/ndu-0.4-r4.ebuild | 50 +++++++++++++++++++++----------------------
 1 file changed, 25 insertions(+), 25 deletions(-)

(limited to 'net-dns')

diff --git a/net-dns/ndu/ndu-0.4-r4.ebuild b/net-dns/ndu/ndu-0.4-r4.ebuild
index b64497eb415c..78c645acef4f 100644
--- a/net-dns/ndu/ndu-0.4-r4.ebuild
+++ b/net-dns/ndu/ndu-0.4-r4.ebuild
@@ -1,54 +1,54 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=0
+EAPI=7
 
-inherit eutils toolchain-funcs
+inherit toolchain-funcs
 
 DESCRIPTION="DNS serial number incrementer and reverse zone builder"
 SRC_URI="http://uranus.it.swin.edu.au/~jn/linux/${P}.tar.gz"
 HOMEPAGE="https://wiki.gentoo.org/wiki/No_homepage"
+
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="amd64 ppc x86"
 IUSE=""
-DEPEND="sys-apps/sed"
+
 RDEPEND="sys-apps/ed" # dnstouch calls ed to do the dirty work
 
-src_unpack() {
-	unpack ${A}
+src_prepare() {
+	default
+	eapply "${FILESDIR}"/${P}-binary-locations.patch
 
-	epatch "${FILESDIR}"/${P}-binary-locations.patch
+	# match our bind config
+	sed -e 's|0.0.127.in-addr.arpa|127.in-addr.arpa|g' -i ndu.conf || die
+	# document the support for the chrooted BIND setup
+	cat >> ndu.conf <<-EOF || die
+		// if you use a chrooted setup, then you need to uncomment these lines:
+		//process "/chroot/dns/named.conf"
+		//chroot "/chroot/dns"
+	EOF
 
-	cd "${S}"/src
+	cd src || die
 	# use the correct compiler
-	sed -e 's|gcc|$(CXX)|g' -i Makefile
+	sed -e 's|gcc|$(CXX)|g' -i Makefile || die
 	# set correct config pathes
-	sed -e 's|#define CONFIG_PATH "/etc/"|#define CONFIG_PATH "/etc/bind/"|g' -i ndu.cpp
-	sed -e 's|"/etc/ndu.conf"|"/etc/bind/ndu.conf"|g' -i dnstouch.cpp
+	sed -e 's|#define CONFIG_PATH "/etc/"|#define CONFIG_PATH "/etc/bind/"|g' \
+		-i ndu.cpp || die
+	sed -e 's|"/etc/ndu.conf"|"/etc/bind/ndu.conf"|g' -i dnstouch.cpp || die
 	# hack up something to work around bug #73858
-	sed -e 's|execlp("ed", "ed", filename, 0);|execlp("ed", "ed", "-s", filename, 0);|g' -i dnstouch.cpp
+	sed -e 's|execlp("ed", "ed", filename, 0);|execlp("ed", "ed", "-s", filename, 0);|g' \
+		-i dnstouch.cpp || die
 	# use the correct editor
-	sed -e 's|VISUAL|EDITOR|g' -i dnsedit
-
-	cd "${S}"
-	# match our bind config
-	sed -e 's|0.0.127.in-addr.arpa|127.in-addr.arpa|g' -i ndu.conf
-	# document the support for the chrooted BIND setup
-	echo '// if you use a chrooted setup, then you need to uncomment these lines:' >>ndu.conf
-	echo '//process "/chroot/dns/named.conf"' >>ndu.conf
-	echo '//chroot "/chroot/dns"' >>ndu.conf
+	sed -e 's|VISUAL|EDITOR|g' -i dnsedit || die
 }
 
 src_compile() {
-	cd "${S}"/src
-	emake CFLAGS="${CFLAGS}" CXX="$(tc-getCXX)"
+	emake -C src CFLAGS="${CFLAGS}" CXX="$(tc-getCXX)"
 }
 
 src_install () {
-	into /usr
 	dobin src/{dnsedit,ndu,dnstouch}
-	into /
 	insinto /etc/bind
 	doins ndu.conf
 	dodoc README INSTALL
-- 
cgit v1.2.3-65-gdbad