fix bug #140467 by Jakub (nls is now in IUSE, and fixed the actual dep to intltool. Also, 2.0.0-r1 is hard-masked, but needs testing by some of you fine folks out there for its extra features: locale-specific-taxes, removal of depreacted functions, documentation extras like LaTeX, dot (graphviz) and html docs. Please test and report

(Portage version: 2.1.1_pre2-r8)

4 files changed, 122 insertions, 4 deletions

diff --git a/app-office/gnucash/ChangeLog b/app-office/gnucash/ChangeLog
index 4d810abdc53f..3ac570bcb322 100644
--- a/app-office/gnucash/ChangeLog
+++ b/app-office/gnucash/ChangeLog
@@ -1,6 +1,16 @@
 # ChangeLog for app-office/gnucash
 # Copyright 2002-2006 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.80 2006/07/12 12:46:05 seemant Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.81 2006/07/15 14:17:27 seemant Exp $
+
+*gnucash-2.0.0-r1 (15 Jul 2006)
+
+  15 Jul 2006; Seemant Kulleen <seemant@gentoo.org> gnucash-2.0.0.ebuild,
+  +gnucash-2.0.0-r1.ebuild:
+  fix bug #140467 by Jakub (nls is now in IUSE, and fixed the actual dep to
+  intltool. Also, 2.0.0-r1 is hard-masked, but needs testing by some of you
+  fine folks out there for its extra features: locale-specific-taxes, removal
+  of depreacted functions, documentation extras like LaTeX, dot (graphviz) and
+  html docs. Please test and report
 
   12 Jul 2006; Seemant Kulleen <seemant@gentoo.org> gnucash-2.0.0.ebuild:
   Update to the new GTK2 version. This has been a long time coming. Thanks a
diff --git a/app-office/gnucash/files/digest-gnucash-2.0.0-r1 b/app-office/gnucash/files/digest-gnucash-2.0.0-r1
new file mode 100644
index 000000000000..a5a631b96c5a
--- /dev/null
+++ b/app-office/gnucash/files/digest-gnucash-2.0.0-r1
@@ -0,0 +1,6 @@
+MD5 d5802c398825500ec322bb2b3229aadd gnucash-2.0.0.tar.gz 10244964
+RMD160 db908189fd82a853d5782ba4df66616874a609dd gnucash-2.0.0.tar.gz 10244964
+SHA256 a61c310dcf4d94da15c46a5f85951e4b0e7524b6b256b8a803f9b275b3066c50 gnucash-2.0.0.tar.gz 10244964
+MD5 9a84f681330aa61ea1aa7448b87e86a4 gnucash-docs-2.0.0.tar.gz 9390564
+RMD160 e9e4ef7175cf2f02b587b0b0c49d34ca4d20fa2c gnucash-docs-2.0.0.tar.gz 9390564
+SHA256 926c94d19865b7da3c49d025ad15d7125c9a5b2a1d05d816234e73678f393cb7 gnucash-docs-2.0.0.tar.gz 9390564
diff --git a/app-office/gnucash/gnucash-2.0.0-r1.ebuild b/app-office/gnucash/gnucash-2.0.0-r1.ebuild
new file mode 100644
index 000000000000..ca1cee94b33a
--- /dev/null
+++ b/app-office/gnucash/gnucash-2.0.0-r1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.0.0-r1.ebuild,v 1.1 2006/07/15 14:17:27 seemant Exp $
+
+inherit eutils gnome2
+
+DOC_VER="2.0.0"
+
+DESCRIPTION="A personal finance manager."
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz
+	mirror://sourceforge/${PN}/${PN}-docs-${DOC_VER}.tar.gz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="postgres ofx hbci chipcard doc debug quotes nls graphviz tetex"
+
+RDEPEND=">=dev-libs/glib-2.4.0
+	>=dev-util/guile-1.6.4-r2
+	>=dev-libs/slib-2.3.8
+	>=sys-libs/zlib-1.1.4
+	>=dev-libs/popt-1.5
+	>=x11-libs/gtk+-2.4
+	>=gnome-base/libgnomeui-2.4
+	>=gnome-base/libgnomeprint-2.10
+	>=gnome-base/libgnomeprintui-2.10
+	>=gnome-base/libglade-2.4
+	>=gnome-extra/gtkhtml-3.10.1
+	>=dev-libs/libxml2-2.5.10
+	>=dev-libs/g-wrap-1.3.4
+	>=gnome-base/gconf-2
+	>=app-text/scrollkeeper-0.3
+	>=x11-libs/goffice-0.0.4
+	ofx? ( >=dev-libs/libofx-0.7.0 )
+	hbci? ( net-libs/aqbanking
+		chipcard? ( sys-libs/libchipcard )
+	)
+	quotes? ( dev-perl/DateManip
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/HTML-TableExtract )
+	postgres? ( dev-db/postgresql )
+	app-text/docbook-xsl-stylesheets
+	=app-text/docbook-xml-dtd-4.1.2*
+	nls? ( dev-util/intltool )
+	graphviz? ( media-gfx/graphviz )
+	tetex? ( app-text/tetex )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	built_with_use gnome-extra/libgsf gnome || die "gnome-extra/libgsf must be built with gnome"
+	built_with_use x11-libs/goffice gnome || die "x11-libs/goffice must be built with gnome"
+}
+
+src_compile() {
+
+	local myconf
+
+	if use doc ; then
+		myconf="$(use_enable graphviz dot)"
+		myconf="${myconf} $(use_enable tetex latex-docs)"
+	fi
+
+	econf \
+		$(use_enable debug) \
+		$(use_enable postgres sql) \
+		$(use_enable ofx) \
+		$(use_enable doc doxygen) \
+		$(use_enable doc html-docs) \
+		$(use_enable hbci) \
+		--disable-deprecated-glib \
+		--disable-deprecated-gdk \
+		--disable-deprecated-gtk \
+		--disable-deprecated-gnome \
+		--enable-locale-specific-tax \
+		${myconf} || die "econf failed"
+
+	MAKEOPTS="-j1"
+	emake || die "emake failed"
+
+	cd "${WORKDIR}/gnucash-docs-${DOC_VER}"
+	econf || die "doc econf failed"
+	emake || die "doc emake failed"
+}
+
+# See http://bugs.gentoo.org/show_bug.cgi?id=132862 regarding gconf schema install
+
+src_install() {
+	gnome2_src_install || die "gnome2_src_install failed"
+	dodoc AUTHORS ChangeLog* DOCUMENTERS HACKING INSTALL NEWS TODO README* doc/README*
+	make_desktop_entry ${P} "GnuCash ${PV}" gnucash-icon.png "GNOME;Office;Finance"
+
+	cd "${WORKDIR}/${PN}-docs-${DOC_VER}"
+	make DESTDIR="${D}" \
+		scrollkeeper_localstate_dir="${D}/var/lib/scrollkeeper" \
+		install || die "doc install failed"
+	rm -rf "${D}/var/lib/scrollkeeper"
+}
diff --git a/app-office/gnucash/gnucash-2.0.0.ebuild b/app-office/gnucash/gnucash-2.0.0.ebuild
index aa6093a58975..8a2b4ef6c0d2 100644
--- a/app-office/gnucash/gnucash-2.0.0.ebuild
+++ b/app-office/gnucash/gnucash-2.0.0.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2006 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.0.0.ebuild,v 1.2 2006/07/12 12:46:05 seemant Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.0.0.ebuild,v 1.3 2006/07/15 14:17:27 seemant Exp $
 
 inherit eutils gnome2
 
@@ -15,7 +15,7 @@ SLOT="0"
 LICENSE="GPL-2"
 KEYWORDS="~amd64 ~x86"
 
-IUSE="postgres ofx hbci chipcard doc debug quotes"
+IUSE="postgres ofx hbci chipcard doc debug quotes nls"
 
 RDEPEND=">=dev-libs/glib-2.4.0
 	>=dev-util/guile-1.6.4-r2
@@ -47,7 +47,7 @@ RDEPEND=">=dev-libs/glib-2.4.0
 DEPEND="${RDEPEND}
 	doc? ( app-doc/doxygen )
 	dev-util/pkgconfig
-	nls? ( sys-devel/gettext )"
+	nls? ( dev-util/intltool )"
 
 pkg_setup() {
 	built_with_use gnome-extra/libgsf gnome || die "gnome-extra/libgsf must be built with gnome"