Version bump. Update to EAPI 4.

(Portage version: 2.2.0_alpha58/cvs/Linux x86_64)

2 files changed, 59 insertions, 1 deletions

diff --git a/app-misc/vlock/ChangeLog b/app-misc/vlock/ChangeLog
index eb602918ccfa..eb0ad9adcdd0 100644
--- a/app-misc/vlock/ChangeLog
+++ b/app-misc/vlock/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-misc/vlock
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/vlock/ChangeLog,v 1.41 2011/01/05 16:54:09 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/vlock/ChangeLog,v 1.42 2011/09/18 21:08:39 radhermit Exp $
+
+*vlock-2.2.3 (18 Sep 2011)
+
+  18 Sep 2011; Tim Harder <radhermit@gentoo.org> +vlock-2.2.3.ebuild:
+  Version bump. Update to EAPI 4.
 
   05 Jan 2011; Justin Lecher <jlec@gentoo.org> vlock-2.2.2-r2.ebuild:
   Some Clean up
diff --git a/app-misc/vlock/vlock-2.2.3.ebuild b/app-misc/vlock/vlock-2.2.3.ebuild
new file mode 100644
index 000000000000..e57431b026e8
--- /dev/null
+++ b/app-misc/vlock/vlock-2.2.3.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/vlock/vlock-2.2.3.ebuild,v 1.1 2011/09/18 21:08:39 radhermit Exp $
+
+EAPI="4"
+
+inherit eutils pam toolchain-funcs multilib
+
+DESCRIPTION="A console screen locker"
+HOMEPAGE="http://cthulhu.c3d2.de/~toidinamai/vlock/vlock.html"
+SRC_URI="http://cthulhu.c3d2.de/~toidinamai/vlock/archive/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="pam test"
+
+RDEPEND="pam? ( sys-libs/pam )"
+DEPEND="${RDEPEND}
+	test? ( dev-util/cunit )"
+
+pkg_setup() {
+	enewgroup vlock
+}
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}/${PN}-2.2.2-asneeded.patch" \
+		"${FILESDIR}/${PN}-2.2.2-test_process.patch"
+}
+
+src_configure() {
+	if use pam; then
+		myconf="--enable-pam"
+	else
+		myconf="--enable-shadow"
+	fi
+	# this package has handmade configure system which fails with econf...
+	./configure --prefix=/usr \
+				--mandir=/usr/share/man \
+				--libdir=/usr/$(get_libdir) \
+				${myconf} \
+				CC="$(tc-getCC)" \
+				LD="$(tc-getLD)" \
+				CFLAGS="${CFLAGS} -pedantic -std=gnu99" \
+				LDFLAGS="${LDFLAGS}" || die "configure failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	use pam && pamd_mimic_system vlock auth
+	dodoc ChangeLog PLUGINS README README.X11 SECURITY STYLE TODO
+}