3.5 branch version bump

(Portage version: 2.2.8-r1/cvs/Linux x86_64, unsigned Manifest commit)

2 files changed, 127 insertions, 1 deletions

diff --git a/app-admin/syslog-ng/ChangeLog b/app-admin/syslog-ng/ChangeLog
index 594926a24ffb..e49163f0a8ea 100644
--- a/app-admin/syslog-ng/ChangeLog
+++ b/app-admin/syslog-ng/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-admin/syslog-ng
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.392 2014/07/08 17:06:56 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.393 2014/07/21 15:51:50 mr_bones_ Exp $
+
+*syslog-ng-3.5.5 (21 Jul 2014)
+
+  21 Jul 2014; Michael Sterrett <mr_bones_@gentoo.org> +syslog-ng-3.5.5.ebuild:
+  3.5 branch version bump
 
   08 Jul 2014; Michael Sterrett <mr_bones_@gentoo.org> syslog-ng-3.4.8.ebuild:
   add amqp use flag (bug #516704)
diff --git a/app-admin/syslog-ng/syslog-ng-3.5.5.ebuild b/app-admin/syslog-ng/syslog-ng-3.5.5.ebuild
new file mode 100644
index 000000000000..e526a5666c2b
--- /dev/null
+++ b/app-admin/syslog-ng/syslog-ng-3.5.5.ebuild
@@ -0,0 +1,121 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.5.5.ebuild,v 1.1 2014/07/21 15:51:50 mr_bones_ Exp $
+
+EAPI=5
+inherit eutils multilib systemd versionator
+
+MY_PV=${PV/_/}
+MY_PV_MM=$(get_version_component_range 1-2)
+DESCRIPTION="syslog replacement with advanced filtering features"
+HOMEPAGE="http://www.balabit.com/network-security/syslog-ng"
+SRC_URI="http://www.balabit.com/downloads/files/syslog-ng/sources/${MY_PV}/source/syslog-ng_${MY_PV}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="amqp caps dbi geoip ipv6 json mongodb pacct +pcre smtp spoof-source ssl systemd tcpd"
+RESTRICT="test"
+
+RDEPEND="
+	pcre? ( dev-libs/libpcre )
+	spoof-source? ( net-libs/libnet:1.1 )
+	ssl? ( dev-libs/openssl:= )
+	smtp? ( net-libs/libesmtp )
+	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
+	>=dev-libs/eventlog-0.2.12
+	>=dev-libs/glib-2.10.1:2
+	json? ( >=dev-libs/json-c-0.9 )
+	caps? ( sys-libs/libcap )
+	geoip? ( >=dev-libs/geoip-1.5.0 )
+	dbi? ( >=dev-db/libdbi-0.8.3 )
+	systemd? ( sys-apps/systemd )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	sys-devel/flex"
+
+S=${WORKDIR}/${PN}-${MY_PV}
+
+src_prepare() {
+	cp "${FILESDIR}"/*logrotate*.in "${TMPDIR}" || die
+	cd "${TMPDIR}" || die
+
+	for f in *logrotate*.in ; do
+		if use systemd ; then
+			sed \
+				's/@GENTOO_RESTART@/systemctl kill -s HUP syslog-ng/' \
+				$f > ${f/.in/} || die
+		else
+			sed \
+				's:@GENTOO_RESTART@:/etc/init.d/syslog-ng reload:' \
+				$f > ${f/.in/} || die
+		fi
+	done
+}
+
+src_configure() {
+	econf \
+		--disable-docs \
+		--with-ivykis=internal \
+		--with-libmongo-client=internal \
+		--sysconfdir=/etc/syslog-ng \
+		--localstatedir=/var/lib/syslog-ng \
+		--with-pidfile-dir=/var/run \
+		--with-module-dir=/usr/$(get_libdir)/syslog-ng \
+		$(systemd_with_unitdir) \
+		$(use_enable systemd) \
+		$(use_enable caps linux-caps) \
+		$(use_enable geoip) \
+		$(use_enable ipv6) \
+		$(use_enable json) \
+		$(use_enable mongodb) \
+		$(use_enable pacct) \
+		$(use_enable pcre) \
+		$(use_enable smtp) \
+		$(use_enable amqp) \
+		$(usex amqp --with-librabbitmq-client=internal --without-librabbitmq-client) \
+		$(use_enable spoof-source) \
+		$(use_enable dbi sql) \
+		$(use_enable ssl) \
+		$(use_enable tcpd tcp-wrapper)
+}
+
+src_install() {
+	# -j1 for bug #484470
+	emake -j1 DESTDIR="${D}" install
+
+	dodoc AUTHORS NEWS contrib/syslog-ng.conf* contrib/syslog2ng \
+		"${FILESDIR}/${MY_PV_MM}/syslog-ng.conf.gentoo.hardened" \
+		"${TMPDIR}/syslog-ng.logrotate.hardened" \
+		"${FILESDIR}/README.hardened"
+
+	# Install default configuration
+	insinto /etc/syslog-ng
+	if use userland_BSD ; then
+		newins "${FILESDIR}/${MY_PV_MM}/syslog-ng.conf.gentoo.fbsd" syslog-ng.conf
+	else
+		newins "${FILESDIR}/${MY_PV_MM}/syslog-ng.conf.gentoo" syslog-ng.conf
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${TMPDIR}/syslog-ng.logrotate" syslog-ng
+
+	newinitd "${FILESDIR}/${MY_PV_MM}/syslog-ng.rc6" syslog-ng
+	newconfd "${FILESDIR}/${MY_PV_MM}/syslog-ng.confd" syslog-ng
+	keepdir /etc/syslog-ng/patterndb.d /var/lib/syslog-ng
+	prune_libtool_files --modules
+}
+
+pkg_postinst() {
+	elog "For detailed documentation please see the upstream website:"
+	elog "http://www.balabit.com/sites/default/files/documents/syslog-ng-ose-3.5-guides/en/syslog-ng-ose-v3.5-guide-admin/html/index.html"
+
+	# bug #355257
+	if ! has_version app-admin/logrotate ; then
+		echo
+		elog "It is highly recommended that app-admin/logrotate be emerged to"
+		elog "manage the log files.  ${PN} installs a file in /etc/logrotate.d"
+		elog "for logrotate to use."
+		echo
+	fi
+}