From 33d7f0caedfd5c5dc0c00ab99da0daa5dfb21783 Mon Sep 17 00:00:00 2001
From: Sven Wegener <swegener@gentoo.org>
Date: Sat, 8 Jan 2022 16:22:56 +0100
Subject: sci-electronics/pulseview: Remove python USE flags

Selecting the python interpreter is completely done by libsigrokdecode.

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Sven Wegener <swegener@gentoo.org>
---
 .../pulseview/pulseview-0.4.2-r1.ebuild            | 69 +++++++++++++++++++
 sci-electronics/pulseview/pulseview-0.4.2.ebuild   | 79 ----------------------
 sci-electronics/pulseview/pulseview-9999.ebuild    | 16 +----
 3 files changed, 72 insertions(+), 92 deletions(-)
 create mode 100644 sci-electronics/pulseview/pulseview-0.4.2-r1.ebuild
 delete mode 100644 sci-electronics/pulseview/pulseview-0.4.2.ebuild

(limited to 'sci-electronics/pulseview')

diff --git a/sci-electronics/pulseview/pulseview-0.4.2-r1.ebuild b/sci-electronics/pulseview/pulseview-0.4.2-r1.ebuild
new file mode 100644
index 000000000000..a71826cfa065
--- /dev/null
+++ b/sci-electronics/pulseview/pulseview-0.4.2-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg-utils
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="git://sigrok.org/${PN}"
+	inherit git-r3
+else
+	SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="Qt based logic analyzer GUI for sigrok"
+HOMEPAGE="https://sigrok.org/wiki/PulseView"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="+decode static"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+RDEPEND="
+	>=dev-cpp/glibmm-2.28.0:2
+	>=dev-libs/boost-1.55:=
+	>=dev-libs/glib-2.28.0:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	>=sci-libs/libsigrok-0.5.1:=[cxx]
+	decode? ( >=sci-libs/libsigrokdecode-0.5.2:= )
+"
+DEPEND="${RDEPEND}"
+
+DOCS=( HACKING NEWS README )
+
+PATCHES=(
+	"${FILESDIR}/${P}-qt-5.15.patch"
+	"${FILESDIR}"/${PN}-0.4.2-glib-2.68.patch
+)
+
+src_prepare() {
+	cmake_src_prepare
+	cmake_comment_add_subdirectory manual
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_WERROR=TRUE
+		-DENABLE_DECODE=$(usex decode)
+		-DSTATIC_PKGDEPS_LIBS=$(usex static)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
diff --git a/sci-electronics/pulseview/pulseview-0.4.2.ebuild b/sci-electronics/pulseview/pulseview-0.4.2.ebuild
deleted file mode 100644
index e96be770c575..000000000000
--- a/sci-electronics/pulseview/pulseview-0.4.2.ebuild
+++ /dev/null
@@ -1,79 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{7,8,9} )
-
-inherit cmake python-single-r1 xdg-utils
-
-if [[ ${PV} == *9999* ]]; then
-	EGIT_REPO_URI="git://sigrok.org/${PN}"
-	inherit git-r3
-else
-	SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
-fi
-
-DESCRIPTION="Qt based logic analyzer GUI for sigrok"
-HOMEPAGE="https://sigrok.org/wiki/PulseView"
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="+decode static"
-REQUIRED_USE="decode? ( ${PYTHON_REQUIRED_USE} )"
-
-BDEPEND="
-	dev-qt/linguist-tools:5
-	virtual/pkgconfig
-"
-RDEPEND="
-	>=dev-cpp/glibmm-2.28.0:2
-	>=dev-libs/boost-1.55:=
-	>=dev-libs/glib-2.28.0:2
-	dev-qt/qtcore:5
-	dev-qt/qtgui:5
-	dev-qt/qtsvg:5
-	dev-qt/qtwidgets:5
-	>=sci-libs/libsigrok-0.5.1:=[cxx]
-	decode? (
-		${PYTHON_DEPS}
-		>=sci-libs/libsigrokdecode-0.5.2:=[${PYTHON_SINGLE_USEDEP}]
-	)
-"
-DEPEND="${RDEPEND}"
-
-DOCS=( HACKING NEWS README )
-
-PATCHES=(
-	"${FILESDIR}/${P}-qt-5.15.patch"
-	"${FILESDIR}"/${PN}-0.4.2-glib-2.68.patch
-)
-
-pkg_setup() {
-	use decode && python_setup
-}
-
-src_prepare() {
-	cmake_src_prepare
-	cmake_comment_add_subdirectory manual
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DDISABLE_WERROR=TRUE
-		-DENABLE_DECODE=$(usex decode)
-		-DSTATIC_PKGDEPS_LIBS=$(usex static)
-	)
-	cmake_src_configure
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-	xdg_desktop_database_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-	xdg_desktop_database_update
-}
diff --git a/sci-electronics/pulseview/pulseview-9999.ebuild b/sci-electronics/pulseview/pulseview-9999.ebuild
index 1b2ea98c17f8..330e533dbf89 100644
--- a/sci-electronics/pulseview/pulseview-9999.ebuild
+++ b/sci-electronics/pulseview/pulseview-9999.ebuild
@@ -1,11 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7,8,9} )
-
-inherit cmake python-single-r1 xdg-utils
+inherit cmake xdg-utils
 
 if [[ ${PV} == *9999* ]]; then
 	EGIT_REPO_URI="git://sigrok.org/${PN}"
@@ -21,7 +19,6 @@ HOMEPAGE="https://sigrok.org/wiki/PulseView"
 LICENSE="GPL-3"
 SLOT="0"
 IUSE="+decode static"
-REQUIRED_USE="decode? ( ${PYTHON_REQUIRED_USE} )"
 
 BDEPEND="
 	dev-qt/linguist-tools:5
@@ -36,19 +33,12 @@ RDEPEND="
 	dev-qt/qtsvg:5
 	dev-qt/qtwidgets:5
 	>=sci-libs/libsigrok-0.6.0:=[cxx]
-	decode? (
-		${PYTHON_DEPS}
-		>=sci-libs/libsigrokdecode-0.6.0:=[${PYTHON_SINGLE_USEDEP}]
-	)
+	decode? ( >=sci-libs/libsigrokdecode-0.6.0:= )
 "
 DEPEND="${RDEPEND}"
 
 DOCS=( HACKING NEWS README )
 
-pkg_setup() {
-	use decode && python_setup
-}
-
 src_prepare() {
 	cmake_src_prepare
 	cmake_comment_add_subdirectory manual
-- 
cgit v1.2.3-65-gdbad