Use virtual/udev instead of sys-fs/udev. Version bump wrt #445408 by Arne Babenhauserheide

(Portage version: 2.2.0_alpha147/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

3 files changed, 82 insertions, 3 deletions

diff --git a/media-sound/quodlibet/ChangeLog b/media-sound/quodlibet/ChangeLog
index 1980416602e0..d414cfd736fc 100644
--- a/media-sound/quodlibet/ChangeLog
+++ b/media-sound/quodlibet/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-sound/quodlibet
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/quodlibet/ChangeLog,v 1.95 2012/12/11 16:45:13 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/quodlibet/ChangeLog,v 1.96 2012/12/11 17:15:05 ssuominen Exp $
+
+*quodlibet-2.4.91 (11 Dec 2012)
+
+  11 Dec 2012; Samuli Suominen <ssuominen@gentoo.org> quodlibet-2.4.ebuild,
+  +quodlibet-2.4.91.ebuild:
+  Use virtual/udev instead of sys-fs/udev. Version bump wrt #445408 by Arne
+  Babenhauserheide
 
   11 Dec 2012; Samuli Suominen <ssuominen@gentoo.org>
   -quodlibet-2.3.92-r1.ebuild, -files/quodlibet-2.3.92-xine-lib-1.2.0.patch:
diff --git a/media-sound/quodlibet/quodlibet-2.4.91.ebuild b/media-sound/quodlibet/quodlibet-2.4.91.ebuild
new file mode 100644
index 000000000000..d0167ae29838
--- /dev/null
+++ b/media-sound/quodlibet/quodlibet-2.4.91.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-sound/quodlibet/quodlibet-2.4.91.ebuild,v 1.1 2012/12/11 17:15:05 ssuominen Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+inherit distutils-r1 gnome2-utils fdo-mime
+
+DESCRIPTION="audio library tagger, manager, and player for GTK+"
+HOMEPAGE="http://code.google.com/p/quodlibet/"
+SRC_URI="http://quodlibet.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+dbus gstreamer ipod +udev"
+
+COMMON_DEPEND=">=dev-python/pygtk-2.24"
+RDEPEND="${COMMON_DEPEND}
+	dev-libs/keybinder:0[python]
+	dev-python/feedparser
+	dev-python/pygobject:2
+	>=media-libs/mutagen-1.20
+	gstreamer? (
+		>=dev-python/gst-python-0.10.2:0.10
+		media-libs/gst-plugins-good:0.10
+		media-plugins/gst-plugins-meta:0.10
+		)
+	!gstreamer? ( media-libs/xine-lib )
+	dbus? (
+		app-misc/media-player-info
+		dev-python/dbus-python
+		)
+	ipod? ( media-libs/libgpod[python] )
+	udev? ( virtual/udev )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool"
+REQUIRED_USE="ipod? ( dbus )"
+
+src_prepare() {
+	sed -i -e '/usr.*bin.*env/s:python:python2:' {exfalso,quodlibet}.py || die
+
+	local qlconfig=${PN}/config.py
+
+	if ! use gstreamer; then
+		sed -i -e '/backend/s:gstbe:xinebe:' ${qlconfig} || die
+	fi
+
+	sed -i -e '/gst_pipeline/s:"":"alsasink":' ${qlconfig} || die
+
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	distutils-r1_src_install
+	dodoc HACKING NEWS README
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/media-sound/quodlibet/quodlibet-2.4.ebuild b/media-sound/quodlibet/quodlibet-2.4.ebuild
index bbbe10d99bca..41fc55d6405d 100644
--- a/media-sound/quodlibet/quodlibet-2.4.ebuild
+++ b/media-sound/quodlibet/quodlibet-2.4.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/quodlibet/quodlibet-2.4.ebuild,v 1.7 2012/12/08 12:33:20 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/quodlibet/quodlibet-2.4.ebuild,v 1.8 2012/12/11 17:15:05 ssuominen Exp $
 
 EAPI=4
 
@@ -39,7 +39,8 @@ DEPEND="${COMMON_DEPEND}
 REQUIRED_USE="ipod? ( dbus )"
 
 src_prepare() {
-	if has_version '>=sys-fs/udev-183'; then
+	# This is properly fixed in 2.4.91, so we don't really bother here
+	if has_version '>=virtual/udev-183'; then
 		sed -i -e '/LoadLibrary/s:libudev.so.0:libudev.so.1:' ${PN}/devices/__init__.py || die
 	fi