# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=5

inherit libtool multilib eutils pam toolchain-funcs flag-o-matic db-use autotools-multilib

MY_PN="Linux-PAM"
MY_P="${MY_PN}-${PV}"

HOMEPAGE="https://fedorahosted.org/linux-pam/"
DESCRIPTION="Linux-PAM (Pluggable Authentication Modules)"

SRC_URI="http://www.linux-pam.org/library/${MY_P}.tar.bz2
	http://www.linux-pam.org/documentation/${MY_P}-docs.tar.bz2"

LICENSE="|| ( BSD GPL-2 )"
SLOT="0"
KEYWORDS="~amd64"
IUSE="cracklib nls elibc_FreeBSD selinux vim-syntax audit test elibc_glibc debug berkdb nis"

RDEPEND="nls? ( virtual/libintl[${MULTILIB_USEDEP}] )
	cracklib? ( >=sys-libs/cracklib-2.8.3[${MULTILIB_USEDEP}] )
	audit? ( sys-process/audit[${MULTILIB_USEDEP}] )
	selinux? ( >=sys-libs/libselinux-1.28[${MULTILIB_USEDEP}] )
	berkdb? ( sys-libs/db[${MULTILIB_USEDEP}] )
	elibc_glibc? (
		>=sys-libs/glibc-2.7
		nis? ( || ( >=net-libs/libtirpc-0.2.2-r1[${MULTILIB_USEDEP}] <sys-libs/glibc-2.14 ) )
	)"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2
	sys-devel/flex[${MULTILIB_USEDEP}]
	nls? ( sys-devel/gettext[${MULTILIB_USEDEP}] )
	virtual/pkgconfig
	abi_x86_32? (
		!<=app-emulation/emul-linux-x86-baselibs-20131008-r1
		!app-emulation/emul-linux-x86-baselibs[-abi_x86_32(-)]
	)"
PDEPEND="sys-auth/pambase
	vim-syntax? ( app-vim/pam-syntax )"
RDEPEND="${RDEPEND}
	!<sys-apps/openrc-0.11.8
	!sys-auth/openpam
	!sys-auth/pam_userdb"

S="${WORKDIR}/${MY_P}"

check_old_modules() {
	local retval="0"

	if sed -e 's:#.*::' "${EROOT}"/etc/pam.d/* 2>/dev/null | fgrep -q pam_stack.so; then
		eerror ""
		eerror "Your current setup is using the pam_stack module."
		eerror "This module is deprecated and no longer supported, and since version"
		eerror "0.99 is no longer installed, nor provided by any other package."
		eerror "The package will be built (to allow binary package builds), but will"
		eerror "not be installed."
		eerror "Please replace pam_stack usage with proper include directive usage,"
		eerror "following the PAM Upgrade guide at the following URL"
		eerror "  http://www.gentoo.org/proj/en/base/pam/upgrade-0.99.xml"
		eerror ""

		retval=1
	fi

	if sed -e 's:#.*::' "${EROOT}"/etc/pam.d/* 2>/dev/null | egrep -q 'pam_(pwdb|console)'; then
		eerror ""
		eerror "Your current setup is using one or more of the following modules,"
		eerror "that are not built or supported anymore:"
		eerror "pam_pwdb, pam_console"
		eerror "If you are in real need for these modules, please contact the maintainers"
		eerror "of PAM through http://bugs.gentoo.org/ providing information about its"
		eerror "use cases."
		eerror "Please also make sure to read the PAM Upgrade guide at the following URL:"
		eerror "  http://www.gentoo.org/proj/en/base/pam/upgrade-0.99.xml"
		eerror ""

		retval=1
	fi

	return $retval
}

pkg_pretend() {
	# do not error out, this is just a warning, one could build a binpkg
	# with old modules enabled.
	check_old_modules
}

src_configure() {
	# Disable automatic detection of libxcrypt; we _don't_ want the
	# user to link libxcrypt in by default, since we won't track the
	# dependency and allow to break PAM this way.
	export ac_cv_header_xcrypt_h=no

	local myeconfargs=(
		--htmldir="${EPREFIX}"/usr/share/doc/${PF}/html
		--libdir="${EPREFIX}"/usr/@GET_LIBDIR@ \
		--enable-securedir="${EPREFIX}"/@GET_LIBDIR@/security
		--enable-isadir="${EPREFIX}"/@GET_LIBDIR@/security
		$(use_enable nls)
		$(use_enable selinux)
		$(use_enable cracklib)
		$(use_enable audit)
		$(use_enable debug)
		$(use_enable berkdb db)
		$(use_enable nis)
		--with-db-uniquename=-$(db_findver sys-libs/db)
		--disable-prelude
	)

	if use hppa || use elibc_FreeBSD; then
		myeconfargs+=( --disable-pie )
	fi

	autotools-multilib_src_configure
}

src_compile() {
	autotools-multilib_src_compile sepermitlockdir="${EPREFIX}/run/sepermit"
}

DOCS=( CHANGELOG ChangeLog README AUTHORS Copyright NEWS )

src_install() {
	AUTOTOOLS_PRUNE_LIBTOOL_FILES=all
	ehook autotools-multilib-per-abi-post_src_install per_abi_install
	autotools-multilib_src_install sepermitlockdir="${EPREFIX}/run/sepermit"

	# Need to be suid
	fperms u+s /sbin/unix_chkpwd

	docinto modules
	for dir in modules/pam_*; do
		newdoc "${dir}"/README README."$(basename "${dir}")"
	done

	if use selinux; then
		dodir /usr/lib/tmpfiles.d
		cat - > "${D}"/usr/lib/tmpfiles.d/${CATEGORY}:${PN}:${SLOT}.conf <<EOF
d /run/sepermit 0755 root root
EOF
	fi
}

per_abi_install() {
	multilib_is_native_abi && gen_usr_ldscript -a pam pamc pam_misc

	# create extra symlinks just in case something depends on them...
	local lib
	local abslibdir=usr/$(get_libdir)
	multilib_is_native_abi && abslibdir=$(get_libdir)
	for lib in pam pamc pam_misc; do
		if ! [[ -f "${ED}"${abslibdir}/lib${lib}$(get_libname) ]]; then
			dosym lib${lib}$(get_libname 0) /${abslibdir}/lib${lib}$(get_libname)
		fi
	done
}

pkg_preinst() {
	check_old_modules || die "deprecated PAM modules still used"
}

pkg_postinst() {
	ewarn "Some software with pre-loaded PAM libraries might experience"
	ewarn "warnings or failures related to missing symbols and/or versions"
	ewarn "after any update. While unfortunate this is a limit of the"
	ewarn "implementation of PAM and the software, and it requires you to"
	ewarn "restart the software manually after the update."
	ewarn ""
	ewarn "You can get a list of such software running a command like"
	ewarn "  lsof / | egrep -i 'del.*libpam\\.so'"
	ewarn ""
	ewarn "Alternatively, simply reboot your system."
	if [ -x "${ROOT}"/var/log/tallylog ] ; then
		elog ""
		elog "Because of a bug present up to version 1.1.1-r2, you have"
		elog "an executable /var/log/tallylog file. You can safely"
		elog "correct it by running the command"
		elog "  chmod -x /var/log/tallylog"
		elog ""
	fi
}