From 8eb9eff5d2af31d9451ea6d365716bf7b133f6d7 Mon Sep 17 00:00:00 2001
From: Yuri Konotopov <ykonotopov@gnome.org>
Date: Sat, 16 Sep 2023 11:12:20 +0400
Subject: net-news/liferea: add 1.15.3

Bug: https://bugs.gentoo.org/893712
Closes: https://github.com/gentoo/gentoo/pull/32825
Signed-off-by: Yuri Konotopov <ykonotopov@gnome.org>
Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 net-news/liferea/Manifest              |  1 +
 net-news/liferea/liferea-1.15.3.ebuild | 69 ++++++++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 net-news/liferea/liferea-1.15.3.ebuild

(limited to 'net-news')

diff --git a/net-news/liferea/Manifest b/net-news/liferea/Manifest
index e58c61d0d1c1..5651346b0272 100644
--- a/net-news/liferea/Manifest
+++ b/net-news/liferea/Manifest
@@ -1 +1,2 @@
 DIST liferea-1.14.5.tar.gz 1833641 BLAKE2B 5505e33bd113b3ea0bf7582f75aa968de2b4bbbc659f224062d735bb357177a3eec5dca26dbc22151ccb1659e740ce2068ee2933ef82eb2e3c3a96b31528e570 SHA512 866e795e31644a8546d0fd6eae2976e0c031650caf77aa87e90bc17a55f65d2c207bb295649c7b4d318fb0d628f7cae1fc0d563f59260eddfeafbe9c885f3550
+DIST liferea-1.15.3.tar.gz 1860898 BLAKE2B c339259b084a7e49b34643cbd9717b04ca7e4fb1ea4f87b30027325b8846c51f3db08105fe5056001e843716b32633fa1ad3a6c5ab4cbdac857b3bf51d7e5477 SHA512 45c237e11ef85ae67da34c557b7ef8695ec450dc35c8454ab16116df4eb0031f6755edd8045f121fc4a2ff6624848212fa5ec47a30e63b2d5936be9759086581
diff --git a/net-news/liferea/liferea-1.15.3.ebuild b/net-news/liferea/liferea-1.15.3.ebuild
new file mode 100644
index 000000000000..76a9aaf11f60
--- /dev/null
+++ b/net-news/liferea/liferea-1.15.3.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit autotools gnome2-utils optfeature python-single-r1 xdg
+
+DESCRIPTION="News Aggregator for RDF/RSS/CDF/Atom/Echo feeds"
+HOMEPAGE="https://lzone.de/liferea/"
+SRC_URI="https://github.com/lwindolf/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-db/sqlite:3
+	dev-libs/fribidi
+	dev-libs/glib:2
+	dev-libs/gobject-introspection
+	dev-libs/json-glib
+	dev-libs/libpeas[gtk,python,${PYTHON_SINGLE_USEDEP}]
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	gnome-base/gsettings-desktop-schemas
+	net-libs/libsoup:3.0
+	net-libs/webkit-gtk:4.1=
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-util/intltool
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf --disable-static
+}
+
+src_compile() {
+	# Workaround crash in libwebkit2gtk-4.0.so
+	# https://bugs.gentoo.org/704594
+	WEBKIT_DISABLE_COMPOSITING_MODE=1 \
+		default
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	optfeature "Libsecret Support plugin" app-crypt/libsecret[introspection]
+	optfeature "Tray Icon (GNOME Classic) plugin" "dev-python/pycairo x11-libs/gdk-pixbuf[introspection]"
+	optfeature "Media Player plugin" media-libs/gstreamer[introspection]
+	optfeature "monitoring network status" net-misc/networkmanager
+	optfeature "Popup Notifications plugin" x11-libs/libnotify[introspection]
+}
-- 
cgit v1.2.3-65-gdbad