Version bump. Integrate more prefix fun.

(Portage version: 2.2.0_alpha19/cvs/Linux x86_64)

1 files changed, 48 insertions, 0 deletions

diff --git a/app-admin/eselect-opengl/eselect-opengl-1.2.1.ebuild b/app-admin/eselect-opengl/eselect-opengl-1.2.1.ebuild
new file mode 100644
index 000000000000..9ffe42e2a049
--- /dev/null
+++ b/app-admin/eselect-opengl/eselect-opengl-1.2.1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect-opengl/eselect-opengl-1.2.1.ebuild,v 1.1 2011/01/26 19:27:41 scarabeus Exp $
+
+EAPI=3
+
+inherit multilib
+
+DESCRIPTION="Utility to change the OpenGL interface being used"
+HOMEPAGE="http://www.gentoo.org/"
+
+# Source:
+# http://www.opengl.org/registry/api/glext.h
+# http://www.opengl.org/registry/api/glxext.h
+GLEXT="67"
+GLXEXT="32"
+
+MIRROR="http://dev.gentooexperimental.org/~scarabeus/"
+SRC_URI="${MIRROR}/glext.h.${GLEXT}.xz
+	${MIRROR}/glxext.h.${GLXEXT}.xz
+	${MIRROR}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+DEPEND="app-arch/xz-utils"
+RDEPEND=">=app-admin/eselect-1.2.4"
+
+pkg_postinst() {
+	local impl="$(eselect opengl show)"
+	if [[ -n "${impl}"  && "${impl}" != '(none)' ]] ; then
+		eselect opengl set "${impl}"
+	fi
+}
+
+src_install() {
+	insinto "/usr/share/eselect/modules"
+	doins opengl.eselect || die
+	doman opengl.eselect.5 || die
+
+	# Install global glext.h and glxext.h
+	insinto "/usr/$(get_libdir)/opengl/global/include"
+	cd "${WORKDIR}"
+	newins glext.h.${GLEXT} glext.h || die
+	newins glxext.h.${GLXEXT} glxext.h || die
+}