New version see bug #193317

(Portage version: 2.1.3.9)

3 files changed, 145 insertions, 1 deletions

diff --git a/media-gfx/blender/ChangeLog b/media-gfx/blender/ChangeLog
index b24a02817851..283a60a2016b 100644
--- a/media-gfx/blender/ChangeLog
+++ b/media-gfx/blender/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/blender
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/ChangeLog,v 1.122 2007/09/19 15:30:57 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/ChangeLog,v 1.123 2007/09/21 23:14:57 lu_zero Exp $
+
+*blender-2.45 (21 Sep 2007)
+
+  21 Sep 2007; Luca Barbato <lu_zero@gentoo.org> +blender-2.45.ebuild:
+  New version, as requested in bug #193317
 
   19 Sep 2007; Luca Barbato <lu_zero@gentoo.org> blender-2.44-r1.ebuild:
   Update internal ffmpeg lib
diff --git a/media-gfx/blender/blender-2.45.ebuild b/media-gfx/blender/blender-2.45.ebuild
new file mode 100644
index 000000000000..159a7a7f5069
--- /dev/null
+++ b/media-gfx/blender/blender-2.45.ebuild
@@ -0,0 +1,136 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/blender/blender-2.45.ebuild,v 1.1 2007/09/21 23:14:57 lu_zero Exp $
+
+inherit multilib flag-o-matic eutils python
+
+#IUSE="jpeg mozilla png sdl static truetype"
+IUSE="blender-game ffmpeg jpeg nls openal openexr png sdl verse"
+FFMPEG_SNAP="0.4.9-p20070616"
+DESCRIPTION="3D Creation/Animation/Publishing System"
+HOMEPAGE="http://www.blender.org/"
+SRC_URI="http://download.blender.org/source/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="|| ( GPL-2 BL )"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND=">=dev-libs/openssl-0.9.6
+	ffmpeg? ( >=media-video/ffmpeg-${FFMPEG_SNAP/-/_}
+			>=media-libs/x264-svn-20061014 )
+	jpeg? ( media-libs/jpeg )
+	media-libs/tiff
+	>=dev-lang/python-2.4
+	nls? ( >=media-libs/freetype-2.0
+			virtual/libintl
+			>=media-libs/ftgl-2.1 )
+	openal? ( media-libs/openal
+			media-libs/freealut )
+	openexr? ( media-libs/openexr )
+	png? ( media-libs/libpng )
+	sdl? ( >=media-libs/libsdl-1.2 )
+	virtual/opengl"
+
+DEPEND="dev-util/scons
+	x11-libs/libXt
+	${RDEPEND}"
+
+blend_with() {
+	local UWORD="$2"
+	if [ -z "${UWORD}" ]; then
+		UWORD="$1"
+	fi
+	if useq $1; then
+		echo "WITH_BF_${UWORD}=1" | tr '[:lower:]' '[:upper:]' \
+			>> ${S}/user-config.py
+	else
+		echo "WITH_BF_${UWORD}=0" | tr '[:lower:]' '[:upper:]' \
+			>> ${S}/user-config.py
+	fi
+}
+
+src_unpack() {
+	unpack ${A}
+	cd ${S}/release/plugins
+	chmod 755 bmake
+	cp -pPR ${S}/source/blender/blenpluginapi include
+
+	cd ${S}
+	epatch ${FILESDIR}/blender-2.37-dirs.patch
+	epatch ${FILESDIR}/blender-2.44-scriptsdir.patch
+	epatch ${FILESDIR}/blender-2.44-swscale.patch
+
+	if use ffmpeg ; then
+		cd ${S}/extern
+		rm -rf ffmpeg
+	fi
+	# pass compiler flags to the scons build system
+	# and set python version to current version in use
+	python_version
+	cat <<- EOF >> ${S}/user-config.py
+		CFLAGS += '${CFLAGS}'
+		BF_PYTHON_VERSION="${PYVER}"
+		BF_PYTHON_INC="/usr/include/python${PYVER}"
+		BF_PYTHON_BINARY="/usr/bin/python${PYVER}"
+		BF_PYTHON_LIB="python${PYVER}"
+	EOF
+
+}
+
+src_compile() {
+	for arg in 'openal' \
+			'openexr' \
+			'jpeg' \
+			'ffmpeg' \
+			'png' \
+			'verse' \
+			'nls international' \
+			'blender-game gameengine'; do
+		blend_with ${arg}
+	done
+
+	# scons uses -l differently -> remove it
+	scons ${MAKEOPTS/-l[0-9]} -h > scons.config
+	scons ${MAKEOPTS/-l[0-9]} || die \
+	"!!! Please add ${S}/scons.config when filing bugs reports to bugs.gentoo.org"
+
+	cd ${S}/release/plugins
+	emake || die
+}
+
+src_install() {
+	exeinto /usr/bin/
+	doexe ${WORKDIR}/install/linux2/blender
+
+	dodir /usr/share/${PN}
+
+	exeinto /usr/$(get_libdir)/${PN}/textures
+	doexe ${S}/release/plugins/texture/*.so
+	exeinto /usr/$(get_libdir)/${PN}/sequences
+	doexe ${S}/release/plugins/sequence/*.so
+	insinto /usr/include/${PN}
+	doins ${S}/release/plugins/include/*.h
+
+	if use nls ; then
+		mv ${WORKDIR}/install/linux2/.blender/{.Blanguages,.bfont.ttf} \
+			${D}/usr/share/${PN}
+		mv ${WORKDIR}/install/linux2/.blender/locale \
+			${D}/usr/share/locale
+	fi
+
+	mv ${WORKDIR}/install/linux2/.blender/scripts ${D}/usr/share/${PN}
+
+	insinto /usr/share/pixmaps
+	doins ${FILESDIR}/${PN}.png
+	insinto /usr/share/applications
+	doins ${FILESDIR}/${PN}.desktop
+
+	dodoc COPYING INSTALL README
+}
+
+pkg_preinst(){
+	if [ -h "${ROOT}/usr/$(get_libdir)/blender/plugins/include" ];
+	then
+		rm -f ${ROOT}/usr/$(get_libdir)/blender/plugins/include
+	fi
+}
diff --git a/media-gfx/blender/files/digest-blender-2.45 b/media-gfx/blender/files/digest-blender-2.45
new file mode 100644
index 000000000000..7ab8c5ecd5ad
--- /dev/null
+++ b/media-gfx/blender/files/digest-blender-2.45
@@ -0,0 +1,3 @@
+MD5 1358ca481b7f2b8eadd3327ebbd563ef blender-2.45.tar.gz 14226829
+RMD160 fd39b59de0f4d770fe26ce39d51356e98b1ec8ea blender-2.45.tar.gz 14226829
+SHA256 921f72a15d4076f62e52674337f5d3a90cd7a82675b12bb549ebe6cd5c9027ae blender-2.45.tar.gz 14226829