From 259c98a828aa52d7c348c749e09e75238c5dae55 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Thu, 24 Nov 2022 10:36:10 -0500
Subject: dev-util/umockdev: Version bump to 0.17.15

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 dev-util/umockdev/Manifest                |  1 +
 dev-util/umockdev/umockdev-0.17.15.ebuild | 59 +++++++++++++++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 dev-util/umockdev/umockdev-0.17.15.ebuild

(limited to 'dev-util/umockdev')

diff --git a/dev-util/umockdev/Manifest b/dev-util/umockdev/Manifest
index 2af2d49a3dbd..61ca9b7ed88e 100644
--- a/dev-util/umockdev/Manifest
+++ b/dev-util/umockdev/Manifest
@@ -1 +1,2 @@
 DIST umockdev-0.17.13.tar.xz 489728 BLAKE2B 0bb4d912aa924c91ff1f4e2cd5ca4ddf81eea1db55ddf9e4cd9a7e9683ed92a268063601a38f7f0a6fb669b301fa9ace94c413e5958ad5587db0097acb2f066c SHA512 77863ad67be0995869b35d12dc43a809d2e67e95f727312ffd9f585c5bb1598c4d31f4909fcff5035dfccdbde8c36819daa633cae53c57ea2d9c3ede3587ec4d
+DIST umockdev-0.17.15.tar.xz 491152 BLAKE2B 40334a0279e81e1af3eb01acafd85c638e8a04af20e4c5b6b64229d89ffcfa231d6ef9e760d24e0cb957fe654252d18dca8579490e52a4c05769163f8a33ac96 SHA512 722339ae0726b00a4ee5fa428f063c5b59f0bad14a8fe24d97276a55dc66c569289c62c4ee5ebdb75a62339444a35468c8c1a33759d76fdf022a1eb4905c0465
diff --git a/dev-util/umockdev/umockdev-0.17.15.ebuild b/dev-util/umockdev/umockdev-0.17.15.ebuild
new file mode 100644
index 000000000000..8015f3762895
--- /dev/null
+++ b/dev-util/umockdev/umockdev-0.17.15.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit meson-multilib python-any-r1 vala
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/martinpitt/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+DESCRIPTION="Mock hardware devices for creating unit tests"
+HOMEPAGE="https://github.com/martinpitt/umockdev/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	net-libs/libpcap[${MULTILIB_USEDEP}]
+	virtual/libudev:=[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
+	>=dev-libs/gobject-introspection-1.32:=
+"
+DEPEND="${RDEPEND}
+	test? (
+		${PYTHON_DEPS}
+		dev-libs/libgudev:=[${MULTILIB_USEDEP}]
+	)
+"
+BDEPEND="
+	$(vala_depend)
+	app-arch/xz-utils
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+multilib_src_configure() {
+	export VALAC="$(type -P valac-$(vala_best_api_version))"
+	meson_src_configure
+}
+
+multilib_src_test() {
+	meson_src_test --no-suite fails-valgrind
+}
-- 
cgit v1.2.3-65-gdbad