blob: 789aba2ffb05c1068e976b3ebec88aef2a937f26 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
PVCUT=$(ver_cut 1-3)
KFMIN=5.96.0
QTMIN=5.15.5
inherit ecm gear.kde.org
DESCRIPTION="Application to manage alarms and other timer based alerts for the desktop"
HOMEPAGE="https://apps.kde.org/kalarm/ https://userbase.kde.org/KAlarm"
LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
SLOT="5"
KEYWORDS="~amd64 arm64 ~ppc64 ~x86"
IUSE="+pim speech X"
DEPEND="
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtwidgets-${QTMIN}:5
>=kde-apps/kcalutils-${PVCUT}:5
>=kde-apps/kidentitymanagement-${PVCUT}:5
>=kde-apps/kmime-${PVCUT}:5
>=kde-apps/kontactinterface-${PVCUT}:5
>=kde-apps/kpimtextedit-${PVCUT}:5[speech=]
>=kde-apps/pimcommon-${PVCUT}:5
>=kde-frameworks/kauth-${KFMIN}:5
>=kde-frameworks/kcalendarcore-${KFMIN}:5
>=kde-frameworks/kcmutils-${KFMIN}:5
>=kde-frameworks/kcodecs-${KFMIN}:5
>=kde-frameworks/kcompletion-${KFMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcontacts-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/kcrash-${KFMIN}:5
>=kde-frameworks/kdbusaddons-${KFMIN}:5
>=kde-frameworks/kglobalaccel-${KFMIN}:5
>=kde-frameworks/kguiaddons-${KFMIN}:5
>=kde-frameworks/kholidays-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kidletime-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/kitemmodels-${KFMIN}:5
>=kde-frameworks/kjobwidgets-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/ktextwidgets-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5[X?]
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=media-libs/phonon-4.11.0
pim? (
>=kde-apps/akonadi-${PVCUT}:5
>=kde-apps/akonadi-contacts-${PVCUT}:5
>=kde-apps/akonadi-mime-${PVCUT}:5
>=kde-apps/kmailtransport-${PVCUT}:5
)
X? (
>=dev-qt/qtx11extras-${QTMIN}:5
x11-libs/libX11
)
"
RDEPEND="${DEPEND}
!kde-apps/kalarmcal:5
pim? ( >=kde-apps/kdepim-runtime-${PVCUT}:5 )
"
PATCHES=( "${FILESDIR}/${PN}-22.07.90-without_x11.patch" )
src_configure() {
local mycmakeargs=(
-DENABLE_AKONADI_PLUGIN=$(usex pim)
-DWITHOUT_X11=$(usex !X)
)
ecm_src_configure
}
src_test() {
# LC_TIME bug 665626, 857012
# TZ bug https://bugs.kde.org/show_bug.cgi?id=445734
LC_TIME="C" TZ=UTC ecm_src_test
}
|
GitWeb