revbump -> distutils-r1, deps upgraded, removed 1.6.1

(Portage version: 2.1.11.63/cvs/Linux x86_64, signed Manifest commit with key 0xB8072B0D)

3 files changed, 55 insertions, 52 deletions

diff --git a/dev-python/fabric/ChangeLog b/dev-python/fabric/ChangeLog
index 093295fb10d3..fc7ab51424e6 100644
--- a/dev-python/fabric/ChangeLog
+++ b/dev-python/fabric/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/fabric
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/ChangeLog,v 1.35 2013/06/03 06:06:11 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/ChangeLog,v 1.36 2013/06/08 14:47:17 idella4 Exp $
+
+*fabric-1.6.1-r1 (08 Jun 2013)
+
+  08 Jun 2013; Ian Delaney <idella4@gentoo.org> +fabric-1.6.1-r1.ebuild,
+  -fabric-1.6.1.ebuild:
+  revbump -> distutils-r1, deps upgraded, removed 1.6.1
 
 *fabric-1.6.1 (03 Jun 2013)
 
diff --git a/dev-python/fabric/fabric-1.6.1-r1.ebuild b/dev-python/fabric/fabric-1.6.1-r1.ebuild
new file mode 100644
index 000000000000..d17e91a1050d
--- /dev/null
+++ b/dev-python/fabric/fabric-1.6.1-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/fabric-1.6.1-r1.ebuild,v 1.1 2013/06/08 14:47:17 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+
+inherit distutils-r1
+
+MY_PN="Fabric"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="A simple pythonic tool for remote execution and deployment."
+HOMEPAGE="http://fabfile.org http://pypi.python.org/pypi/Fabric"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/paramiko-1.10.0[${PYTHON_USEDEP}]
+	python_targets_python2_5? ( dev-python/multiprocessing[python_targets_python2_5] )
+	python_targets_python2_6? ( dev-python/multiprocessing[python_targets_python2_6] )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( <dev-python/fudge-1.0 )"
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+src_test() {
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	nosetests tests || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/fabric/fabric-1.6.1.ebuild b/dev-python/fabric/fabric-1.6.1.ebuild
deleted file mode 100644
index 867be3bc15f2..000000000000
--- a/dev-python/fabric/fabric-1.6.1.ebuild
+++ /dev/null
@@ -1,51 +0,0 @@
-# Copyright 1999-2013 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/fabric/fabric-1.6.1.ebuild,v 1.1 2013/06/03 06:06:11 patrick Exp $
-
-EAPI="4"
-PYTHON_DEPEND="2:2.5"
-SUPPORT_PYTHON_ABIS="1"
-RESTRICT_PYTHON_ABIS="2.4 3.* *-jython *-pypy-*"
-DISTUTILS_SRC_TEST="nosetests"
-
-# Requires multiprocessing package from py2.6+
-PYTHON_TESTS_RESTRICTED_ABIS="2.5"
-
-inherit distutils
-
-MY_PN="Fabric"
-MY_P="${MY_PN}-${PV}"
-
-DESCRIPTION="Fabric is a simple, Pythonic tool for remote execution and deployment."
-HOMEPAGE="http://fabfile.org http://pypi.python.org/pypi/Fabric"
-SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc"
-
-RDEPEND=">=dev-python/paramiko-1.10.0"
-DEPEND="${RDEPEND}
-	dev-python/setuptools
-	doc? ( dev-python/sphinx )
-	test? ( <dev-python/fudge-1.0 )"
-
-S="${WORKDIR}/${MY_P}"
-PYTHON_MODULES="fabfile fabric"
-
-src_compile() {
-	distutils_src_compile
-
-	if use doc; then
-		emake -C docs html
-	fi
-}
-
-src_install() {
-	distutils_src_install
-
-	if use doc; then
-		dohtml -r docs/_build/html/
-	fi
-}