blob: c11540c545006ae0bc055d1e715973561f6482c3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
inherit toolchain-funcs
MY_PN='spacenav'
DESCRIPTION="libspnav is a replacement for the magellan library with a cleaner API"
HOMEPAGE="http://spacenav.sourceforge.net/"
SRC_URI="https://github.com/FreeSpacenav/libspnav/releases/download/v${PV}/libspnav-${PV}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
IUSE="static-libs X"
CDEPEND="X? ( x11-libs/libX11 )"
RDEPEND="app-misc/spacenavd[X?]
${CDEPEND}"
DEPEND="${CDEPEND}"
PATCHES=(
"${FILESDIR}"/${P}-no-xorg-compile.patch
)
src_configure() {
local args=(
--disable-opt
--disable-debug
$(use_enable X x11)
)
econf "${args[@]}"
# https://bugs.gentoo.org/838349
sed "/^Libs:/ s,/lib,/$(get_libdir)," -i spnav.pc || die
}
src_compile() {
local args=(
AR="$(tc-getAR)"
CC="$(tc-getCC)"
incpaths=-I.
libpaths=
)
emake "${args[@]}"
}
src_install() {
local args=(
DESTDIR="${D}"
libdir="$(get_libdir)"
)
emake "${args[@]}" install
# The custom configure script does not support --disable-static
# and conditionally patching $(lib_a) out of Makefile.in does not
# seem like a very maintainable option, hence we delete the .a file
# after "make install", instead.
use static-libs || find "${D}" -type f -name \*.a -delete
}
|
GitWeb
