From 7b8d7eff6e3d3128c446d9d1b6df042b914bcc3b Mon Sep 17 00:00:00 2001
From: Paul Healy <lmiphay@gmail.com>
Date: Tue, 9 Apr 2019 20:42:22 +0100
Subject: add clion ebuild (bump from portage)

Signed-off-by: Paul Healy <lmiphay@gmail.com>
---
 dev-util/clion/Manifest            |  2 ++
 dev-util/clion/clion-2019.1.ebuild | 65 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 dev-util/clion/Manifest
 create mode 100644 dev-util/clion/clion-2019.1.ebuild

(limited to 'dev-util')

diff --git a/dev-util/clion/Manifest b/dev-util/clion/Manifest
new file mode 100644
index 0000000..aa81d42
--- /dev/null
+++ b/dev-util/clion/Manifest
@@ -0,0 +1,2 @@
+DIST clion-2019.1.tar.gz 429061573 BLAKE2B 14c2227509fd4c24d09ca139ff9f58ab2be71ad249d8f8a09d615cdc1aa07e9d2e0be9618e795859f564b63705a34e61dc90f3de5a012ad8fdf9a2f8ba512c33 SHA512 5c919ad2ea87744e0b3488958e58a9f67d8a8dcfa6affd86f975842c9e562663464d73373c72ef8085cede8f16828342dc17e182e761c199936bffee2f398509
+EBUILD clion-2019.1.ebuild 1636 BLAKE2B c7bf57eedb61011fcbe0d55642861430e5245d6a60fc00aa0939dc3a5f36ef984e4c5bf61ea8c321993517cf415addee2899388b507797a01ea84eba830b0d01 SHA512 4de323127bd79d5a110ff83e925b5de36604825d003e54dd9ca3682166d9c71d323b6a1be5d621dfdf9e8de9934fd7fea9b795dfff5e15e3c6fa4f304dd2a6cd
diff --git a/dev-util/clion/clion-2019.1.ebuild b/dev-util/clion/clion-2019.1.ebuild
new file mode 100644
index 0000000..f6d25d7
--- /dev/null
+++ b/dev-util/clion/clion-2019.1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop eutils
+
+DESCRIPTION="A complete toolset for C and C++ development"
+HOMEPAGE="http://www.jetbrains.com/clion"
+SRC_URI="http://download.jetbrains.com/cpp/CLion-${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="IDEA
+	|| ( IDEA_Academic IDEA_Classroom IDEA_OpenSource IDEA_Personal )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+RESTRICT="splitdebug"
+IUSE="custom-jdk"
+
+# RDEPENDS may cause false positives in repoman.
+# clion requires cmake and gdb at runtime to build and debug C/C++ projects
+RDEPEND="
+	dev-util/cmake
+	sys-devel/gdb
+	!custom-jdk? ( virtual/jdk )"
+
+QA_PREBUILT="opt/${P}/*"
+
+src_prepare() {
+	default
+
+	local remove_me=(
+		bin/gdb/linux
+		bin/lldb/linux
+		bin/cmake
+		license/CMake*
+	)
+
+	use arm || remove_me+=( bin/fsnotifier-arm )
+
+	use custom-jdk || remove_me+=( jre64 )
+
+	rm -rv "${remove_me[@]}" || die
+}
+
+src_install() {
+	local dir="/opt/${P}"
+
+	insinto "${dir}"
+	doins -r *
+	fperms 755 "${dir}"/bin/{clion.sh,fsnotifier{,64},clang/linux/clang{d,-tidy}}
+
+	if use custom-jdk; then
+		if [[ -d jre64 ]]; then
+		fperms 755 "${dir}"/jre64/bin/{java,jjs,keytool,orbd,pack200,policytool,rmid,rmiregistry,servertool,tnameserv,unpack200}
+		fi
+	fi
+
+	make_wrapper "${PN}" "${dir}/bin/${PN}.sh"
+	newicon "bin/${PN}.svg" "${PN}.svg"
+	make_desktop_entry "${PN}" "clion" "${PN}" "Development;IDE;"
+
+	# recommended by: https://confluence.jetbrains.com/display/IDEADEV/Inotify+Watches+Limit
+	dodir /usr/lib/sysctl.d/
+	echo "fs.inotify.max_user_watches = 524288" > "${D}/usr/lib/sysctl.d/30-clion-inotify-watches.conf" || die
+}
-- 
cgit v1.2.3-65-gdbad