Version bump, add i2500vfd, irtrans, lis and shuttlevfd drivers.

(Portage version: 2.1.6.13/cvs/Linux x86_64)

4 files changed, 199 insertions, 4 deletions

diff --git a/app-misc/lcdproc/ChangeLog b/app-misc/lcdproc/ChangeLog
index d5475b29a9e7..41fc436c9377 100644
--- a/app-misc/lcdproc/ChangeLog
+++ b/app-misc/lcdproc/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-misc/lcdproc
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/ChangeLog,v 1.65 2009/05/16 08:57:16 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/ChangeLog,v 1.66 2009/06/08 15:18:51 rbu Exp $
+
+*lcdproc-0.5.3_pre1 (08 Jun 2009)
+
+  08 Jun 2009; Robert Buchholz <rbu@gentoo.org> metadata.xml,
+  lcdproc-0.5.1-r4.ebuild, +lcdproc-0.5.3_pre1.ebuild:
+  Version bump, add i2500vfd, irtrans, lis and shuttlevfd drivers.
 
   16 May 2009; Robin H. Johnson <robbat2@gentoo.org>
   lcdproc-0.5.1-r4.ebuild, lcdproc-0.5.2-r1.ebuild, lcdproc-0.5.2-r2.ebuild:
diff --git a/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild b/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild
index ad653fee5fc4..a1c70aa6f89c 100644
--- a/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild
+++ b/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild
@@ -1,9 +1,7 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild,v 1.8 2009/05/16 08:57:16 robbat2 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.1-r4.ebuild,v 1.9 2009/06/08 15:18:51 rbu Exp $
 
-WANT_AUTOCONF="latest"
-WANT_AUTOMAKE="latest"
 inherit eutils autotools multilib
 
 DESCRIPTION="Client/Server suite to drive all kinds of LCD (-like) devices"
diff --git a/app-misc/lcdproc/lcdproc-0.5.3_pre1.ebuild b/app-misc/lcdproc/lcdproc-0.5.3_pre1.ebuild
new file mode 100644
index 000000000000..612a705fabdf
--- /dev/null
+++ b/app-misc/lcdproc/lcdproc-0.5.3_pre1.ebuild
@@ -0,0 +1,190 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/lcdproc/lcdproc-0.5.3_pre1.ebuild,v 1.1 2009/06/08 15:18:51 rbu Exp $
+
+EAPI=2
+inherit multilib versionator
+
+MY_PV=$(replace_version_separator 3 '-')
+MY_P=${PN}-${MY_PV}
+S=${WORKDIR}/${MY_P}
+
+
+DESCRIPTION="Client/Server suite to drive all kinds of LCD (-like) devices"
+HOMEPAGE="http://lcdproc.org/"
+SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="doc debug nfs samba seamless-hbars usb lirc irman joystick ftdi"
+
+# The following array holds the USE_EXPANDed keywords
+IUSE_LCD_DEVICES=(ncurses bayrad cfontz cfontz633 cfontzpacket
+	cwlinux eyeboxone g15 graphlcd glk
+	hd44780 icpa106 imon imonlcd iowarrior
+	lb216 lcdm001 lcterm
+	md8800 ms6931 mtcs16209x mtxorb noritakevfd
+	pyramid sed1330 sed1520 serialvfd sli
+	stv5730 svga t6963 text tyan
+	ula200 xosd ea65 picolcd serialpos
+	i2500vfd irtrans lis shuttlevfd )
+
+# Iterate through the array and add the lcd_devices_* that we support
+NUM_DEVICES=${#IUSE_LCD_DEVICES[@]}
+index=0
+while [ "${index}" -lt "${NUM_DEVICES}" ] ; do
+	IUSE="${IUSE} lcd_devices_${IUSE_LCD_DEVICES[${index}]}"
+	let "index = ${index} + 1"
+done
+
+RDEPEND="
+	usb?      ( virtual/libusb:0 )
+	ftdi?     ( dev-embedded/libftdi )
+	lirc?     ( app-misc/lirc )
+	irman?    ( media-libs/libirman )
+
+	lcd_devices_graphlcd?  ( app-misc/graphlcd-base  app-misc/glcdprocdriver )
+	lcd_devices_g15?       ( dev-libs/libg15  dev-libs/libg15render )
+	lcd_devices_ncurses?   ( sys-libs/ncurses )
+	lcd_devices_svga?      ( media-libs/svgalib )
+	lcd_devices_ula200?    ( dev-embedded/libftdi )
+	lcd_devices_xosd?      ( x11-libs/xosd  x11-libs/libX11  x11-libs/libXext )
+	lcd_devices_cfontzpacket? ( virtual/libusb:0 )
+	lcd_devices_cwlinux?    ( virtual/libusb:0 )
+	lcd_devices_pyramid?    ( virtual/libusb:0 )
+	lcd_devices_picolcd?    ( virtual/libusb:0 )
+	lcd_devices_i2500vfd?   ( dev-embedded/libftdi )
+	lcd_devices_lis?        ( dev-embedded/libftdi virtual/libusb:0 )
+	lcd_devices_shuttlevfd? ( virtual/libusb:0 )"
+DEPEND="${RDEPEND}
+	doc?      ( app-text/xmlto )"
+RDEPEND="${RDEPEND}
+	lcd_devices_g15?      ( app-misc/g15daemon )"
+
+pkg_setup() {
+	if [ -n "${LCDPROC_DRIVERS}" ] ; then
+		ewarn "Setting the drivers to compile via LCDPROC_DRIVERS is not supported anymore."
+		ewarn "Please use LCD_DEVICES now and see emerge -pv output for the options."
+	fi
+}
+
+src_prepare() {
+	sed -i "79s:server/drivers:/usr/$(get_libdir)/lcdproc:" LCDd.conf
+	einfo "Patching LCDd.conf to use DriverPath=/usr/$(get_libdir)/lcdproc/"
+}
+
+src_configure() {
+	# This array contains the driver names required by configure --with-drivers=
+	# The positions must be the same as the corresponding use_expand flags
+	local DEVICE_DRIVERS=(curses bayrad CFontz CFontz633 CFontzPacket
+		CwLnx EyeboxOne g15 glcdlib glk
+		hd44780 icp_a106 imon imonlcd IOWarrior
+		lb216 lcdm001 lcterm
+		MD8800 ms6931 mtc_s16209x MtxOrb NoritakeVFD
+		pyramid sed1330 sed1520 serialVFD sli
+		stv5730 svga t6963 text tyan
+		ula200 xosd ea65 picolcd serialPOS
+		i2500vfd irtrans lis shuttleVFD )
+
+	# Generate comma separated list of drivers
+	COMMA_DRIVERS=""
+	FIRST_DRIVER=""
+	local index=0
+
+	while [ "${index}" -lt "${NUM_DEVICES}" ] ; do
+		if use "lcd_devices_${IUSE_LCD_DEVICES[${index}]}" ; then
+			append-driver "${DEVICE_DRIVERS[${index}]}"
+		fi
+		let "index = ${index} + 1"
+	done
+
+	# Append the not-lcd-drivers (input)
+	use lirc && append-driver "lirc"
+	use irman && append-driver "irman"
+	use joystick && append-driver "joy"
+
+	if [ -z "${COMMA_DRIVERS}" ] ; then
+		ewarn "You are compiling LCDd without support for any LCD drivers at all."
+	else
+		# Patch the config to contain a driver that is actually installed instead of the default
+		elog "Compiling the following drivers for LCDd: ${COMMA_DRIVERS}"
+		elog "Setting Driver=${FIRST_DRIVER} in LCDd.conf"
+		sed -i "44s:curses:${FIRST_DRIVER}:" LCDd.conf
+	fi
+
+	local EXTRA_CONF
+	if use lcd_devices_cfontzpacket || use lcd_devices_cwlinux || use lcd_devices_pyramid || \
+		use lcd_devices_picolcd || use lcd_devices_lis || use lcd_devices_shuttlevfd ; then
+		EXTRA_CONF="--enable-libusb"
+	else
+		EXTRA_CONF="$(use_enable usb libusb)"
+	fi
+
+	if use lcd_devices_ula200 || use lcd_devices_i2500vfd || use lcd_devices_lis ; then
+		EXTRA_CONF="${EXTRA_CONF} --enable-libftdi"
+	else
+		EXTRA_CONF="${EXTRA_CONF} $(use_enable ftdi libftdi)"
+	fi
+
+	econf \
+		$(use_enable debug) \
+		$(use_enable nfs stat-nfs) \
+		$(use_enable samba stat-smbfs ) \
+		$(use_enable seamless-hbars) \
+		${EXTRA_CONF} \
+		"--enable-drivers=${COMMA_DRIVERS}"  \
+		|| die "configure failed"
+}
+
+src_compile() {
+	default
+
+	if use doc; then
+		ebegin "Creating user documentation"
+		cd "${S}"/docs/lcdproc-user
+		xmlto html lcdproc-user.docbook
+		eend $?
+
+		ebegin "Creating dev documentation"
+		cd "${S}"/docs/lcdproc-dev
+		xmlto html lcdproc-dev.docbook
+		eend $?
+	fi
+}
+
+append-driver() {
+	[[ -z $* ]] && return 0
+	if [ -z "${COMMA_DRIVERS}" ] ; then
+		# First in the list
+		COMMA_DRIVERS="$*"
+		FIRST_DRIVER="$*"
+	else
+		# Second, third, ... include a comma at the front
+		COMMA_DRIVERS="${COMMA_DRIVERS},$*"
+	fi
+	return 0
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "make install failed"
+
+	# move example clients installed to /usr/bin
+	rm -f "${D}"/usr/bin/{tail,lcdmetar,iosock,fortune,x11amp}.pl
+	insinto /usr/share/lcdproc/clients
+	doins clients/examples/*.pl
+	doins clients/metar/
+
+	newinitd "${FILESDIR}/0.5.1-LCDd.initd" LCDd
+	newinitd "${FILESDIR}/0.5.2-r2-lcdproc.initd" lcdproc
+
+	dodoc README CREDITS ChangeLog INSTALL TODO
+
+	if use doc; then
+		insinto /usr/share/doc/${PF}/lcdproc-user
+		doins docs/lcdproc-user/*.html
+		insinto /usr/share/doc/${PF}/lcdproc-dev
+		doins docs/lcdproc-dev/*.html
+	fi
+}
diff --git a/app-misc/lcdproc/metadata.xml b/app-misc/lcdproc/metadata.xml
index 30fbfbd808e0..abd486394891 100644
--- a/app-misc/lcdproc/metadata.xml
+++ b/app-misc/lcdproc/metadata.xml
@@ -20,5 +20,6 @@
     (<pkg>media-libs/libirman</pkg>)</flag>
   <flag name='nfs'>Adds support for NFS file system</flag>
   <flag name='seamless-hbars'>Try to avoid gaps in horizontal bars</flag>
+  <flag name='ftdi'>Enable support for FTDI connections in some selected LCD_DEVICES (currently hd44780)</flag>
 </use>
 </pkgmetadata>