blob: 64e90eb82352bf48c8fe4618b336a69c85f4c329 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit autotools eutils
DESCRIPTION="Graphical file manager for Unix-like systems, using GTK+"
HOMEPAGE="http://gentoo.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="alpha amd64 hppa ~ia64 ppc ~ppc64 sparc x86"
IUSE="nls"
RDEPEND="
>x11-libs/gtk+-3.12:3
dev-libs/glib:2
x11-libs/cairo
x11-libs/gdk-pixbuf
x11-libs/pango
"
DEPEND="
${RDEPEND}
nls? ( sys-devel/gettext )
"
DOCS=(
AUTHORS BUGS CONFIG-CHANGES CREDITS NEWS README TODO docs/{FAQ,menus.txt}
)
src_prepare() {
sed -i \
-e 's^icons/gnome/16x16/mimetypes^gentoo/icons^' \
gentoorc.in || die
sed -i \
-e '/GTK_DISABLE_DEPRECATED/d' \
-e '/^GENTOO_CFLAGS=/s|".*"|"${CFLAGS}"|g' \
-e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' \
configure.ac || die #357343
eapply_user
eautoreconf
}
src_configure() {
econf \
--sysconfdir=/etc/gentoo \
$(use_enable nls)
}
src_install() {
default
docinto html
dodoc -r docs/{images,config,*.{html,css}}
newman docs/gentoo.1x gentoo.1
docinto scratch
dodoc docs/scratch/*
make_desktop_entry ${PN} Gentoo \
/usr/share/${PN}/icons/${PN}.png \
"System;FileTools;FileManager"
}
|
GitWeb
