Convert to python-single-r1, bug 458802 by mgorny.

(Portage version: 2.2.0_alpha163/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

1 files changed, 20 insertions, 21 deletions

diff --git a/app-text/asciidoc/asciidoc-9999.ebuild b/app-text/asciidoc/asciidoc-9999.ebuild
index 9bb8b13e3e5d..0d5c45f70c70 100644
--- a/app-text/asciidoc/asciidoc-9999.ebuild
+++ b/app-text/asciidoc/asciidoc-9999.ebuild
@@ -1,14 +1,13 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild,v 1.10 2012/12/27 19:09:35 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/asciidoc/asciidoc-9999.ebuild,v 1.11 2013/02/23 00:44:44 floppym Exp $
 
-EAPI="3"
+EAPI=5
 
-PYTHON_DEPEND="2:2.5"
-RESTRICT_PYTHON_ABIS="3.*"
+PYTHON_COMPAT=( python{2_5,2_6,2_7} pypy{1_9,2_0} )
 
 [ "$PV" == "9999" ] && inherit mercurial autotools
-inherit python
+inherit python-single-r1
 
 DESCRIPTION="A text document format for writing short documents, articles, books and UNIX man pages"
 HOMEPAGE="http://www.methods.co.nz/asciidoc/"
@@ -29,14 +28,16 @@ RDEPEND=">=app-text/docbook-xsl-stylesheets-1.75
 		dev-libs/libxslt
 		graphviz? ( media-gfx/graphviz )
 		app-text/docbook-xml-dtd:4.5
-		highlight? ( || ( dev-python/pygments dev-util/source-highlight ) )
+		highlight? ( || ( dev-python/pygments[${PYTHON_USEDEP}] dev-util/source-highlight ) )
+		${PYTHON_DEPS}
 "
 DEPEND="test? ( dev-util/source-highlight
 			media-sound/lilypond
 			media-gfx/imagemagick
 			dev-texlive/texlive-latex
 			app-text/dvipng
-			media-gfx/graphviz )
+			media-gfx/graphviz
+			${PYTHON_DEPS} )
 "
 
 if [ "$PV" == "9999" ]; then
@@ -46,10 +47,6 @@ if [ "$PV" == "9999" ]; then
 		dev-util/source-highlight"
 fi
 
-pkg_setup() {
-	python_set_active_version 2
-}
-
 src_prepare() {
 	if ! use vim-syntax; then
 		sed -i -e '/^install/s/install-vim//' Makefile.in || die
@@ -75,32 +72,34 @@ src_compile() {
 	default
 
 	if [ "$PV" == "9999" ]; then
-		( cd doc && aap -f main.aap ../{CHANGELOG,README,BUGS} )
+		cd doc || die
+		aap -f main.aap ../{CHANGELOG,README,BUGS} || die
 	fi
 }
 
 src_install() {
 	use vim-syntax && dodir /usr/share/vim/vimfiles
 
-	emake DESTDIR="${D}" install || die "install failed"
+	emake DESTDIR="${D}" install
 
-	python_convert_shebangs -r 2 "${D}"
+	python_fix_shebang "${ED}"/usr/bin/*.py
 
 	if use examples; then
 		# This is a symlink to a directory
 		rm examples/website/images || die
 
-		insinto /usr/share/doc/${PF}
-		doins -r examples || die
-		dosym ../../../asciidoc/images /usr/share/doc/${PF}/examples || die
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+		dosym ../../../asciidoc/images /usr/share/doc/${PF}/examples
 	fi
 
 	dodoc BUGS CHANGELOG README docbook-xsl/asciidoc-docbook-xsl.txt \
-			dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt || die
+			dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt
 }
 
 src_test() {
 	cd tests || die
-	ASCIIDOC_PY=../asciidoc.py "$(PYTHON)" test${PN}.py update || die
-	ASCIIDOC_PY=../asciidoc.py "$(PYTHON)" test${PN}.py run || die
+	local -x ASCIIDOC_PY=../asciidoc.py
+	"${PYTHON}" test${PN}.py update || die
+	"${PYTHON}" test${PN}.py run || die
 }