blob: e56fa7341ec5bdc68d2fe920b0ece80ccf2d4b07 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit qmake-utils
DESCRIPTION="Qt-based library for OAuth support"
HOMEPAGE="https://wiki.github.com/ayoy/qoauth"
SRC_URI="https://dev.gentoo.org/~johu/distfiles/${P}.tar.xz"
LICENSE="LGPL-2.1"
SLOT="5"
KEYWORDS="amd64 ~ppc64 x86"
IUSE="debug doc test"
COMMON_DEPEND="
app-crypt/qca:2[debug?,qt5]
dev-qt/qtnetwork:5
"
DEPEND="${COMMON_DEPEND}
doc? ( app-doc/doxygen )
test? ( dev-qt/qttest:5 )
"
RDEPEND="${COMMON_DEPEND}
app-crypt/qca:2[ssl]
!dev-libs/qoauth:0
"
# disable functional tests that require network connection
# and rely on 3rd party external server (bug #341267)
PATCHES=( "${FILESDIR}/${PN}-1.0.1-disable-ft.patch" )
src_prepare() {
default
if ! use test; then
sed -i -e '/SUBDIRS/s/tests//' ${PN}.pro || die "sed failed"
fi
sed -i -e '/^ *docs \\$/d' \
-e '/^ *build_all \\$/d' \
-e 's/^\#\(!macx\)/\1/' \
src/src.pro || die "sed failed"
sed -i -e "s/\(.*\)lib$/\1$(get_libdir)/" src/pcfile.sh || die "sed failed"
}
src_configure() {
eqmake5 qoauth.pro
}
src_install() {
if use doc; then
doxygen "${S}"/Doxyfile || die "failed to generate documentation"
HTML_DOCS=( "${S}"/doc/html/. )
fi
INSTALL_ROOT="${D}" default
}
|
GitWeb
