Rewrite the ebuilds to not require autotools/newer EAPI to make upgrading simple.

(Portage version: 2.2.0_alpha72/cvs/Linux x86_64)

1 files changed, 56 insertions, 0 deletions

diff --git a/app-admin/eselect-python/eselect-python-20111108.ebuild b/app-admin/eselect-python/eselect-python-20111108.ebuild
new file mode 100644
index 000000000000..9f82be490e2d
--- /dev/null
+++ b/app-admin/eselect-python/eselect-python-20111108.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect-python/eselect-python-20111108.ebuild,v 1.1 2011/11/08 23:55:51 vapier Exp $
+
+# Keep the EAPI low here because everything else depends on it.
+# We want to make upgrading simpler.
+
+ESVN_PROJECT="eselect-python"
+ESVN_REPO_URI="https://overlays.gentoo.org/svn/proj/python/projects/eselect-python/trunk"
+
+if [[ ${PV} == "99999999" ]] ; then
+	inherit autotools subversion
+else
+	SRC_URI="mirror://gentoo/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+fi
+
+DESCRIPTION="Eselect module for management of multiple Python versions"
+HOMEPAGE="http://www.gentoo.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+RDEPEND=">=app-admin/eselect-1.2.3"
+# Avoid autotool deps for released versions for circ dep issues.
+if [[ ${PV} == "99999999" ]] ; then
+	DEPEND="sys-devel/autoconf"
+else
+	DEPEND=""
+fi
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	[[ -x configure ]] || eautoreconf
+}
+
+src_install() {
+	keepdir /etc/env.d/python
+	emake DESTDIR="${D}" install || die
+}
+
+pkg_preinst() {
+	if has_version "<${CATEGORY}/${PN}-20090804" || ! has_version "${CATEGORY}/${PN}"; then
+		run_eselect_python_update="1"
+	fi
+}
+
+pkg_postinst() {
+	if [[ "${run_eselect_python_update}" == "1" ]]; then
+		ebegin "Running \`eselect python update\`"
+		eselect python update --ignore 3.0 --ignore 3.1 --ignore 3.2 > /dev/null
+		eend "$?"
+	fi
+}