virtual/tetex (bug #152409), new version (bug #158251), startup crash (bug #162229)

(Portage version: 2.1.2-r3)

4 files changed, 126 insertions, 3 deletions

diff --git a/app-office/gnucash/ChangeLog b/app-office/gnucash/ChangeLog
index bd95d17e0c76..79b300ab6d64 100644
--- a/app-office/gnucash/ChangeLog
+++ b/app-office/gnucash/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-office/gnucash
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.114 2007/01/10 19:00:36 peper Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/ChangeLog,v 1.115 2007/01/24 20:13:17 seemant Exp $
+
+*gnucash-2.0.4 (24 Jan 2007)
+
+  24 Jan 2007; Seemant Kulleen <seemant@gentoo.org> gnucash-2.0.1.ebuild,
+  +gnucash-2.0.4.ebuild:
+  virtual/tetex (bug #152409), new version (bug #158251), startup crash (bug
+  #162229)
 
   10 Jan 2007; Piotr Jaroszyński <peper@gentoo.org> Manifest:
   Fix Manifest.
diff --git a/app-office/gnucash/files/digest-gnucash-2.0.4 b/app-office/gnucash/files/digest-gnucash-2.0.4
new file mode 100644
index 000000000000..7169d56b95bb
--- /dev/null
+++ b/app-office/gnucash/files/digest-gnucash-2.0.4
@@ -0,0 +1,6 @@
+MD5 5755b05a3eaebab392fe9ad49073beb2 gnucash-2.0.4.tar.bz2 7355992
+RMD160 8a0ef12f5e670585f1a674eebc65c3a3c4668a78 gnucash-2.0.4.tar.bz2 7355992
+SHA256 6c3515743f1e08e32cd0aae101feba39aea072a5c2e5a0cc8338f7df78b5ace2 gnucash-2.0.4.tar.bz2 7355992
+MD5 ffc058efd0283a4b43ca31980c40db49 gnucash-docs-2.0.1.tar.bz2 9262237
+RMD160 f2b00a5ce745921ea4e8a2360baff13aaf3fc083 gnucash-docs-2.0.1.tar.bz2 9262237
+SHA256 f39e6248fef20c761c74b534024869952e26b98879930b3a675178fd3d5260ff gnucash-docs-2.0.1.tar.bz2 9262237
diff --git a/app-office/gnucash/gnucash-2.0.1.ebuild b/app-office/gnucash/gnucash-2.0.1.ebuild
index 19a058a7a7d9..a837bfb5d102 100644
--- a/app-office/gnucash/gnucash-2.0.1.ebuild
+++ b/app-office/gnucash/gnucash-2.0.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2007 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.0.1.ebuild,v 1.17 2007/01/10 17:48:24 hkbst Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.0.1.ebuild,v 1.18 2007/01/24 20:13:17 seemant Exp $
 
 inherit eutils gnome2
 
@@ -45,7 +45,7 @@ RDEPEND=">=dev-libs/glib-2.4.0
 	app-text/docbook-xsl-stylesheets
 	=app-text/docbook-xml-dtd-4.1.2*
 	nls? ( dev-util/intltool )
-	tetex? ( app-text/tetex )"
+	tetex? ( virtual/tetex )"
 
 DEPEND="${RDEPEND}
 	doc? ( app-doc/doxygen )
diff --git a/app-office/gnucash/gnucash-2.0.4.ebuild b/app-office/gnucash/gnucash-2.0.4.ebuild
new file mode 100644
index 000000000000..fbaf1bfb228a
--- /dev/null
+++ b/app-office/gnucash/gnucash-2.0.4.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/gnucash/gnucash-2.0.4.ebuild,v 1.1 2007/01/24 20:13:17 seemant Exp $
+
+inherit eutils gnome2
+
+DOC_VER="2.0.1"
+
+DESCRIPTION="A personal finance manager."
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2
+	mirror://sourceforge/${PN}/${PN}-docs-${DOC_VER}.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~sparc ~x86"
+
+IUSE="ofx hbci chipcard doc debug quotes nls"
+
+RDEPEND=">=dev-libs/glib-2.4.0
+	=dev-scheme/guile-1.6*
+	=dev-scheme/slib-3.1.1*
+	>=sys-libs/zlib-1.1.4
+	>=dev-libs/popt-1.5
+	>=x11-libs/gtk+-2.4
+	>=gnome-base/libgnomeui-2.4
+	>=gnome-base/libgnomeprint-2.10
+	>=gnome-base/libgnomeprintui-2.10
+	>=gnome-base/libglade-2.4
+	>=gnome-extra/gtkhtml-3.10.1
+	>=dev-libs/libxml2-2.5.10
+	=dev-libs/g-wrap-1.9.6*
+	>=gnome-base/gconf-2
+	>=app-text/scrollkeeper-0.3
+	>=x11-libs/goffice-0.0.4
+	gnome-extra/yelp
+	ofx? ( >=dev-libs/libofx-0.7.0 )
+	hbci? ( net-libs/aqbanking
+		chipcard? ( sys-libs/libchipcard )
+	)
+	quotes? ( dev-perl/DateManip
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/HTML-TableExtract )
+	app-text/docbook-xsl-stylesheets
+	=app-text/docbook-xml-dtd-4.1.2*
+	nls? ( dev-util/intltool )"
+
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen
+		media-gfx/graphviz
+		virtual/tetex )
+	dev-util/pkgconfig"
+
+pkg_setup() {
+	built_with_use gnome-extra/libgsf gnome || die "gnome-extra/libgsf must be built with gnome"
+	built_with_use x11-libs/goffice gnome || die "x11-libs/goffice must be built with gnome"
+}
+
+src_compile() {
+
+	local myconf
+
+	if use doc ; then
+		myconf="${myconf} --enable-latex-docs"
+	fi
+
+	econf \
+		$(use_enable debug) \
+		$(use_enable ofx) \
+		$(use_enable doc doxygen) \
+		$(use_enable doc html-docs) \
+		$(use_enable doc dot) \
+		$(use_enable hbci) \
+		--enable-locale-specific-tax \
+		${myconf} || die "econf failed"
+
+	MAKEOPTS="-j1"
+	emake || die "emake failed"
+
+	cd "${WORKDIR}/gnucash-docs-${DOC_VER}"
+	econf || die "doc econf failed"
+	emake || die "doc emake failed"
+}
+
+src_test() {
+	einfo "Skipping tests because one of the upstream tests is broken"
+	einfo "Please reference: https://bugs.gentoo.org/show_bug.cgi?id=146769#c1"
+	einfo "We have a filed a bug upstream.  When that is resolved,"
+	einfo "We will re-enable the tests."
+}
+
+# See http://bugs.gentoo.org/show_bug.cgi?id=132862 regarding gconf schema install
+
+src_install() {
+	gnome2_src_install || die "gnome2_src_install failed"
+	dodoc AUTHORS ChangeLog* DOCUMENTERS HACKING INSTALL NEWS TODO README* doc/README*
+	make_desktop_entry ${P} "GnuCash ${PV}" gnucash-icon.png "GNOME;Office;Finance"
+
+	cd "${WORKDIR}/${PN}-docs-${DOC_VER}"
+	make DESTDIR="${D}" \
+		scrollkeeper_localstate_dir="${D}/var/lib/scrollkeeper" \
+		install || die "doc install failed"
+	rm -rf "${D}/var/lib/scrollkeeper"
+}
+
+pkg_postinst() {
+	elog "Please note that postgresql support has been removed."
+	elog "Please see: https://bugs.gentoo.org/show_bug.cgi?id=146769#c9"
+	elog "for an explanation."
+}