dev-python/pyelftools/pyelftools-0.29.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )

inherit distutils-r1

DESCRIPTION="pure-Python library for analyzing ELF files and DWARF debugging information"
HOMEPAGE="
	https://pypi.org/project/pyelftools/
	https://github.com/eliben/pyelftools/
"
# PyPI tarball lacks some test files
SRC_URI="
	https://github.com/eliben/pyelftools/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="public-domain"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux"
IUSE="examples"

python_test() {
	# readelf_tests often fails due to host `readelf` changing output format
	"${EPYTHON}" test/run_all_unittests.py || die
	"${EPYTHON}" test/run_examples_test.py || die
}

python_install_all() {
	use examples && dodoc -r examples
	distutils-r1_python_install_all
}