bump to 0.6.3; bug #202507

(Portage version: 2.1.4)

1 files changed, 76 insertions, 0 deletions

diff --git a/app-text/poppler-bindings/poppler-bindings-0.6.3.ebuild b/app-text/poppler-bindings/poppler-bindings-0.6.3.ebuild
new file mode 100644
index 000000000000..3c163ec305cd
--- /dev/null
+++ b/app-text/poppler-bindings/poppler-bindings-0.6.3.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler-bindings/poppler-bindings-0.6.3.ebuild,v 1.1 2008/01/21 16:01:42 dang Exp $
+
+inherit autotools eutils multilib
+
+MY_P=${P/-bindings/}
+DESCRIPTION="rendering bindings for GUI toolkits for poppler"
+HOMEPAGE="http://poppler.freedesktop.org/"
+
+# Creating the testsuite tarball (must be done for every release)
+#
+# cvs -d :pserver:anoncvs@cvs.freedesktop.org:/cvs/poppler login
+# cvs -d :pserver:anoncvs@cvs.freedesktop.org:/cvs/poppler co test
+# tar czf poppler-test-${PV}.tar.gz
+# upload to d.g.o/space/distfiles-local
+
+SRC_URI="http://poppler.freedesktop.org/${MY_P}.tar.gz
+		test? ( mirror://gentoo/poppler-test-0.6.1.tar.gz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="gtk qt3 cairo qt4 test"
+
+RDEPEND="~app-text/poppler-${PV}
+	cairo? ( >=x11-libs/cairo-1.4 )
+	gtk? (
+		>=x11-libs/gtk+-2.8
+		>=gnome-base/libglade-2
+	)
+	qt3? ( =x11-libs/qt-3* )
+	qt4? ( =x11-libs/qt-4* )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+S=${WORKDIR}/${MY_P}
+
+src_unpack(){
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}"/poppler-0.6-bindings.patch
+
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_compile() {
+	# Configure needs help finding qt libs on multilib systems
+	export QTLIB="${QTDIR}/$(get_libdir)"
+	echo $QTLIB
+
+	econf --enable-opi \
+		$(use_enable cairo cairo-output) \
+		$(use_enable gtk poppler-glib) \
+		$(use_enable qt3 poppler-qt) \
+		$(use_enable qt4 poppler-qt4) \
+		|| die "configuration failed"
+	cd poppler
+	if use cairo; then
+		emake libpoppler-cairo.la || die "cairo failed"
+	fi
+	if use qt4; then
+		emake libpoppler-arthur.la || die "arthur failed"
+	fi
+	cd ..
+	emake || die "compilation failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+}
+
+pkg_postinst() {
+	ewarn "You need to rebuild everything depending on poppler, use revdep-rebuild"
+}