From 679a1cb69df7807da6ea7ce56414ea55c8f33c74 Mon Sep 17 00:00:00 2001
From: "Haelwenn (lanodan) Monnier" <contact@hacktivis.me>
Date: Sun, 14 Jul 2024 17:24:03 +0200
Subject: dev-lang/hare: add 0.24.2

Signed-off-by: Haelwenn (lanodan) Monnier <contact@hacktivis.me>
---
 dev-lang/hare/Manifest           |  1 +
 dev-lang/hare/hare-0.24.2.ebuild | 56 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 57 insertions(+)
 create mode 100644 dev-lang/hare/hare-0.24.2.ebuild

diff --git a/dev-lang/hare/Manifest b/dev-lang/hare/Manifest
index 76d43de88c..996944dd6b 100644
--- a/dev-lang/hare/Manifest
+++ b/dev-lang/hare/Manifest
@@ -1 +1,2 @@
 DIST hare-0.24.0.tar.gz 767869 BLAKE2B 4e1e706a7e0623ebe71803dc591b362527dd140f025cb3529e95d9bec8bea464bc008d512e4981f1dcd34f770b8831a0d6dd37cb453ee54e01e900c1cd52c159 SHA512 d7b96bc031d432e0ca0a9186a043d4cd4af4d4b57be5ce4b913d6acd26cdb708d8c9ad8e2c64c78c192a11a96977d3e916985a548238591b3c4d177b9cc811d9
+DIST hare-0.24.2.tar.gz 912808 BLAKE2B 2dbb83448efe85c36be50ebfbe9c8c567ac7a8c420253f242aa911e815fbf41ff4fbe0e36d22b5654b74441cc73bbaac9de5b9cdb06f9f687813babe2bf359c0 SHA512 6214d0068f507f156bff85d12aeb515e5f752bff03645b3b207d224aecc62e34d4a44a171fc2b357eaaf72a804c2b79d6ad2886caa2804f1dcad07cc25d7efac
diff --git a/dev-lang/hare/hare-0.24.2.ebuild b/dev-lang/hare/hare-0.24.2.ebuild
new file mode 100644
index 0000000000..4ef0d76a9c
--- /dev/null
+++ b/dev-lang/hare/hare-0.24.2.ebuild
@@ -0,0 +1,56 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ "${PV}" = 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.sr.ht/~sircmpwn/hare"
+	SLOT="0"
+else
+	MY_PV="$(ver_rs 3 -)"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://git.sr.ht/~sircmpwn/hare/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+	SLOT="0/${PV}"
+	KEYWORDS="~amd64 ~arm64 ~riscv"
+fi
+
+DESCRIPTION="The Hare systems programming language"
+HOMEPAGE="https://harelang.org/"
+LICENSE="MPL-2.0 GPL-3"
+
+# release policy: https://git.sr.ht/~sircmpwn/hare/tree/master/item/docs/release.md
+DEPEND="
+	~dev-lang/harec-0.24.2
+	>=sys-devel/qbe-1.2
+"
+BDEPEND="app-text/scdoc"
+RDEPEND="${DEPEND}"
+
+# hare and haredoc are built by hare
+QA_FLAGS_IGNORED="usr/bin/hare usr/bin/haredoc"
+
+src_configure() {
+	local target_arch
+	case ${ARCH} in
+		amd64 ) target_arch=x86_64 ;;
+		arm64 ) target_arch=aarch64 ;;
+		riscv ) target_arch=riscv64 ;;
+		* ) die "unsupported architecture: ${ARCH}" ;;
+	esac
+
+	# Note: PREFIX needs to be set early as it is used for HAREPATH
+	cp configs/linux.mk config.mk || die
+	sed -i \
+		-e "s;^ARCH =.*;ARCH = ${target_arch};" \
+		-e "s;^PREFIX =.*;PREFIX = ${EPREFIX}/usr;" \
+		-e 's;^AS =;AS ?=;' \
+		-e 's;^LD =;LD ?=;' \
+		-e 's;^AR =;AR ?=;' \
+		config.mk || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+}
-- 
cgit v1.2.3-65-gdbad