Version bump, add sync plugin support to 9999

(Portage version: 2.2.16/cvs/Linux x86_64, signed Manifest commit with key 0xD80F5F1E1245142E)

4 files changed, 103 insertions, 5 deletions

diff --git a/app-portage/layman/ChangeLog b/app-portage/layman/ChangeLog
index 94569a8af174..d272374eec40 100644
--- a/app-portage/layman/ChangeLog
+++ b/app-portage/layman/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-portage/layman
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.224 2015/01/17 09:52:50 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/ChangeLog,v 1.225 2015/02/08 18:50:41 dolsen Exp $
+
+*layman-2.3.0 (08 Feb 2015)
+
+  08 Feb 2015; Brian Dolbec <dolsen@gentoo.org> +layman-2.3.0.ebuild,
+  layman-9999.ebuild:
+  Version bump. Add portage plugin USE flag and installation to layman-9999.
 
   17 Jan 2015; Patrick Lauer <patrick@gentoo.org> layman-2.2.0-r7.ebuild:
   Fix #525896, tests now actually run and fail
diff --git a/app-portage/layman/layman-2.3.0.ebuild b/app-portage/layman/layman-2.3.0.ebuild
new file mode 100644
index 000000000000..a172ae3b2fac
--- /dev/null
+++ b/app-portage/layman/layman-2.3.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-2.3.0.ebuild,v 1.1 2015/02/08 18:50:41 dolsen Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+PYTHON_REQ_USE="xml(+)"
+
+inherit eutils distutils-r1 linux-info prefix
+
+DESCRIPTION="Tool to manage Gentoo overlays"
+HOMEPAGE="http://layman.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="bazaar cvs darcs +git gpg g-sorcery mercurial squashfs subversion sync-plugin-portage test"
+
+DEPEND="test? ( dev-vcs/subversion )"
+
+RDEPEND="
+	bazaar? ( dev-vcs/bzr )
+	cvs? ( dev-vcs/cvs )
+	darcs? ( dev-vcs/darcs )
+	git? ( dev-vcs/git )
+	mercurial? ( dev-vcs/mercurial )
+	g-sorcery? ( app-portage/g-sorcery )
+	subversion? (
+		|| (
+			>=dev-vcs/subversion-1.5.4[http]
+			>=dev-vcs/subversion-1.5.4[webdav-neon]
+			>=dev-vcs/subversion-1.5.4[webdav-serf]
+		)
+	)
+	sync-plugin-portage?  ( >=sys-apps/portage-2.2.16[${PYTHON_USEDEP}] )
+	!sync-plugin-portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
+	gpg? ( dev-python/pyGPG )
+	>=dev-python/ssl-fetch-0.2[${PYTHON_USEDEP}]
+	"
+
+layman_check_kernel_config() {
+	local CONFIG_CHECK
+	use squashfs && CONFIG_CHECK+=" ~BLK_DEV_LOOP ~SQUASHFS"
+	[[ -n ${CONFIG_CHECK} ]] && check_extra_config
+}
+
+pkg_pretend() {
+	layman_check_kernel_config
+}
+
+pkg_setup() {
+	layman_check_kernel_config
+}
+
+python_prepare_all()  {
+	esetup.py setup_plugins
+	distutils-r1_python_prepare_all
+	#rm "${S}"/"${PN}"/tests/dtest.py
+	eprefixify etc/layman.cfg layman/config.py
+}
+
+python_test() {
+	for suite in layman/tests/external.py ; do
+		PYTHONPATH="." "${PYTHON}" ${suite} \
+		|| die "test suite '${suite}' failed"
+	done
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	insinto /etc/layman
+	doins etc/layman.cfg
+
+	doman doc/layman.8
+	dohtml doc/layman.8.html
+
+	keepdir /var/lib/layman
+	keepdir /etc/layman/overlays
+}
+
+pkg_postinst() {
+	# now run layman's update utility
+	einfo "Running layman-updater..."
+	"${EROOT}"/usr/bin/layman-updater
+	einfo
+}
diff --git a/app-portage/layman/layman-9999.ebuild b/app-portage/layman/layman-9999.ebuild
index c9236fe64ebd..f45e5514b543 100644
--- a/app-portage/layman/layman-9999.ebuild
+++ b/app-portage/layman/layman-9999.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2014 Gentoo Foundation
+# Copyright 1999-2015 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-9999.ebuild,v 1.39 2014/10/14 21:41:25 twitch153 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-9999.ebuild,v 1.40 2015/02/08 18:50:41 dolsen Exp $
 
 EAPI="5"
 
@@ -17,7 +17,7 @@ EGIT_REPO_URI="git://git.overlays.gentoo.org/proj/layman.git"
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS=""
-IUSE="bazaar cvs darcs +git gpg g-sorcery mercurial squashfs subversion test"
+IUSE="bazaar cvs darcs +git gpg g-sorcery mercurial squashfs subversion sync-plugin-portage test"
 
 DEPEND="test? ( dev-vcs/subversion )
 	app-text/asciidoc"
@@ -37,7 +37,8 @@ RDEPEND="
 		)
 	)
 	gpg? ( =dev-python/pyGPG-9999 )
-	sys-apps/portage[${PYTHON_USEDEP}]
+	sync-plugin-portage?  ( >=sys-apps/portage-2.2.16[${PYTHON_USEDEP}] )
+	!sync-plugin-portage? ( sys-apps/portage[${PYTHON_USEDEP}] )
 	>=dev-python/ssl-fetch-0.2[${PYTHON_USEDEP}]
 	"
 
@@ -56,6 +57,7 @@ pkg_setup() {
 }
 
 python_prepare_all()  {
+	esetup.py setup_plugins
 	distutils-r1_python_prepare_all
 	eprefixify etc/layman.cfg layman/config.py
 }
diff --git a/app-portage/layman/metadata.xml b/app-portage/layman/metadata.xml
index e3caad80f524..5f6237c6c7d9 100644
--- a/app-portage/layman/metadata.xml
+++ b/app-portage/layman/metadata.xml
@@ -20,5 +20,6 @@
 		<flag name="mercurial">Support <pkg>dev-vcs/mercurial</pkg> based overlays</flag>
 		<flag name="squashfs">Support mounting squashfs image overlays locally read-only</flag>
 		<flag name="subversion">Support <pkg>dev-vcs/subversion</pkg> based overlays</flag>
+		<flag name="sync-plugin-portage">Install the <pkg>sys-apps/portage</pkg> sync module</flag>
 	</use>
 </pkgmetadata>