dev-util/bloaty/bloaty-1.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake

DESCRIPTION="A size profiler for binaries"
HOMEPAGE="https://github.com/google/bloaty"

if [[ ${PV} == 9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/google/${PN}"
	IUSE="test"
	RESTRICT="!test? ( test )"
else
	SRC_URI="https://github.com/google/${PN}/releases/download/v${PV}/${P}.tar.bz2"
	KEYWORDS="amd64 ~arm64"
fi

LICENSE="Apache-2.0"
SLOT="0"

BDEPEND="
	virtual/pkgconfig
"
DEPEND="
	dev-cpp/abseil-cpp:=
	dev-libs/capstone:=
	dev-libs/protobuf:=
	dev-libs/re2:=
"
RDEPEND="${DEPEND}"

PATCHES=(
	"${FILESDIR}"/${PN}-1.1-system-abseil.patch
)

src_configure() {
	local mycmakeargs=(
		-DBLOATY_ENABLE_CMAKETARGETS=OFF
		-DBUILD_SHARED_LIBS=OFF
	)

	if [[ ${PV} == 9999 ]]; then
		mycmakeargs+=(
			-DBUILD_TESTING=$(usex test)
			$(usex test -DINSTALL_GTEST=OFF "")
		)
	fi

	cmake_src_configure
}