Fix bug #525724 - Add USE=selinux dependency to selinux-irqbalance

(Portage version: 2.2.8-r2/cvs/Linux x86_64, signed Manifest commit with key 0x2EDD52403B68AF47)

2 files changed, 55 insertions, 1 deletions

diff --git a/sys-apps/irqbalance/ChangeLog b/sys-apps/irqbalance/ChangeLog
index 8e5e46223209..8f2e5c6b5fd3 100644
--- a/sys-apps/irqbalance/ChangeLog
+++ b/sys-apps/irqbalance/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-apps/irqbalance
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/irqbalance/ChangeLog,v 1.59 2014/03/19 16:58:31 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/irqbalance/ChangeLog,v 1.60 2014/11/08 16:32:15 swift Exp $
+
+*irqbalance-1.0.7-r1 (08 Nov 2014)
+
+  08 Nov 2014; Sven Vermeulen <swift@gentoo.org> +irqbalance-1.0.7-r1.ebuild:
+  Fix bug #525724 - Add USE=selinux dependency to selinux-irqbalance
 
 *irqbalance-1.0.7 (19 Mar 2014)
 
diff --git a/sys-apps/irqbalance/irqbalance-1.0.7-r1.ebuild b/sys-apps/irqbalance/irqbalance-1.0.7-r1.ebuild
new file mode 100644
index 000000000000..a9bb94b38a59
--- /dev/null
+++ b/sys-apps/irqbalance/irqbalance-1.0.7-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/irqbalance/irqbalance-1.0.7-r1.ebuild,v 1.1 2014/11/08 16:32:15 swift Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils systemd linux-info
+
+DESCRIPTION="Distribute hardware interrupts across processors on a multiprocessor system"
+HOMEPAGE="https://github.com/Irqbalance/irqbalance"
+SRC_URI="https://github.com/Irqbalance/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="caps +numa selinux"
+
+CDEPEND="dev-libs/glib:2
+	caps? ( sys-libs/libcap-ng )
+	numa? ( sys-process/numactl )
+"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-irqbalance )
+"
+
+pkg_setup() {
+	CONFIG_CHECK="~PCI_MSI"
+	linux-info_pkg_setup
+}
+
+src_configure() {
+	local myeconfargs=(
+		$(use_with caps libcap-ng)
+		$(use_enable numa)
+		)
+	autotools-utils_src_configure
+}
+
+src_install() {
+	autotools-utils_src_install
+	newinitd "${FILESDIR}"/irqbalance.init.3 irqbalance
+	newconfd "${FILESDIR}"/irqbalance.confd-1 irqbalance
+	systemd_dounit "${FILESDIR}"/irqbalance.service
+}