Convert to python-r1. Add slot-operator dep for poppler, bug 462020.

(Portage version: 2.2.0_alpha166/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

2 files changed, 64 insertions, 2 deletions

diff --git a/dev-python/python-poppler/ChangeLog b/dev-python/python-poppler/ChangeLog
index c6e5b85828f2..9bf92950fadb 100644
--- a/dev-python/python-poppler/ChangeLog
+++ b/dev-python/python-poppler/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/python-poppler
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/python-poppler/ChangeLog,v 1.23 2012/07/16 22:36:55 reavertm Exp $
+# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-poppler/ChangeLog,v 1.24 2013/03/17 16:56:47 floppym Exp $
+
+*python-poppler-0.12.1-r4 (17 Mar 2013)
+
+  17 Mar 2013; Mike Gilbert <floppym@gentoo.org>
+  +python-poppler-0.12.1-r4.ebuild:
+  Convert to python-r1. Add slot-operator dep for poppler, bug 462020.
 
   16 Jul 2012; Maciej Mrozowski <reavertm@gentoo.org>
   -python-poppler-0.12.1-r1.ebuild, -python-poppler-0.12.1-r2.ebuild:
diff --git a/dev-python/python-poppler/python-poppler-0.12.1-r4.ebuild b/dev-python/python-poppler/python-poppler-0.12.1-r4.ebuild
new file mode 100644
index 000000000000..284d3fe1db76
--- /dev/null
+++ b/dev-python/python-poppler/python-poppler-0.12.1-r4.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-poppler/python-poppler-0.12.1-r4.ebuild,v 1.1 2013/03/17 16:56:47 floppym Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit autotools-utils eutils python-r1
+
+DESCRIPTION="Python bindings to the Poppler PDF library"
+HOMEPAGE="http://launchpad.net/poppler-python"
+SRC_URI="http://launchpad.net/poppler-python/trunk/development/+download/pypoppler-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd"
+IUSE="examples"
+
+S=${WORKDIR}/pypoppler-${PV}
+
+RDEPEND="${PYTHON_DEPS}
+	>=app-text/poppler-0.15.0:=[cairo]
+	>=dev-python/pycairo-1.8.4[${PYTHON_USEDEP}]
+	dev-python/pygobject:2[${PYTHON_USEDEP}]
+	dev-python/pygtk:2[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+# http://pkgs.fedoraproject.org/gitweb/?p=pypoppler.git;a=tree
+PATCHES=(
+	"${FILESDIR}"/${P}-75_74.diff
+	"${FILESDIR}"/${P}-79_78.diff
+	"${FILESDIR}"/${P}-poppler0.15.0-changes.patch
+	"${FILESDIR}"/${P}-poppler-0.18.0-minimal-fix.patch
+)
+
+src_configure() {
+	python_parallel_foreach_impl autotools-utils_src_configure
+}
+
+src_compile() {
+	python_foreach_impl autotools-utils_src_compile
+}
+
+src_test() {
+	python_foreach_impl autotools-utils_src_test
+}
+
+src_install() {
+	python_foreach_impl autotools-utils_src_install
+	prune_libtool_files --modules
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins demo/demo-poppler.py || die
+	fi
+}