Clean up deps a bit.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

2 files changed, 104 insertions, 1 deletions

diff --git a/app-misc/strigi/ChangeLog b/app-misc/strigi/ChangeLog
index 570c640bdbb8..1bf0131fd21c 100644
--- a/app-misc/strigi/ChangeLog
+++ b/app-misc/strigi/ChangeLog
@@ -1,6 +1,14 @@
 # ChangeLog for app-misc/strigi
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/strigi/ChangeLog,v 1.34 2009/04/11 15:46:47 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/strigi/ChangeLog,v 1.35 2009/05/14 20:17:12 scarabeus Exp $
+
+  14 May 2009; Tomas Chvatal <scarabeus@gentoo.org> +strigi-0.6.5.ebuild:
+  Clean up deps a bit.
+
+*strigi-0.6.5 (14 May 2009)
+
+  14 May 2009; Tomas Chvatal <scarabeus@gentoo.org> +strigi-0.6.5.ebuild:
+  Version bump. Per bug #269872.
 
   11 Apr 2009; Raúl Porcel <armin76@gentoo.org> strigi-0.6.4.ebuild:
   Add ~alpha/~ia64
diff --git a/app-misc/strigi/strigi-0.6.5.ebuild b/app-misc/strigi/strigi-0.6.5.ebuild
new file mode 100644
index 000000000000..eb9d285a5d1b
--- /dev/null
+++ b/app-misc/strigi/strigi-0.6.5.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/strigi/strigi-0.6.5.ebuild,v 1.1 2009/05/14 20:17:12 scarabeus Exp $
+
+EAPI="2"
+
+inherit cmake-utils eutils
+
+DESCRIPTION="Fast crawling desktop search engine with Qt4 GUI"
+HOMEPAGE="http://strigi.sourceforge.net/"
+SRC_URI="http://www.vandenoever.info/software/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~x86"
+IUSE="+clucene +dbus debug exif fam hyperestraier inotify log +qt4 test"
+
+COMMONDEPEND="
+	dev-libs/libxml2
+	virtual/libiconv
+	>=virtual/poppler-utils-0.8
+	clucene? ( >=dev-cpp/clucene-0.9.19[-debug] )
+	dbus? (
+		x11-libs/qt-dbus:4
+		x11-libs/qt-gui:4
+	)
+	exif? ( >=media-gfx/exiv2-0.17 )
+	fam? ( virtual/fam )
+	hyperestraier? ( app-text/hyperestraier )
+	log? ( >=dev-libs/log4cxx-0.10.0 )
+	qt4? (
+		x11-libs/qt-core:4
+		x11-libs/qt-gui:4
+		x11-libs/qt-dbus:4
+	)
+	!clucene? (
+		!hyperestraier? (
+			>=dev-cpp/clucene-0.9.19[-debug]
+		)
+	)
+"
+DEPEND="${COMMONDEPEND}
+	test? ( dev-util/cppunit )"
+RDEPEND="${COMMONDEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.6.4-gcc44.patch
+}
+
+src_configure() {
+	# Strigi needs either expat or libxml2.
+	# However libxml2 seems to be required in both cases, linking to 2 xml parsers
+	# is just silly, so we forcefully disable linking to expat.
+	# Enabled: POLLING (only reliable way to check for files changed.)
+
+	mycmakeargs="${mycmakeargs}
+		-DENABLE_EXPAT=OFF -DENABLE_POLLING=ON
+		-DFORCE_DEPS=ON -DENABLE_CPPUNIT=OFF
+		-DENABLE_REGENERATEXSD=OFF
+		$(cmake-utils_use_enable clucene CLUCENE)
+		$(cmake-utils_use_enable dbus DBUS)
+		$(cmake-utils_use_enable exif EXIV2)
+		$(cmake-utils_use_enable fam FAM)
+		$(cmake-utils_use_enable hyperestraier HYPERESTRAIER)
+		$(cmake-utils_use_enable inotify INOTIFY)
+		$(cmake-utils_use_enable log LOG4CXX)
+		$(cmake-utils_use_enable qt4 DBUS)
+		$(cmake-utils_use_enable qt4 QT4)"
+
+	if ! use clucene && ! use hyperestraier; then
+		mycmakeargs="${mycmakeargs} -DENABLE_CLUCENE=ON"
+	fi
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	mycmakeargs="${mycmakeargs} -DENABLE_CPPUNIT=ON"
+	cmake-utils_src_configure
+	cmake-utils_src_compile
+
+	pushd "${CMAKE_BUILD_DIR}" > /dev/null
+	ctest --extra-verbose || die "Tests failed."
+	popd > /dev/null
+}
+
+pkg_postinst() {
+	if ! use clucene && ! use hyperestraier; then
+		elog "Because you didn't enable any of the supported backends:"
+		elog "clucene, hyperestraier and sqlite"
+		elog "clucene support was silently installed."
+		elog "If you prefer another backend, be sure to reinstall strigi"
+		elog "and to enable that backend use flag"
+	fi
+}